Нужно найти и исправить ошибку

program z1;
const n=7;m=4;
var     P : array [1..4, 1..7] of integer;
    SV : array [1..4] of integer;
    SD : array [1..7] of integer;
    i,k, MV, MD : byte;
Procedure VVOD;
var i,k:byte;
    P : array [1..4, 1..7] of integer;
  begin
For i := 1 to m do
For k := 1 to n do  begin
write ('Bведите кол-во посетителей в ', i, '-ой группе,', k, '-ого дня:'); 
readln( P[ i, k]);    
P[ i, k]:= random(50);   
end; 
end;
 
Procedure SUM_1str;
var SV : array [0..4] of integer;
    P : array [1..4, 1..7] of integer;
    k,i:byte;
  Begin
    SV[i] := 0;
    For k:=1 to 7 do SV[i] := SV[i] + P[i,k];
  End; 
Procedure Sum_STR;
var i:byte;
  Begin
    For  i := 1 to 4 do SUM_1str;
  End;
Procedure SUM_1stl;
var SD : array [1..7] of integer;
    P : array [1..4, 1..7] of integer;
    i,k:byte;
  Begin
    SD[ k] := 0;
    For i :=1 to 4 do SD[ k] := SD[ k] + P[i,k];
  End; 
Procedure Sum_STL;
var k:byte;
  Begin
    For k := 1 to 7 do SUM_1stl;
  End;
Procedure N_MIN_STL;
var SD : array [1..7] of integer;
    i,k,MD : byte;
  Begin
    MD:=1;
    For k:=2  to 7 do   if  SD[ k] < SD[ MD]  
    then  MD := k;
  End;
Procedure N_MAX_STR;
var SV : array [1..4] of integer;
      i,k, MV: byte;
  Begin
    MV := 1;
    For i :=2 to 4  do  if  SV [ i] > SV [MV] 
    then MV := i ;
  End;
Procedure VYVOD;
var P : array [1..4, 1..7] of integer;
      SV : array [1..4] of integer;
      SD : array [1..7] of integer;
      i,k, MV, MD : byte;
  Begin
    Writeln ('Кол-во посетителей' :30,'Всего' :25);
    For i := 1 to m do          begin
    For k := 1 to n do  write( P[i, k] :5 );  
    Writeln ( SV [ i] :10);     end;
    Writeln;
    For k := 1 to n do  write( SD [ k] :5 );
    writeln;
    For i:=1 to m do if SV[i] = SV[MV] then writeln ('Возрастная группа - ', i );
    For k := 1 to n do if SD [k] = SD [MD]  then writeln ('День недели - ', k);
  End;
begin
  VVOD;
  Sum_STR;
  Sum_STL;  
  N_MIN_STL;    
  N_MAX_STR;     
  VYVOD; 
  readln; 
end.

readln( P[ i, k]);    
P[ i, k]:= random(50);

program z1;
uses
  CRT;
const
  nmax = 7;
  mmax = 4;
 
type
  TV = array [1..4, 1..7] of integer;
  TSG = array [1..4] of integer;
  TSD = array [1..7] of integer;
 
 
Procedure VVOD(var PP: TV; m,n: byte);
{Процедура для ввода данных в двумерный массив}
var
  i,k: byte;
    Pv: TV;
begin
  For i:= 1 to m do
    For k:= 1 to n do
      begin
       { write ('Bведите кол-во посетителей в ', i, '-ой группе,', k, '-ого дня: ');
         readln( Pv[i,k]); }
        Pv[i,k]:= random(50);
      end;
  PP:= Pv;
end;
 
 
Procedure SumVisitorGroup(PP: TV; m,n: byte; var SSG: TSG);
{Процедура для суммирования посетителей по группам}
var
  SG: TSG;
  k,i: byte;
Begin
  For i:= 1 to m do
    begin
      SG[i]:= 0;
      For k:= 1 to n do
        SG[i]:= SG[i] + PP[i,k];
    end;
  SSG:= SG;
