Блок-схемы

// подключаем модули
Uses graphabc, events,CRT;
 
// задаем массив строк пунктов меню
const vybor:array[1..5] of string=('1 - О программе',
                                   '2 - I уровень сложности',
                                   '3 - II уровень сложности',
                                   '4 - III уровень сложности',
                                   '5 - Выход');
var hUp,i,x,y,r,Speed,SpeedX,SpeedY,MinSpeed: integer; // переменные скоростей и положения шарика
    State: integer; // состояние
    k:byte; // номер пункта меню
 
// процедура "о программе"
Procedure DoAbout;
begin
  // очищаем экран
  ClrScr;
  TextOut(150,40,'"Шары". Автор: 123, 2016');
  SetFontSize(20);
  TextOut(40,80,'Как играть?');
  SetFontSize(12);
  TextOut(40,110,'Управление производится стрелками "вверх", "вниз".');
  TextOut(40,130,'Для продолжения игры после проигрыша необходимо по-');
  TextOut(40,150,'дождать 5 секунд, после чего вы попадёте в меню.');
  ReadKey;
end;
// процедура работы с меню
procedure Menu(var k:byte;kol:byte);
var kod: char;
    i:byte;
begin
 // очищаем экран
 Clrscr;
 k:=1;
 // переходим к краю экрана
 GotoXY(1,1);
 // в цикле движемся по пунктам
 Repeat
  For i:=1 to kol do
   begin
     // если выбраннный пункт меню, то рисуем его активным цветом
     if i=k then
      begin
         TextBackGround(2);
         TextColor(1);
      end
     else
      // если невыбранный пункт меню, то рисуем его пассивным цветом
      begin
         TextBackGround(7);
         TextColor(0)
      end;
     GotoXY(1,i);
     // выводим текст пункта меню
     Write(vybor[i]);
   end;
  Writeln;
  // задаем цвет фона
  TextBackGround(15);
  // выводим подсказку
  Writeln('Выбор пункта меню клавиша Enter');
  // считываем код нажатой клавиши пока не будет нажата стрелка или Enter
  Repeat
    kod:=ReadKey;
  Until kod in [#13, #72, #80];
  // выбираем код из возможных
  Case Kod of
     #72: begin  {стрелка вверх}
            // переходим к предыдущему пункту
            k:=k-1;
            if k=0 then k:=kol;{если верхний край, вниз}
          end;
     #80: begin  {стрелка вниз}
            // переходим к следующему пункту
            k:=k+1;
            if k>kol then k:=1;{если нижний край, вверх}
          end;
    end;
 until kod=#13; {Enter -выход}
end;
 
// обработка клавиш в игре нажатых
procedure Keys(Key:integer);
begin
  case Key of
    // вверх  - смещаем ячейку вверх на 20 пикселей
    VK_UP:  if hUp>10 then hUp := hUp-20 ;
    // вниз - смещаем вниз на 20 пикселей
    VK_Down: if hUp<410 then hUp := hUp+20;
    // Esc - выход
     VK_Escape: halt;
  end;
end;
 
// процедура генерации скоростей по Х и У
Procedure GenSpeed;
var count,YEnd,Sp:integer;
begin
  Repeat
    Randomize;
    // генерируем скрорость по оси Х
    SpeedX:=Random(3)+MinSpeed;
    // генерируем скорость по оси У
    SpeedY:=Random(MinSpeed+3);
    // считаем общую скорость
    Sp:=Round(Sqrt(SpeedX*SpeedX+SpeedY*SpeedY));
    Count:=(370-10) div SpeedX;
    // считаем куда в итоге попадет шарик и будет ли это левая стенка
    YEnd:=50+SpeedY*Count;
  // повторяем пока не попадем в левую стенку с заданной скоростью на данном уровне
  Until (YEnd>=25) and (YEnd<=455) ;
end;
 
// процедура новой игры
Procedure NewGame(Level:integer);
    // текст уровня, скорости и числа пойманых шариков
var LevStr,SpeedStr, CountStr,BallStr: String;
    BallCount,m,CountB: integer;
begin
 // очищаем экран
 ClrScr;
 // рисуем игровое поле
 Line(10,470,400,470);
 Line(400,10,400,470);
 hUp:=10; // начальное положение ячеки по У
 State:=0; // состояние
 x:=370; y:=50; // координаты появления шарика
 r:=12; // радиус шарика
 CountB:=0; // количество пойманых шариков
 // выводм количество пойманых шариков
 Str(CountB,CountStr); TextOut(570,60,CountStr);
 // исходя из уровня задаем число шариков на уровне и скорость
 Case Level of
   1: begin Speed:=5; BallCount:=3; end;
   2: begin Speed:=7; BallCount:=5; r:=15; end;
   3: begin Speed:=8; BallCount:=999; r:=17; end;
 end;
 // считаем минимальную скорость по оси Х
 MinSpeed:=Speed-2;
 // генерируем скорости по осям Х и У
 GenSpeed;
 // выводим уровень и текущую скорость и пойманные шары
  Str(Level,LevStr); TextOut(420,20,'Уровень:');
 TextOut(510,20,LevStr);
 Str(Speed,SpeedStr); TextOut(420,40,'Скорость:');
 TextOut(520,40,SpeedStr);
 TextOut(420,60,'Поймано шаров:');
 TextOut(420,80,'Шаров осталось:');
 Str(BallCount,BallStr); TextOut(580,80,BallStr);
 // основной цикл игры
  Repeat
    // перехватываем нажатие клавиш
    OnKeyDown:=Keys;
    // задаем цвет белый
    SetPenColor(clWhite); SetBrushColor(clWhite);
    // задержка
    Delay(50);
    // рисуем белым левую стенку и шарик - очищаем от предыдущего шага
    Line(10,0,10,480); Circle(x,y,r);
    // задаем цвет черный
    SetPenColor(clBlack);
    // рисуем ячейку в нужном месте
    Line(10,10,10,hUp); Line(10,470,10,hUp+60);
    // смещаем шарик в новое место
    x:=x-SpeedX; y:=y+SpeedY;
    // задаем цвет шарика в зависимости от уровня
    Case Level of
      1: begin SetPenColor(clRandom); SetBrushColor(clRandom); end;
      2: begin SetPenColor(clGreen); SetBrushColor(clYellow); end;
      3: begin SetPenColor(clBlack); SetBrushColor(clPurple); end;
    end;
    // рисуем шарик
    Circle(x,y,r);
    // если дошли до левого края
    if x<10 then
      begin
        // если попали
        if (y-r>=hUp) and (y+r<=hUp+60) then
          begin
           // очищаем последнее положение шарика
           SetPenColor(clWhite); SetBrushColor(clWhite);
           Circle(x,y,r);
           // переводим шарик в начальное положение
           x:=370; y:=50;
           // генерируем новую скорость по Х и У
           GenSpeed;
           //уменьшаем число шаров до конца уровня
           Dec(BallCount);
           // увеличиваем число пойманных шаров и выводим его
           Inc(CountB); Str(CountB,CountStr); TextOut(570,60,CountStr);
           Str(BallCount,BallStr); TextOut(580,80,BallStr);
           // если набрали достаточное число шариков, то переходим на следующий уровень
           if BallCount=0  then NewGame(Level+1);
          end
        else
          // если не поймали
          if (y-r<hUp) or (y+r>hUp+60) then
          begin
            // очищаем последнее положение шарика
            SetPenColor(clWhite); SetBrushColor(clWhite);
            Circle(x,y,r);
            // задаем размер шрифта и цвет
            SetFontSize(24);
            SetPenColor(clBlack);
            // закрашиваем левую стенку
            Line(10,10,10,470);
            // выводим сообщение
            TextOut(120,200,'GAME OVER');
            // ожидаем нажатия клавиши
            Readkey;
            // отмечаем, что игрок проиграл
            State:=1;
            SetFontSize(12);
             // задержка 5 сек
            delay(5000);
            ClearWindow;
          end;
      end;
  Until State=1;
end;
 
// процедура показа меню
Procedure MenuShow;
begin
  // очищаем экран
  ClrScr;
  repeat
   // задаем размер шрифта
   SetFontSize(12);
   Menu(k,5);{выводим меню}
   case k of{выбираем стрелками действие}
     1:DoAbout;
     2:NewGame(1);
     3:NewGame(2);
     4:NewGame(3);
     5: begin
          State:=1;
          Halt; // завершение программы
        end;
   end;
  until k=5;
end;
 
begin
  // задаем разрешение окна
  SetWindowWidth(640);
  SetWindoWheight(480);
  // показываем меню
  MenuShow;
  // завершение программы
  Readln;
end.