Сложение двух чисел, имеющих тип string

const
  n=1000;{максимальная разрядность}
 
type
  big = record
    v: array[1..n] of byte;
    m: integer
  end;
 
function TruncBig(a: big): big;
var
  i, p, n: integer;
begin
  n := a.m;
  p := 0;
  while (p < n) and (a.v[p + 1] = 0) do p := p + 1;
  for i := 1 to n - p do Result.v[i] := a.v[i + p];
  Result.m := n - p
end;
 
function Str2Big(s:string): big;
var
  i, n, k, err: integer;
begin
  n := Length(s);
  Result.m := n;
  for i := 1 to n do 
  begin
    Val(s[i], k, err);
    Result.v[i] := k
  end
end;
 
function Big2Str(p: big; truncation:boolean): string;
var
  i, n: integer;
  c, s: string;
begin
  s := '';
  n := p.m;
  for i := 1 to n do
  begin
    Str(p.v[i], c);
    s := s + c
  end;
  if truncation then begin
    i := 0;
    while (s[i + 1] = '0') and (i < n) do i := i + 1;
    if i > 0 then s := Copy(s, i + 1, n - i)
  end;
  Result := s
end;
 
procedure AlignBig(var a, b: big);
var
  i, na, nb, n: integer;
begin
  na := a.m; nb := b.m; n := abs(na - nb);
  if a.m > b.m then begin
    for i := b.m downto 1 do b.v[i + n] := b.v[i];
    for i := 1 to n do b.v[i] := 0;
    b.m := a.m
  end
  else begin
    for i := a.m downto 1 do a.v[i + n] := a.v[i];
    for i := 1 to n do a.v[i] := 0;
    a.m := b.m
  end
end;
 
function AddBig(var a, b: big): big;
var
  j, k, n, s: integer;
begin
  AlignBig(a, b);
  n := a.m; k := 0;
  for j := n downto 1 do 
  begin
    s := a.v[j] + b.v[j] + k;
    Result.v[j] := s mod 10;
    k := s div 10
  end;
  if k <> 0 then begin
    for j := n downto 1 do Result.v[j + 1] := Result.v[j];
    Result.v[1] := k;
    Result.m := n + 1
  end
  else Result.m := n
end;
 
var
  a, b: big;
  s: string;
 
begin
  a := Str2Big('1000000000000000000000000000000000');
  b := Str2Big('50000000070605040302010');
  Writeln(Big2Str(AddBig(a,b),True))
end.