Ввести арифметическое выражение с простыми дробями и выполнить действия

unit fraction;
interface
    type
        natur = 1..high(longint);
        frac = record
            p : longint; {числитель дроби}
            q : natur {знаменатель дроби}
     end;
 
procedure reduce(var a: frac);
procedure add(a, b: frac; var c: frac);
procedure dec(a, b: frac; var c: frac);
procedure mult(a, b: frac; var c: frac);
procedure division(a, b: frac; var c: frac);
procedure power(a: frac; n : natur; var c: frac);
 
{раздел реализации модуля}
implementation
 
{нахождение наибольшего общего делителя (нод) двух чисел - вспомогательная функция}
function nod(a, b: natur): natur;
begin
  while (a <> b) do
    if (a > b)
        then
            if (a mod b <> 0)
                then
                    a := (a mod b)
                else
                    a := b
        else
            if (b mod a <> 0)
            then
                b := (b mod a)
            else
                b := a;
    nod := a
end;
 
procedure reduce; {сокращение дроби}
var m, n : natur;
begin
   if (a.p <> 0)
   then begin
        if (a.p < 0)
            then
                m := abs(a.p)
            else
                m := a.p; {совмещение типов, т.к. a.p - longint}
        n := nod(m, a.q);
        a.p := a.p div n;
        a.q := a.q div n
   end
end;
 
procedure add; {сумма дробей}
begin
    c.q := (a.q * b.q) div nod(a.q, b.q);
    c.p := a.p * c.q div a.q + b.p * c.q div b.q;
    reduce(c)
end;
 
procedure dec; {разность дробей}
begin
    c.q := (a.q * b.q) div nod(a.q, b.q);
    c.p := a.p * c.q div a.q - b.p * c.q div b.q;
    reduce(c)
end;
 
procedure mult; {умножение дробей}
begin
    c.q := a.q * b.q;
    c.p := a.p * b.p;
    reduce(c)
end;
 
procedure division; {деление дробей}
begin
    c.q := a.q * b.p;
    c.p := a.p * b.q;
    reduce(c)
end;
 
procedure power; {возведение в степень}
var i : natur;
begin
    c.q := 1;
    c.p := 1;
    reduce(a);
    for i := 1 to n do
        mult(a, c, c)
end;
 
{раздел инициализации модуля}
begin
end.