Составить программу, которая выводит на экран графики двух гармонических колебаний

uses
  crt, graphABC;
 
const
  w = 50;  
 
var
  Am1, phi1, omeha1, Am2, phi2, omeha2, a, b, fmin, fmax, dx, dy, mx, my: real;
  Q, x0, y0: integer;
  s: string;
 
function F(x, Am, phi, omeha: real): real;
begin
  f := Am * sin(omeha * x + phi);
end;
 
procedure Interval(d: real; var a, b: real);
begin
  if frac(a / d) <> 0 then a := d * trunc(a / d) - d;
  if frac(b / d) <> 0 then b := d * trunc(b / d) + d;
end;
 
///Процедура вычисляет начало координат x0, y0
procedure NachaloCoordinat(a, b, fMin, fMax, mx, my: real);
begin
  if a < 0 then
    if b < 0 then x0 := WindowWidth - w
    else x0 := trunc(abs(a) * mx) + w
  else x0 := w;
  if fMin < 0 then
    if fMax < 0 then y0 := w + 0
    else y0 := WindowHeight - trunc(abs(fMin) * my) - w
  else y0 := WindowHeight - w;
end;
 
procedure SystemCoordinate;
var
 i, j, x, y: integer;
 n: real;
begin
  mx := (windowwidth - 2 * w) / (b - a); //масштаб по Х
  my := (windowheight - 2 * w) / (fmax - fmin); //масштаб по Y
  NachaloCoordinat(a, b, fMin, fMax, mx, my);
  Line(10, y0, WindowWidth - 10, y0);  //OX
  Line(x0, 10, x0, WindowHeight - 10); //OY
  SetFontColor(clRed);
  TextOut(WindowWidth - 20, y0 + 10, 'X');
  TextOut(x0 + 5, 10, 'Y');
  SetFontSize(8);
  SetFontColor(clBlue);
  { Засечки на оси OX: }
  j := round((b - a) / dx) + 1; //j - количество засечек
  for i := 1 to j do 
  begin
    x := w + trunc((i - 1) * Mx * dx);
    Line(x, y0 - 3, x, y0 + 3); //рисуем засечки на оси OX
    n := a + (i - 1) * dx;
    Str(n, s);
    if abs(n) > 0.00001 then TextOut(x - TextWidth(s) div 2, y0 + 10, s)
  end;
  { Засечки на оси OY: }
  j := round((fmax - fmin) / dy) + 1; //j - количество засечек
  for i := 1 to j do 
  begin
    y := windowheight - w - trunc((i - 1) * My * dy);
    Line(x0 - 3, y, x0 + 3, y); //рисуем засечки на оси Oy
    n := fmin + (i - 1) * dy;
    Str(n, s);
    if abs(N) > 0.00001 then TextOut(x0 + 7, y - 8, s)
  end
end;
 
///Процедура рисования графика f(x)
procedure Graphik(Am, phi, omeha: real);
var
  x1, y1: real;
  i, x, y: integer;
  bln: boolean;
begin
  { Строим график с помощью маленьких отрезков: }
  bln := false;
  Q := WindowWidth - 2 * w;
  for i := 0 to Q do 
  begin
    x1 := a + i / mx;
    y1 := f(x1, Am, phi, omeha);
    if abs(y1) < maxInt then y := y0 - round(y1 * my);
    if (a > 0) and (b > 0) then x1 := x1 - a
    else
    if (a < 0) and (b < 0) then x1 := x1 - b;
    x := x0 + round(x1 * mx);
    if bln then begin
      if (y >= w) and (y <= windowheight - w) then LineTo(x, y)
      else bln := false
    end
    else
      if (y >= w) and (y <= windowheight - w) then begin
        MoveTo(x, y);
        bln := true
      end
  end
end;
 
begin
  SetWindowCaption('Колебания');
  SetWindowSize(800, 600);
  writeln('Первый график:');
  write('  Введите интервал: ');
  readln(a, b);
  write('  Введите амплитуду: ');
  readln(Am1);
  write('Введите фазу: ');
  readln(phi1);
  write('Введите частоту: ');
  read(omeha1);
  writeln('Второй график:');
  write('  Введите амплитуду: ');
  readln(Am2);
  write('Введите фазу: ');
  readln(phi2);
  write('Введите частоту: ');
  readln(omeha2);
  clrscr;
  hidecursor;
  dx := 0.5; dy := 1; //задаем шаг
  if Am1 > Am2 then begin
    fmin := -Am1; fmax := Am1;
  end
  else begin
    fmin := -Am2; fmax := Am2;
  end;  
  Interval(dx, a, b);
  Interval(dy, fmin, fmax);
  ClearWindow;
  SystemCoordinate; //рисуем систему координат
  SetPenColor(clGreen);
  SetPenWidth(2);
  Graphik(Am1, phi1, omeha1);
  SetPenColor(clRed);
  Graphik(Am2, phi2, omeha2);
end.

readln(omeha2);
  clrscr;
  hidecursor;