Программа вычисления значения выражения с использованием подпрограмм. Что не так?

@UNAVXZ · Регистрация: 04.12.2016

Студворк — интернет-сервис помощи студентам

Для организации вычислений по заданной формуле составить программу с использованием функции или подпрограммы.Для этого в фомуле выявить вычисления,подобные по своей схеме,т.е. различающиеся только объектами операций t=(1/x+1/x²+1/x³+1/x⁴+1/x⁵+1/x⁶+p)/(2b-c-c²-c³-c⁴-c⁵-20).

Pascal
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
Program ABC;
uses crt;
var p,b,c,x, t,r,z: real;
n:integer;
procedure k(var r:real;n:integer;x:real);
begin
for n:=1 to 6 do
r:=1/(exp(n)*ln(x));
end;
 procedure m(var z:real;n:integer);
begin
for n:=1 to 5 do
z:=exp(n)*ln(c);
end;
 begin
writeln('Введите x,p,b,c');
readln(x,p,b,c);
k(x,n,r);
m(c,n,z);
t:=r+p/2*b-z-20;
writeln(t:);
readln;
end.

@Cyborg Drone · 10.12.2016, 14:47

Очень много ошибок. Исправленная программа, сравнивайте:

Pascal
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
procedure k(var y:real; x:real);
var n: integer;
begin
  y := 0;
  for n := 1 to 6 do y := y + 1 / (exp(n * ln(x)))
end;
 
procedure m(var y: real; x:real);
var n: integer;
begin
  y := 0;
  for n := 1 to 5 do y := y + exp(n * ln(x))
end;
 
var p, b, c, x, t, r, z: real;
begin
  writeln('Введите x, p, b, c');
  readln(x, p, b, c);
  k(r, x);
  m(z, c);
  t := (r + p) / (2 * b - z - 20);
  writeln('t = ', t);
  readln
end.

Описание глобальных переменных до подпрограмм, и тем более использование глобальных переменных в подпрограммах - это дурной тон, и делать такое следует только в случае крайней необходимости, поскольку это чревато плохо обнаруживаемыми ошибками. Возведение в целочисленную степень с помощью логарифмирования и потенцирования не есть хорошо. К тому же, суммы степеней удобнее вычислять с применением рекуррентного соотношения. И функцию здесь применить удобнее, чем процедуру. Например, так:

Pascal
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
function sum(x:real; n: integer): real;
var i: integer;
    a, s: real;
begin
  a := x;
  s := a;
  for i := 2 to n do
    begin
      a := a * x;
      s := s + a
    end;
  sum := s
end;
 
var p, b, c, x: real;
begin
  writeln('Введите x, p, b, c');
  readln(x, p, b, c);
  writeln('t = ', (p + sum(1/x, 6)) / (2 * b - sum(c, 5) - 20));
  readln
end.

Или так:

Pascal
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
function sum(y, z, x:real; n: integer): real;
var i: integer;
    a, s: real;
begin
  a := x;
  s := a;
  for i := 2 to n do
    begin
      a := a * x;
      s := s + a
    end;
  sum := y + z * s
end;
 
var p, b, c, x: real;
begin
  writeln('Введите x, p, b, c');
  readln(x, p, b, c);
  writeln('t = ', sum(p, 1, 1/x, 6) / sum(2 * b - 20, -1, c, 5));
  readln
end.

Новые блоги и статьи Все статьи Все блоги /
SDL3 для Web (WebAssembly): Реализация движения на Box2D v3 - трение и коллизии с повёрнутыми стенами 8Observer8 20.02.2026 Содержание блога Box2D позволяет легко создать главного героя, который не проходит сквозь стены и перемещается с заданным трением о препятствия, которые можно располагать под углом, как верхнее. . .	Конвертировать закладки radiotray-ng в m3u-плейлист damix 19.02.2026 Это можно сделать скриптом для PowerShell. Использование . \СonvertRadiotrayToM3U. ps1 <path_to_bookmarks. json> Рядом с файлом bookmarks. json появится файл bookmarks. m3u с результатом. # Check if. . .	Семь CDC на одном интерфейсе: 5 U[S]ARTов, 1 CAN и 1 SSI Eddy_Em 18.02.2026 Постепенно допиливаю свою "многоинтерфейсную плату". Выглядит вот так: https:/ / www. cyberforum. ru/ blog_attachment. php?attachmentid=11617&stc=1&d=1771445347 Основана на STM32F303RBT6. На борту пять. . .	Камера Toupcam IUA500KMA Eddy_Em 12.02.2026 Т. к. у всяких "хикроботов" слишком уж мелкий пиксель, для подсмотра в ESPriF они вообще плохо годятся: уже 14 величину можно рассмотреть еле-еле лишь на экспозициях под 3 секунды (а то и больше),. . .
И ясному Солнцу zbw 12.02.2026 И ясному Солнцу, и светлой Луне. В мире покоя нет и люди не могут жить в тишине. А жить им немного лет.	«Знание-Сила» zbw 12.02.2026 «Знание-Сила» «Время-Деньги» «Деньги -Пуля»	SDL3 для Web (WebAssembly): Подключение Box2D v3, физика и отрисовка коллайдеров 8Observer8 12.02.2026 Содержание блога Box2D - это библиотека для 2D физики для анимаций и игр. С её помощью можно определять были ли коллизии между конкретными объектами и вызывать обработчики событий столкновения. . . .	SDL3 для Web (WebAssembly): Загрузка PNG с прозрачным фоном с помощью SDL_LoadPNG (без SDL3_image) 8Observer8 11.02.2026 Содержание блога Библиотека SDL3 содержит встроенные инструменты для базовой работы с изображениями - без использования библиотеки SDL3_image. Пошагово создадим проект для загрузки изображения. . .