Нужно исправить ошибку.Тип параметра или возвращаемого значения не может быть описанием записи или описанием массива

program DijkstraAlgorithm;
uses crt;
const V=6; inf=100000;
type vektor=array[1..V] of integer;
var start: integer;
const GR: array[1..V, 1..V] of integer=(
(0, 1, 4, 0, 2, 0),
(0, 0, 0, 9, 0, 0),
(4, 0, 0, 7, 0, 0),
(0, 9, 7, 0, 0, 2),
(0, 0, 0, 0, 0, 8),
(0, 0, 0, 0, 0, 0));
{алгоритм Дейкстры}
procedure Dijkstra(GR: array[1..V, 1..V] of integer; st: integer);
var count, index, i, u, m, min: integer;
distance: vektor;
visited: array[1..V] of boolean;
begin
m:=st;
for i:=1 to V do
begin
distance[i]:=inf; visited[i]:=false; 
end;
distance[st]:=0;
for count:=1 to V-1 do
begin
min:=inf;
for i:=1 to V do
if (not visited[i]) and (distance[i]<=min) then
begin
min:=distance[i]; index:=i;
end;
u:=index;
visited[u]:=true;
for i:=1 to V do
if (not visited[i]) and (GR[u, i]<>0) and (distance[u]<>inf) and
(distance[u]+GR[u, i]<distance[i]) then
distance[i]:=distance[u]+GR[u, i];
end;
write('Стоимость пути из начальной вершины до остальных:'); writeln;
for i:=1 to V do
if distance[i]<>inf then
writeln(m,' > ', i,' = ', distance[i])
else writeln(m,' > ', i,' = ', 'маршрут недоступен');
end;
{основной блок программы}
begin
clrscr;
write('Начальная вершина >> '); read(start);
Dijkstra(GR, start);
end.

program DijkstraAlgorithm;
uses
  crt;
const
  V = 6;
type
  TArr1 = array[1..V,1..V] of integer;
  TArr2 = array[1..V] of integer;
  TArr3 = array[1..V] of boolean;
 
{алгоритм Дейкстры}
procedure Dijkstra(GRr: TArr1; VV, st: integer);
const
  inf = 100000;
var
  count, index, i, u, m, min: integer;
  distance: TArr2;
  visited: TArr3;
begin
  m:= st;
  for i:= 1 to VV do
    begin
      distance[i]:= inf;
      visited[i]:= false;
    end;
  distance[st]:= 0;
  for count:= 1 to VV-1 do
    begin
      min:= inf;
      for i:= 1 to VV do
      if (not visited[i]) and (distance[i] <= min) then
        begin
          min:= distance[i];
          index:= i;
        end;
      u:= index;
      visited[u]:= true;
      for i:= 1 to VV do
        if (not visited[i]) and (GRr[u, i] <> 0) and (distance[u] <> inf) and
           (distance[u]+ GRr[u, i] < distance[i]) then
          distance[i]:= distance[u] + GRr[u, i];
    end;
  write('Стоимость пути из начальной вершины до остальных:');
  writeln;
  for i:= 1 to VV do
  if distance[i] <> inf then
    writeln(m,' > ', i,' = ', distance[i])
  else
    writeln(m,' > ', i,' = ', 'маршрут недоступен');
end;
{основной блок программы}
const
  GR: TArr1 =((0, 1, 4, 0, 2, 0),
              (0, 0, 0, 9, 0, 0),
              (4, 0, 0, 7, 0, 0),
              (0, 9, 7, 0, 0, 2),
              (0, 0, 0, 0, 0, 8),
              (0, 0, 0, 0, 0, 0));
var
  start: integer;
begin
  clrscr;
  write('Начальная вершина >> ');
  readln(start);
  Dijkstra(GR, V, start);
  Readln;
end.