Звезда Алгоритмом Брезенхема

uses graphABC,crt;
//процедура рисования отрезка
procedure Brezenhem(x1,y1,x2,y2:integer);
var currentX, currentY: integer;
    errorX, errorY: integer;
    d, dx, dy, incX, incY: integer;
begin
dx := x2 - x1;
dy := y2 - y1;
errorX := 0;
errorY := 0;
if(dx > 0) then incX := 1
else if(dx = 0) then incX := 0
else incX := -1;
if(dy > 0) then incY := 1
else if(dy = 0) then incY := 0
else incY := -1;
dx := abs(dx);
dy := abs(dy);
if(dy > dx) then d := dy
else d := dx;
currentX := x1;
currentY := y1;
setpixel(currentX, currentY, clRed);
while((currentX <> x2) OR (currentY <> y2)) do
 begin
  errorX := errorX + dx;
  errorY := errorY + dy;
  if(errorX >= d) then
   begin
    errorX := errorX - d;
    currentX := currentX + incX;
   end;
  if(errorY >= d) then
   begin
    errorY := errorY - d;
    currentY := currentY + incY;
   end;
  SetPixel(currentX, currentY, clRed);
 end;
end;
//процедура построения 5-и угольной звезды
procedure Zvezda(x,y,r: integer); //координаты центра и радиус
var x1,y1,x2,y2,x3,y3,i: integer;
    r1,a:real;//внутренний радиус звезды и угол на вершину
begin
r1:=r*0.382;
a:=pi/2;
for i:=1 to 5 do
 begin
  x1:=x+round(r*cos(a));//первая точка
  y1:=y-round(r*sin(a));
  x2:=x+round(r1*cos(a+pi/5)); //вторая точка
  y2:=y-round(r1*sin(a+pi/5));
  x3:=x+round(r*cos(a+2*pi/5)); //третья точка
  y3:=y-round(r*sin(a+2*pi/5));
  Brezenhem(x1,y1,x2,y2);
  Brezenhem(x2,y2,x3,y3);
  a:=a+2*pi/5;
 end;
end;
var n,i,x,y,r:integer;
begin
randomize;
write('Количество звезд n=');
readln(n);
clrscr;
hidecursor;
for i:=1 to n do
 begin
  r:=10+random(50);
  x:=r+random(windowwidth-2*r);
  y:=r+random(windowheight-2*r);
  Zvezda(x,y,r);
 end;
end.

//процедура построения 5-и угольной звезды
procedure Zvezda(x,y,r: integer); //координаты центра и радиус
var x1,y1,x2,y2,i: integer;
    r1,a:real;//внутренний радиус звезды и угол на вершину
begin
r1:=r*0.382;
a:=pi/2;
for i:=1 to 5 do
 begin
  x1:=x+round(r*cos(a));//первая точка
  y1:=y-round(r*sin(a));
  x2:=x+round(r1*cos(a+pi/5)); //вторая точка
  y2:=y-round(r1*sin(a+pi/5));
  Brezenhem(x1,y1,x2,y2);
  x2:=x+round(r1*cos(a-pi/5)); //третья точка
  y2:=y-round(r1*sin(a-pi/5));
  Brezenhem(x1,y1,x2,y2);
  a:=a+2*pi/5;
 end;
end;