В двумерном массиве поменять местами два последних нечётных элемента

type index = record ip, jp: byte end; //тип для массива индексов
const n = 5; //размерность массива
label ex; //метка
var a: array[1..n, 1..n] of integer; //массив
    q: array[1..2] of index; //массив индексов для двух элементов
    i, j, k: byte; //счётчики
    t: integer; //буферная переменная
begin
  randomize;
  writeln('Исходный массив:');
  for i := 1 to n do //генерируем и печатаем массив
    begin
      for j := 1 to n do
        begin
          a[i, j] := -99 + random(199); //диапазон значений [-99..99]
          write(a[i, j]:4)
        end;
      writeln
    end;
  k := 2; //индекс массива индексов, пока указывает на последний элемент
  for i := n downto 1 do //сканируем матрицу "с конца"
    for j := n downto 1 do
      if odd(a[i, j]) //если нечётный,
        then begin //то
          q[k].ip := i; //запоминаем индексы массива
          q[k].jp := j;
          dec(k); //смещаем индекс массива индексов на 1
          if k = 0 then goto ex //если записали два элемента, то досрочно выходим из обеих циклов
        end;
  ex: //выход из двух и более вложенных циклов иногда проще сделать с goto
  case k of //в зависимости от индекса массива индексов
    0:  begin //если 0, то
          writeln('Последние два нечётных элемента массива:'); //выводим два последних нечётных
          for i := 1 to 2 do writeln('A[', q[i].ip, ', ', q[i].jp, '] = ', a[q[i].ip, q[i].jp]);
          t := a[q[1].ip, q[1].jp]; //меняем местами два последних нечётных
          a[q[1].ip, q[1].jp] := a[q[2].ip, q[2].jp];
          a[q[2].ip, q[2].jp] := t;
          writeln('Преобразованный массив:'); //печатаем массив
          for i := 1 to n do
            begin
              for j := 1 to n do write(a[i, j]:4);
              writeln
            end
        end;
    1:  writeln('Массив содержит только один нечётный элемент: A[', q[2].ip, ', ', q[2].jp, '] = ', a[q[2].ip, q[2].jp]);
    else writeln('Массив не содержит нечётных элементов') //если k=2, то в q ничего не писалось
  end;
  readln
end.