Ввести файл F1. Записать в файл F2 компоненты файла F1 в обратном порядке

//Ввести файл F1. Записать в файл F2 компоненты файла F1 в обратном порядке.
//В каждом из файлов элемент, стоящий справа от максимума
//продублировать значением этого максимума.
//Файлы вывести до и после преобразования.
uses crt;
type tfile=file of integer; //тип файлов
var n:integer;
procedure createfile(var f:tfile);//создание файла F1
var a,i:integer;
begin
assign(f,'f1');
rewrite(f);
for i:=1 to n do
 begin
  a:=random(50);
  write(f,a)
 end;
end;
procedure readfile(var f:tfile);//чтение и вывод файлов на экран
var a:integer;
begin
seek(f,0);
while not eof(f) do
 begin
  read(f,a);
  write(a:4)
 end;
writeln;
end;
procedure revers(var f1,f2:tfile);//создание перевернуго файла F2
var a,i:integer;
begin
assign(f2,'f2');
rewrite(f2);
seek(f1,0);
for i:=filesize(f1)-1 downto 0 do
 begin
  seek(f1,i);
  read(f1,a);
  seek(f2,filesize(f2));
  write(f2,a)
 end;
end;
procedure max(var f:tfile;var mx,imx:integer); //нахождение макс и его номера
var i,a:integer;
begin
seek(f,0);
mx:=-maxint-1;
imx:=0;
for i:=0 to filesize(f)-1 do
 begin
  read(f,a);
  if a>mx then
   begin
    mx:=a;
    imx:=i
   end;
 end;
writeln('Максимальный элемент=',mx,' его номер=',imx+1);
end;
procedure vstavka(var f:tfile;imx,mx,k:integer);//вставка макс после следующего за макс
var i,a:integer;
begin
writeln('Вставка максимального в файл F',k);
seek(f,0);
if imx=filesize(f)-1 then
writeln('Максимальный элемент последний, дублирование невозможно')
else
 begin
  if imx=filesize(f)-2 then
   begin
    seek(f,filesize(f));
    write(f,mx);
   end
  else
   begin
    for i:=filesize(f) downto imx+3 do
     begin
      seek(f,i-1);
      read(f,a);
      seek(f,i);
      write(f,a);
     end;
    seek(f,imx+2);
    write(f,mx)
   end;
  readfile(f);
 end;
end;
var f1,f2:tfile;
    i,j,mx1,mx2,imx1,imx2:integer;
begin
write('Сколько компонентов записать в файл n=');
readln(n);
createfile(f1);
writeln('Исходный файл F1');
readfile(f1);
max(f1,mx1,imx1);
revers(f1,f2);
writeln('Исходный файл F2');
readfile(f2);
max(f2,mx2,imx2);
vstavka(f1,imx1,mx1,1);
vstavka(f2,imx2,mx2,2);
close(f1);
close(f2)
end.