Найти значение выражения

@JiL777 · Регистрация: 03.12.2015

Студворк — интернет-сервис помощи студентам

Даны натуральные числа N, М . Целые числа а1..аn, b1....bm, c1.....c30. Получить:

$https://www.cyberforum.ru/cgi-bin/latex.cgi?<br /> l=\begin{cases}\min \left( b_1,\,...,\,b_m\right)+\min \left(c_1,\,...,\,c_{30} \right) & \text{, if } \begin{vmatrix}\min \left( a_1,\,...,\,a_n\right)\end{vmatrix}\,>\,10 \\\\ 1+\left( \max \left(c_1,\,...,\,c_{30} \right)\right)^3 & \text{, otherwise }\end{cases}<br />$

Необходимо использовать процедуры (подпрограмы).

@Cyborg Drone · 13.01.2016, 13:37

Pascal
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
{генерация и печать массива}
procedure gen_prn(s: string; var x: array of integer; r: integer);
var i: integer;
begin
  writeln('Массив ', s, ':');
  for i := 0 to r - 1 do
    begin
      x[i] := -99 + random(199);
      write(x[i]:4)
    end;
  writeln
end;
 
{нахождение минимума (d = -1) или максимума (d = 1) массива}
procedure min_max(var x: array of integer; r: integer; d: integer; var t: integer);
var i: integer;
begin
  t := x[0];
  for i := 1 to r - 1 do
    if d * x[i] > d * t
      then t := x[i]
end;
 
const mi = 100;
 
{ввод размера массива}
procedure inp_raz(s: string; var x: integer);
begin
  repeat
    write('Введите размер массива ', s, ' (1..', mi, '): ');
    readln(x)
  until (x >= 1) and (x <= mi)
end;
 
var l, m, n, p, q: integer;
    a, b: array [1..mi] of integer;
    c: array [1..30] of integer;
 
begin
  randomize;
  inp_raz('A', n);
  inp_raz('B', m);
  gen_prn('A', a, n);
  gen_prn('B', b, m);
  gen_prn('C', c, 30);
  min_max(a, n, -1, p);
  if p > 10
    then begin
      min_max(b, m, -1, p);
      min_max(c, 30, -1, q);
      l := p + q
    end
    else begin
      min_max(c, 30, 1, p);
      l := 1 + p * p * p
    end;
  write('L = ', l);
  readln
end.

@JiL777 · 14.01.2016, 04:05 **[ТС]**

44 строчка кода пишет : неправельный тип параметров подпрограммы

@Cyborg Drone · 14.01.2016, 04:22

Полагаю, что-нибудь неверно скопировали. Прогон программы:

Code
Введите размер массива A (1..100): 10
Введите размер массива B (1..100): 55
Массив A:
 -72   5 -14  56 -16  54 -14 -50  18 -10
Массив B:
  10 -52  14 -61 -31  35 -51  48 -89 -41  36  44   7 -77 -72  20 -58 -76  46 -46
 -13  62 -71 -22  98  62   1   1 -64  61  37 -48 -59   9  60 -78 -13 -62 -37  71
  -6 -75 -63  82 -71  53  79 -45 -53 -81 -54  70 -52 -96  91
Массив C:
 -90 -41  32 -29 -60 -90 -17 -74  69 -92 -35 -98  84  95 -63 -67 -76  -6  32 -11
  67  16 -94 -37 -90 -36 -88   3  65 -75
L = 857376

Строка 44 выполнилась успешно.

@Антон1985 · 14.01.2016, 06:54

Программа описанная в посте #2 в TurboPascal-е работает отлично, а в PascalABC строку

Pascal
1
var x: array of integer;

в параметре процедур не понимает.

@Cyborg Drone · 14.01.2016, 08:05

Всё время забываю, что в этом уродце ABC нет открытых массивов... Вот так попробуйте:

Pascal
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
const mi = 100;
 
type matrix = array [1..mi] of integer;
 
{генерация и печать массива}
procedure gen_prn(s: string; var x: matrix; r: integer);
var i: integer;
begin
  writeln('Массив ', s, ':');
  for i := 1 to r do
    begin
      x[i] := -99 + random(199);
      write(x[i]:4)
    end;
  writeln
end;
 
{нахождение минимума (d = -1) или максимума (d = 1) массива}
procedure min_max(var x: matrix; r: integer; d: integer; var t: integer);
var i: integer;
begin
  t := x[1];
  for i := 2 to r do
    if d * x[i] > d * t
      then t := x[i]
end;
 
{ввод размера массива}
procedure inp_raz(s: string; var x: integer);
begin
  repeat
    write('Введите размер массива ', s, ' (1..', mi, '): ');
    readln(x)
  until (x >= 1) and (x <= mi)
