Динамические структуры данных

type
  T = integer;
 
type
  TNode = class
  public
    Value: T;
    Next: TNode;
    
    constructor Create(value: T; next: TNode);
    begin
      self.Value := value;
      self.Next := next;
    end;
    
    constructor Create(value: T);
    begin
      Create(value, nil);
    end;
  end;
  
type
  TStack = class
  private
    head: TNode;
    count: integer;
 
  public
    function GetHead: TNode;
    begin
      Result := head;
    end;
    
    function GetCount: integer;
    begin
      Result := count;
    end;
    
    procedure Push(x: T);
    var
      node: TNode;
 
    begin
      node := TNode.Create(x, head);
      head := node;
      Inc(count);
    end;
    
    function Pop: T;
    begin
      if count = 0 then
        raise EInvalidOp.Create();
 
      Result := head.Value;
      head := head.Next;
      Dec(count);
    end;
  end;
 
var
  S: TStack;
  i: integer;
  
begin
  S := TStack.Create();
  
  for i := -1 to 8 do
    S.Push(i);
 
  Writeln('Количество элементов равно ', S.GetCount());
  
  for i := 0 to 9 do
    Writeln(S.Pop());
end.