End;
 
 
Procedure SumVisitorDay(PP: TV; m,n: byte; var SSD: TSD);
{Процедура для суммирования посетителей по дням}
var
  SD: TSD;
  k,i: byte;
  Begin
    For k:= 1 to n do
      begin
        SD[k]:= 0;
        For i:= 1 to m do
          SD[k]:= SD[k] + PP[i,k];
      end;
  SSD:= SD;
  End;
 
 
Function CommonSumVisitor(PP: TV; m,n: byte): integer;
{Функция для подсчета общего количества посетителей}
var
  i,k: byte;
  s: integer;
Begin
  s:= 0;
  For i:= 1 to m do
    For k:= 1 to n do
      s:= s + PP[i,k];
  CommonSumVisitor:= s;
End;
 
 
Function NumberMaxVisitorGroup(SSG: TSG; m: byte): integer;
{Функция для нахождения номера группы с наибольшим количеством посетителей}
var
  k, Number: byte;
  Maxvalue: integer;
Begin
  Maxvalue:= SSG[1];
  Number:= 1;
  For k:= 2  to m do
    if  Maxvalue < SSG[k] then
      begin
        Maxvalue:= SSG[k];
        Number:= k
      end;
  NumberMaxVisitorGroup:= Number;
End;
 
 
Function NumberMinVisitorDay(SSD: TSD; n: byte): integer;
{Функция для нахождения номера дня с наименьшим количеством посетителей}
var
  k, Number: byte;
  Minvalue: integer;
Begin
  Minvalue:= SSD[1];
  Number:= 1;
  For k:= 2  to n do
    if  Minvalue > SSD[k] then
      begin
        Minvalue:= SSD[k];
        Number:= k
      end;
  NumberMinVisitorDay:= Number;
End;
 
 
Procedure VYVOD(PP: TV; m,n: integer; SSG: TSG; SSD: TSD);
{Процедура для вывода информации в консоль}
var
  i,k: byte;
 
Begin
  clrscr;
  Writeln ('Группы посетителей' :28,'ПН':5,'ВТ':5,'СР':5,'ЧТ':5,'ПТ':5,'СБ':5,'ВС':5, 'ВСЕГО' :8);
  writeln;
  For i := 1 to m do
    begin
      textcolor(7);
      case i of
      1: write('1.':3, 'Старшеклассники':25);
      2: write('2.':3, 'Студенты':25);
      3: write('3.':3, 'Молодые специалисты':25);
      4: write('4.':3, 'Специалисты со стажем':25);
      end;
      For k := 1 to n do
        write( PP[i,k]:5 );
      textcolor(11);
      Write(SSG[i]:8);
      Writeln;
    end;
  writeln;
  textcolor(7);
  write('   ВСЕГО':28);
  textcolor(10);
  For k:= 1 to n do
    write(SSD[k]:5);
  writeln;
  writeln;
  textcolor(7);
  writeln('Общее количество посетителей: ', CommonSumVisitor(PP,m,n));
  writeln('Номер возрастной группы, проявившей наибольший интерес: ', NumberMaxVisitorGroup(SSG,m));
  writeln('Номер дня, наплыв посетителей в который было наименьшим: ', NumberMinVisitorDay(SSD,n));
End;
 
 
 
var
  P: TV;  { Переменная для хранения массива с начальными данными по количеству посетителей}
  SG: TSG;  { Переменная для хранения массива с данными по сумме посетителей по группам}
  SD: TSD;   { Переменная для хранения массива с данными по сумме посетителей по дням}
 
begin
  randomize;
  VVOD(P,mmax,nmax);
  SumVisitorGroup(P,mmax,nmax,SG);
  SumVisitorDay(P,mmax,nmax,SD);
  VYVOD(P,mmax,nmax,SG,SD);
  readln;
end.