end;
 
var l, m, n, p, q: integer;
    a, b, c: matrix;
 
begin
  randomize;
  inp_raz('A', n);
  inp_raz('B', m);
  gen_prn('A', a, n);
  gen_prn('B', b, m);
  gen_prn('C', c, 30);
  min_max(a, n, -1, p);
  if p > 10
    then begin
      min_max(b, m, -1, p);
      min_max(c, 30, -1, q);
      l := p + q
    end
    else begin
      min_max(c, 30, 1, p);
      l := 1 + p * p * p
    end;
  write('L = ', l);
  readln
end.

@JiL777 · 15.01.2016, 01:45 **[ТС]**

работает , спасибо!
Теперь буду разбираться с кодом. еще раз спасибочки!!!

Новые блоги и статьи Все статьи Все блоги /
Загрузка PNG с альфа-каналом на SDL3 для Android: с помощью SDL_LoadPNG (без SDL3_image) 8Observer8 28.01.2026 Содержание блога SDL3 имеет собственные средства для загрузки и отображения PNG-файлов с альфа-каналом и базовой работы с ними. В этой инструкции используется функция SDL_LoadPNG(), которая. . .	Загрузка PNG с альфа-каналом на SDL3 для Android: с помощью SDL3_image 8Observer8 27.01.2026 Содержание блога SDL3_image - это библиотека для загрузки и работы с изображениями. Эта пошаговая инструкция покажет, как загрузить и вывести на экран смартфона картинку с альфа-каналом, то есть с. . .	влияние грибов на сукцессию anaschu 26.01.2026 Бифуркационные изменения массы гриба происходят тогда, когда мы уменьшаем массу компоста в 10 раз, а скорость прироста биомассы уменьшаем в три раза. Скорость прироста биомассы может уменьшаться за. . .	Воспроизведение звукового файла с помощью SDL3_mixer при касании экрана Android 8Observer8 26.01.2026 Содержание блога SDL3_mixer - это библиотека я для воспроизведения аудио. В отличие от инструкции по добавлению текста код по проигрыванию звука уже содержится в шаблоне примера. Нужно только. . .
Установка Android SDK, NDK, JDK, CMake и т.д. 8Observer8 25.01.2026 Содержание блога Перейдите по ссылке: https:/ / developer. android. com/ studio и в самом низу страницы кликните по архиву "commandlinetools-win-xxxxxx_latest. zip" Извлеките архив и вы увидите. . .	Вывод текста со шрифтом TTF на Android с помощью библиотеки SDL3_ttf 8Observer8 25.01.2026 Содержание блога Если у вас не установлены Android SDK, NDK, JDK, и т. д. то сделайте это по следующей инструкции: Установка Android SDK, NDK, JDK, CMake и т. д. Сборка примера Скачайте. . .	Использование SDL3-callbacks вместо функции main() на Android, Desktop и WebAssembly 8Observer8 24.01.2026 Содержание блога Если вы откроете примеры для начинающих на официальном репозитории SDL3 в папке: examples, то вы увидите, что все примеры используют следующие четыре обязательные функции, а. . .	моя боль iceja 24.01.2026 Выложила интерполяцию кубическими сплайнами www. iceja. net REST сервисы временно не работают, только через Web. Написала за 56 рабочих часов этот сайт с нуля. При помощи perplexity. ai PRO , при. . .

@JiL777 0 / 0 / 0 Регистрация: 03.12.2015 Сообщений: 23

	Найти значение выражения 11.01.2016, 19:09. Показов 1210. Ответов 6 Метки нет (Все метки) Даны натуральные числа N, М . Целые числа а1..аn, b1....bm, c1.....c30. Получить: $https://www.cyberforum.ru/cgi-bin/latex.cgi?<br /> l=\begin{cases}\min \left( b_1,\,...,\,b_m\right)+\min \left(c_1,\,...,\,c_{30} \right) & \text{, if } \begin{vmatrix}\min \left( a_1,\,...,\,a_n\right)\end{vmatrix}\,>\,10 \\\\ 1+\left( \max \left(c_1,\,...,\,c_{30} \right)\right)^3 & \text{, otherwise }\end{cases}<br />$ Необходимо использовать процедуры (подпрограмы). 0

@JiL777 0 / 0 / 0 Регистрация: 03.12.2015 Сообщений: 23
	14.01.2016, 04:05 [ТС]
	44 строчка кода пишет : неправельный тип параметров подпрограммы 0

@JiL777 0 / 0 / 0 Регистрация: 03.12.2015 Сообщений: 23
	15.01.2016, 01:45 [ТС]
	работает , спасибо! Теперь буду разбираться с кодом. еще раз спасибочки!!! 0

Найти значение выражения

Решение