Длинная арифметика

program power2;
 
const m = 10000; {точность}
      w = 70; {ширина печати}
 
var s: array [1..m] of byte; {цифры числа}
    i, k: integer; {счётчики}
    j: integer; {количество значащих разрядов}
    p: integer; {степень}
    d: integer; {десятичный порядок}
    f: boolean; {флаг потери точности}
 
 
begin
  repeat
    write('Power = '); {ввод степени}
    readln(p);
    p := abs(p); {почему бы и нет?}
  until p > 0;
  s[1] := 5; {первая цифра после запятой для 2^-1, считаем, что один раз s на два поделили}
  for i := 2 to m do s[i] := 0; {остальные цифры обнуляем}
  j := 2; {пока пусть 2 значащих разряда}
  d := 1; {десятичный порядок пока = -1}
  f := false; {потери точности нет}
  for i := 1 to p - 1 do {цикл деления на 2 аж p - 1 раз}
    begin
      for k := 2 to j do {делим столбиком}
        begin
          s[k] := (s[k - 1] mod 2) * 10 + s[k]; {перенос остатка в следующий разряд}
          s[k - 1] := s[k - 1] div 2 {деление текущего разряда}
        end;
        if s[j] > 9 then {если последний разряд > 9, корректируем число}
          begin
            if j < m {если точность не превышена,}
              then {то увеличиваем количество значащих разрядов на 1}
                begin
                  j := j + 1;
                  s[j - 1] := s[j - 1] div 2; {и корректируем число}
                  s[j] := (s[j - 1] mod 2)
                end
              else {если точность превышена,}
                begin
                  s[j] := s[j] div 2; {усекаем число}
                  f := true {точность потеряна}
                end;
          end;
        while s[1] = 0 do {пока (если) есть незначащий ноль}
          begin
            d := d + 1; {инкремент десятичного порядка}
            for k := 1 to j - 1 do s[k] := s[k + 1]; {сдвигаем число влево}
            s[j] := 0; {последний разряд = 0}
            j := j - 1 {делаем число короче на 1 разряд}
          end;
    end;
  if f then writeln('Precision overflow. Result may be incorrect.'); {произошла потеря точности}
  writeln('2^-', p, ' ='); {ввыводим результат}
  write(s[1]);
  if j > 1 then write('.');
  k := 2; {общее количество напечатанных знаков = 2, потому что уже напечатано X.}
  for i := 2 to j - 1 do {пробегаемся по разрядам}
    begin
      write(s[i]); {печатаем очередной разряд числа}
      k := k + 1; {инкремент количества напечатанных знаков}
      if k mod w = 0 then writeln {печатаем по w знаков}
    end;
  write('e-', d); {печатаем десятичный порядок}
  writeln;
  writeln('Significant digits: ', j - 1); {печатаем количество значащих цифр}
  readln
end.