Автоматический перевод с английского языка

program Translator;
uses DOS, CRT, RUSCP;
var
 f: text;
 ch: char;
 r: registers;
 word_eng: string;
 
 procedure InitMouse;
  begin
   r.ax:=0;
   intr($33,r);
   if r.ax <> $FFFF
    then
     begin
      writeln('The mouse did not find.');
      Halt(1);
     end;
   writeln('The mouse found.');
   r.ax:=1;
   intr($33,r);
  end;
 
 procedure AssignDictionary;
  begin
   Assign(f,'slovar.txt');
  end;
 
 procedure SetExampleString;
  begin
   writeln('wrestler thrift plaid rap.');
  end;
 
 procedure GetWordEng;
  var
   x,y: word;
   entry: boolean;
   symb,exit: char;
   marks_punct: set of char;
 
  begin
   entry:=true;
   marks_punct:=[' ',',','.','!','?','-','(',')'];
   repeat
    r.ax:=3;
    intr($33,r);
    if r.bx and 1 <> 0 then
     begin
      x:=r.cx div 8;
      y:=r.dx div 8;
      r.ax:=2;
      intr($33,r);
 
      exit:=chr(Mem[SegB800:y*160+x*2]);
 
      symb:='1';
      while not (symb in marks_punct) do
       begin
        Dec(x);
        symb:=chr(Mem[SegB800:y*160+x*2]);
       end;
 
      Inc(x);
      symb:='1';
      word_eng:='';
      while not (symb in marks_punct) do
       begin
        if symb <> '1' then word_eng:=word_eng+symb;
        symb:=chr(Mem[SegB800:y*160+x*2]);
        Inc(x);
       end;
 
      if (entry = true) and not(exit in marks_punct)
       then
        begin
         entry:=false;
         writeln(word_eng);
        end;
 
      r.ax:=1;
      Intr($33, r);
     end;
   until (r.bx and 2 <> 0) or (entry = false);
  end;
 
 procedure SearchTranslation;
  var
   i: byte;
   symb: char;
   flag: boolean;
   word,str: string;
  begin
   Reset(f);
   flag:=false;
   while not Eof(f) do
    begin
     i:=1;
     word:='';
     readln(f,str);
 
     while str[i] <> ' ' do
      begin
       word:=word+str[i];
       Inc(i);
      end;
 
     if word = word_eng
      then
       begin
        str:=WIN1251toOEM866(str);
        writeln(str);
        flag:=true;
        Close(f);
        Break;
       end;
    end;
 
   if flag = false
    then
     begin
      Close(f);
      writeln('The word did not find in the dictionary.');
     end;
  end;
 
begin
 ClrScr;
 InitMouse;
 SetExampleString;
 AssignDictionary;
 writeln('Fix the mouse over a word and press the left buttom to translate.');
 repeat
  GetWordEng;
  SearchTranslation;
  writeln('Please, press <Enter> to continue or press <Esc> to exit.');
  ch:=ReadKey;
 until ch = #27;
end.