Переставить строки и столбцы матрицы так, чтобы максимальный по модулю элемент был расположен на пересечении k-й строки и k-го столбца

program _matrix;
 
const
 
 N  = 5;
 M  = 3;
 
type 
 
 TMatrix   = array [1..N, 1..M] of integer;
 TPosition = record
  i     : byte;
  j     : byte;
  value : integer;
 end;
 
 
var
 
 Matrix     : TMatrix;
 Max        : TPosition;
 k          : byte;
 
procedure FillMatrix(var MTR : TMatrix;rnd : boolean;lb,rb:integer);
{процедура заполнения матрицы значениями из (lb,rb)
 rnd=true - случайнo rnd=false - вручную           } 
 var  
  i,j       : byte;
  x         : integer;
 function RandomInt(a,b:integer):integer;
 {возвращает случайное целое из (a;b)}
  var
   x        : integer;
   sign     : 0..1;
  begin
   x:=0;
   if a<=b then 
    begin
     if b<0 then 
      repeat 
       x:=-random(Abs(a))
      until (x>a) and (x<b);
    if b>0 then 
     repeat 
      x:=random(b);
      sign:=random(2);
      if sign>0 then x:=-x;
     until (x>a) and (x<b);
   end;
  RandomInt:=x;   
 end;
 
begin
 Writeln();
 case rnd of 
    TRUE : begin
            for i:=1 to N do 
            for j:=1 to M do 
            MTR[i,j]:=RandomInt(lb,rb);
           end;
    FALSE: begin
            for i:=1 to N do 
            for j:=1 to M do 
             begin
              repeat
               write('[',i,',',j,',]: ' );
               readln(x);
              until (x>lb) and (x<rb);
              MTR[i,j]:=x;
             end;
           end;
 end;   
 writeln();
end;
 
procedure PrintMatrix(const MTR : TMatrix);
{процедура вывода матрицы на экран      }
 var
  i,j       : integer;
begin
 writeln();
 for i:=1 to N do begin
 for j:=1 to M do write(MTR[i,j]:5,' ');
                  writeln();
                  end;
 writeln();               
end;
 
procedure SwapLines(var MTR : TMatrix; a,b : integer);
{   процедура меняет местами строки матрицы 
              с номерами a,b              }
 var
  i         : integer;
  temp      : array [1..M] of integer;
begin
for i:=1 to M do temp[i] := MTR[a,i];
for i:=1 to M do MTR[a,i]:= MTR[b,i];
for i:=1 to M do MTR[b,i]:= temp[i];
end; 
 
procedure SwapColumns(var MTR : TMatrix; a,b : integer);
{   процедура меняет местами столбцы матрицы 
              с номерами a,b              }
 var
  i         : integer;
  temp      : array [1..N] of integer;
begin
for i:=1 to N do temp[i] := MTR[i,a];
for i:=1 to N do MTR[i,a]:= MTR[i,b];
for i:=1 to N do MTR[i,b]:= temp[i];
end;   
 
function GetAbsMax(const MTR : TMatrix):TPosition;
{возвращает максимальный по модулю элемент матрицы}
 var 
  i,j       : byte;
  Max       : TPosition;
begin
 Max.i:=1;
 Max.j:=1;
 Max.value:=MTR[1,1];
 for i:=1 to N do 
 for j:=1 to M do 
    if Abs(Max.value) < Abs(MTR[i,j]) then 
     begin
      Max.i:=i;
      Max.j:=j;
      Max.value:=MTR[i,j];
     end;
 GetAbsmax:=Max;     
end;
 
BEGIN
 
{ fill & print Matrix }
 randomize;
 FillMatrix(Matrix,true,-100,100); { false если вручную}
 PrintMatrix(Matrix);
 
{ process. & output }
 Max:=GetAbsMax(Matrix);
 Writeln(Max.value);writeln();
 Write('k: ');Readln(k);
 SwapLines(Matrix,k,Max.i);
 SwapColumns(Matrix,k,Max.j);
 PrintMatrix(Matrix);
 
END.