Требуется переставить цифры числа так, чтобы полученное число было минимально возможным

var
  d: array['0'..'9'] of integer; {массив количества соответствующих цифр}
  min, c: char; {минимальная цифра, счётчик для массива d}
  s: string; {входная строка}
  i: integer; {счётчик}
 
begin
  readln(s); {читаем строку}
  min := succ('9'); {назначаем минимум больший, чем максимальная по значению цифра}
  for i := 1 to length(s) do {цикл по всем символам строки}
    if s[i] in ['0'..'9'] {если очередной символ строки - цифра,}
      then begin {то}
        if (s[i] > '0') and (s[i] < min) {если цифра в диапазоне ['1'..(min-1)]}
          then min := s[i]; {то минимум равен текущему символу}
        inc(d[s[i]]) {подсчитываем количество конкретных цифр}
      end;
  if (min > '9') and (d['0'] = 1) {если минимум не найден, и в строке встречен только один 0}
    then min := '0'; {то min = '0'}
  if (min <= '9') {если минимум найден,}
    then begin {то выводим число}
      writeln('YES'); {число найдено}
      write(min); {печатаем минимальную цифру}
      dec(d[min]); {и уменьшаем найденое количество минимальной цифры}
      for c := '0' to '9' do {печатаем остальные цифры в порядке возрастания}
        for i := 1 to d[c] do {каждую цифру столько раз, сколько она встретилась (кроме min, естественно)}
          write(c); {печать цифры}
      writeln {переход на новую строку после вывода всех цифр}
    end
    else writeln('NO') {число не найдено (либо цифр нет, либо найдены только нули (два или более))}
end.

function check(var t: string): boolean;
var i, z: integer;
begin
  z := 0;
  for i := length(t) downto 1 do
    if not(t[i] in ['0'..'9'])
      then delete(t, i, 1)
      else if t[i] = '0'
        then inc(z);
  check := (length(t) > z) or (length(t) = 1) and (z = 1)
end;
 
procedure sort(var t: string);
var i, j, k, min: integer;
    c: char;
begin
  for i := 1 to length(t) - 1 do
    begin
      min := i;
      for j := i + 1 to length(t) do
        if t[j] < t[min] then min := j;
      if min > i
        then begin
          c := t[i];
          t[i] := t[min];
          t[min] := c
        end
    end;
  for i := 1 to length(t) do
    if t[i] > '0'
      then begin
        c := t[1];
        t[1] := t[i];
        t[i] := c;
        break
      end
end;
 
var
  s: string;
  p: integer;
 
begin
  readln(s);
  p := pos('.', s);
  if p > 0 then delete(s, p, length(s) - p + 1);
  if check(s)
    then begin
      sort(s);
      writeln('YES');
      writeln(s)
    end
    else writeln('NO')
end.