Графика в языках программирования

@Маргарита13 · Регистрация: 01.12.2010

Студворк — интернет-сервис помощи студентам

1. Изобразить движение маятника.
2. Изобразить пароход и закрасить его отдельные элементы различными цветами
А) Составить процедуры рисования фигур.
Б) Разделить графический экран с использованием
заливки на 8 областей разного цвета.
4. Построить график функции y=5x2+3x-7 на отрезке [-4,16].
Рисунки с заданиями в архивеИзобразить движение маятника.rar. Все эти задания необходимо написать на Паскаль АВС. Помогите пожалуйста! Заранее спасибо)

@Маргарита13 · 04.04.2012, 17:58 **[ТС]**

Помогите пожалуйста... очень надо(

@Puporev · 04.04.2012, 18:17

Маятник.

Pascal
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
uses graphABC;
//рисование маятника
procedure M(xc,yc,x1,y1:integer);
begin
setbrushstyle(bsSolid);
setbrushcolor(clBlack);
line(xc,yc,x1,y1);
circle(xc,yc,2);
circle(x1,y1,4);
end;
var xc,yc,d,x1,y1:integer;
    u,du,a:real;
begin
xc:=windowwidth div 2;
yc:=50;
d:=150;
x1:=xc;
y1:=yc+d;
u:=-pi/2;//начальное положение вертикально
du:=0.1;
a:=pi/4;//амплитуда
lockdrawing;
repeat
while u>=-pi/2-a do//ход влево
 begin
  clearwindow;
  u:=u-du;
  x1:=xc+round(d*cos(u));
  y1:=yc-round(d*sin(u));
  M(xc,yc,x1,y1);
  sleep(200);
  redraw;
 end;
while u<=-pi/2+a do //ход вправо
 begin
  clearwindow;
  u:=u+du;
  x1:=xc+round(d*cos(u));
  y1:=yc-round(d*sin(u));
  M(xc,yc,x1,y1);
  sleep(200);
  redraw;
 end;
a:=a-pi/20;//уменьшим амплитуду
until a<0;
clearwindow;//установим в начальное положение
UnlockDrawing;
M(xc,yc,xc,yc+d);
end.

@Маргарита13 · 04.04.2012, 19:13 **[ТС]**

помогите пожалуйста и с остальными задачками...

@Puporev · 05.04.2012, 10:23

2.Б 8 цветов.

Pascal
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
uses graphABC;
var x1,y1,x2,y2:integer;
begin
x1:=windowwidth div 2;
y1:=windowheight div 2;
setpencolor(clRed);
line(0,0,x1,y1);
line(x1,0,x1,y1);
line(0,0,x1,y1);
floodfill(10,5,clRed);
setpencolor(clBlue);
line(0,0,x1,y1);
line(0,y1,x1,y1);
line(0,0,0,y1);
floodfill(5,10,clBlue);
setpencolor(clGreen);
line(0,y1,x1,y1);
line(0,2*y1,x1,y1);
line(0,y1,0,2*y1);
floodfill(5,y1+10,clGreen);
setpencolor(clYellow);
line(0,2*y1,x1,y1);
line(0,2*y1,x1,2*y1);
line(x1,y1,x1,2*y1);
floodfill(10,2*y1-5,clYellow);
setpencolor(clPurple);
line(x1,0,2*x1,0);
line(x1,y1,2*x1,0);
line(2*x1,0,2*x1,y1);
floodfill(x1+10,5,clPurple);
setpencolor(clBrown);
line(x1,y1,2*x1,0);
line(x1,y1,2*x1,y1);
line(2*x1,0,2*x1,y1);
floodfill(x1+10,y1-5,clBrown);
setpencolor(clCream);
line(x1,y1,2*x1,y1);
line(x1,y1,2*x1,2*y1);
line(2*x1,y1,2*x1,2*y1);
floodfill(x1+10,y1+5,clCream);
setpencolor(clAqua);
line(x1,y1,2*x1,2*y1);
line(x1,y1,x1,2*y1);
line(2*x1,y1,2*x1,2*y1);
floodfill(x1+10,2*y1-5,clAqua);
end.

Добавлено через 6 минут
А-1.

Pascal
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
uses graphABC;
procedure Fig(x,y,r,c:integer);
begin
setpencolor(c);
line(x-r,y,x,y-r);
line(x,y-r,x+r,y);
line(x+r,y,x,y+r);
line(x,y+r,x-r,y);
end;
var x,y,r,i:integer;
begin
x:=100;
y:=windowheight div 2;
r:=50;
for i:=1 to 3 do
 begin
  Fig(x,y,r,clRed);
  x:=x+r;
 end;
end.

Добавлено через 7 минут
А-2.

Pascal
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
uses graphABC;
procedure Fig(x,y,r,c:integer;a:real);
var x1,y1,x2,y2,x3,y3,x4,y4,i:integer;
    u:real;
begin
u:=a;
x1:=x+round(r*cos(u));
y1:=y-round(r*sin(u));
u:=u+pi/2;
x2:=x+round(r*cos(u));
y2:=y-round(r*sin(u));
u:=u+pi/2;
x3:=x+round(r*cos(u));
y3:=y-round(r*sin(u));
u:=u+pi/2;
x4:=x+round(r*cos(u));
y4:=y-round(r*sin(u));
setpencolor(c);
line(x1,y1,x2,y2);
line(x2,y2,x3,y3);
line(x3,y3,x4,y4);
line(x4,y4,x1,y1);
end;
var x,y,r,i:integer;
begin
x:=windowwidth div 2;;
y:=windowheight div 2;
r:=100;
Fig(x,y,r,clRed,0);
Fig(x,y,r,clRed,pi/4);
end.

Добавлено через 1 минуту
На сегодня хватит, на тройку точно есть. Спать пора, завтра добавлю.

Добавлено через 10 часов 26 минут
Кстати деление на 8 частей я сделал как в Турбо Паскале, в АВС это проще делается.

Pascal
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
uses graphABC;
var x1,y1,x2,y2:integer;
begin
x1:=windowwidth div 2;
y1:=windowheight div 2;
rectangle(0,0,2*x1,2*y1);
line(0,0,2*x1,2*y1);
line(2*x1,0,0,2*y1);
line(x1,0,x1,2*y1);
line(0,y1,2*x1,y1);
floodfill(10,5,clRed);
floodfill(5,10,clBlue);
floodfill(5,y1+10,clGreen);
floodfill(10,2*y1-5,clYellow);
floodfill(x1+10,5,clPurple);
floodfill(x1+10,y1-5,clBrown);
floodfill(x1+10,y1+5,clCream);
floodfill(x1+10,2*y1-5,clAqua);
end.

Добавлено через 21 минуту
График функции.

Pascal
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
uses graphABC;
function F(x:real):real;
begin
F:=5*x*x+3*x-7;
end;
var x,mx,my,dx:real;
    x0,y0,xn,xk,i:integer;
    s:string;
begin
xn:=-4;xk:=16;{интервал по Х}
x0:=round(abs(xn)*windowwidth/(xk-xn));
mx:=(windowwidth-50)/(xk-xn);{масштаб по Х}
y0:=windowheight-80;
my:=(y0-30)/F(xk);
line(0,y0,windowwidth,y0);{оси}
line(x0,0,X0,windowheight);
for i:=1 to xk do{максимальное количество засечек в одну сторону}
  begin
    line(x0-3,y0-round(i*my*100),x0+3,y0-round(i*my*100));{засечки на оси У}
    line(x0-3,y0+round(i*my*100),x0+3,y0+round(i*my*100));
    {подпись оси У}
    str(i*100,s);
    textout(x0-35,y0-round(i*my*100),s);{соответственно засечкам}
    textout(x0-35,y0+round(i*my*100),'-'+s);
    line(x0+round(i*mx),y0-3,x0+round(i*mx),Y0+3); {засечки на оси Х}
    line(x0-round(i*mx),y0-3,x0-round(i*mx),Y0+3);
    {подпись оси Х}
    str(i,s);
    textout(x0+round(i*mx),y0+10,s);
    textout(x0-round(i*mx),y0+10,'-'+s);
  end;
{центр}
textout(x0+5,y0+10,'0');
{подписи концов осей}
textout(windowwidth-10,y0-10,'X');
textout(x0+5,10, 'Y');
{график}
x:=xn;
dx:=0.01;
setpencolor(clRed);
moveto(x0+round(x*mx),y0-round(F(x)*my));
while x<=xk do
 begin
 lineto(x0+round(x*mx),y0-round(F(x)*my));
  x:=x+dx;
 end;
{название}
setfontcolor(clRed);
setfontsize(12);
textout(x0+100,20,'Grafik functii y=5x^2+3x-7');
textout(x0+120,40,'na intervale [-4;16]');
end.

Добавлено через 1 час 23 минуты
Корабль.

Pascal
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
uses graphABC;
var xc,y1,x1,d,h,i:integer;
begin
xc:=windowwidth div 2;
y1:=windowheight-80;
h:=80;
d:=60;
ClearWindow(clSkyBlue);
//корпус
line(xc-3*d,y1-h,xc+3*d,y1-h);
line(xc-3*d,y1-h,xc-2*d,y1);
line(xc-2*d,y1,xc+3*d,y1);
line(xc+3*d,y1-h,xc+3*d,y1);
floodfill(xc+3*d-5,y1-5,clGray);
//якорное окно
setbrushstyle(bsClear);
setpenwidth(3);
circle(xc-2*d,y1-h div 2,5);
circle(xc-2*d,y1-h div 2,10);
line(xc-2*d,y1-h div 2+5,xc-2*d,y1-23);
line(xc-2*d-3,y1-25,xc-2*d+3,y1-25);
//первая палуба
y1:=y1-h;
setpenwidth(1);
rectangle(xc-2*d,y1-d,xc+2*d,y1);
floodfill(xc-2*d+5,y1-d+5,clWhite);
x1:=xc-2*d;
for i:=1 to 3 do
 begin
  circle(x1+i*d,y1-d div 2,8);
  floodfill(x1+i*d,y1-d div 2,clYellow);
 end;
//надстройка
y1:=y1-d;
rectangle(xc-d,y1-d,xc+d,y1);
floodfill(xc,y1-5,clLtGray);
y1:=y1-d;
h:=40;
//труба
line(xc-h,y1,xc,y1-h);
line(xc,y1-h,xc+h,y1-h);
line(xc+h,y1-h,xc+h,y1);
floodfill(xc+h-5,y1-5,clAqua);
line(xc-2*(h div 3),y1-h div 3,xc+h,y1-h div 3);
line(xc-h div 3,y1-2*(h div 3),xc+h,y1-2*(h div 3));
floodfill(xc+h-5,y1-h div 3-2,clWhite);
end.

@Маргарита13 · 05.04.2012, 17:50 **[ТС]**

Спасибки) буду ждать остальной части заданий)

@Puporev · 05.04.2012, 17:52

Сообщение от Маргарита13

буду ждать остальной части заданий)

Какой остальной? Глазки свои разуйте...

@Маргарита13 · 05.04.2012, 17:54 **[ТС]**

Спасибо большое*** очень помогли*

Добавлено через 1 минуту

Сообщение от Puporev

Какой остальной? Глазки свои разуйте...

у меня по ходу браузер тупит(( только что увидела) спасибо большое)

Комментарий модератора

Если какой-либо пост на форуме показался вам полезным, нажмите кнопку "Спасибо" внизу самого поста.

Новые блоги и статьи Все статьи Все блоги /
http://iceja.net/ сервер решения полиномов iceja 18.01.2026 Выкатила http:/ / iceja. net/ сервер решения полиномов (находит действительные корни полиномов методом Штурма). На сайте документация по API, но скажу прямо VPS слабенький и 200 000 полиномов. . .	Расчёт переходных процессов в цепи постоянного тока igorrr37 16.01.2026 / * Дана цепь постоянного тока с R, L, C, k(ключ), U, E, J. Программа составляет систему уравнений по 1 и 2 законам Кирхгофа, решает её и находит: токи, напряжения и их 1 и 2 производные при t = 0;. . .	Восстановить юзерскрипты Greasemonkey из бэкапа браузера damix 15.01.2026 Если восстановить из бэкапа профиль Firefox после переустановки винды, то список юзерскриптов в Greasemonkey будет пустым. Но восстановить их можно так. Для этого понадобится консольная утилита. . .	Сукцессия микоризы: основная теория в виде двух уравнений. anaschu 11.01.2026 https:/ / rutube. ru/ video/ 7a537f578d808e67a3c6fd818a44a5c4/
WordPad для Windows 11 Jel 10.01.2026 WordPad для Windows 11 — это приложение, которое восстанавливает классический текстовый редактор WordPad в операционной системе Windows 11. После того как Microsoft исключила WordPad из. . .	Classic Notepad for Windows 11 Jel 10.01.2026 Old Classic Notepad for Windows 11 Приложение для Windows 11, позволяющее пользователям вернуть классическую версию текстового редактора «Блокнот» из Windows 10. Программа предоставляет более. . .	Почему дизайн решает? Neotwalker 09.01.2026 В современном мире, где конкуренция за внимание потребителя достигла пика, дизайн становится мощным инструментом для успеха бренда. Это не просто красивый внешний вид продукта или сайта — это. . .	Модель микоризы: классовый агентный подход 3 anaschu 06.01.2026 aa0a7f55b50dd51c5ec569d2d10c54f6/ O1rJuneU_ls https:/ / vkvideo. ru/ video-115721503_456239114

@Маргарита13 0 / 0 / 0 Регистрация: 01.12.2010 Сообщений: 28

	Графика в языках программирования 04.04.2012, 17:33. Показов 4540. Ответов 7 Метки нет (Все метки) 1. Изобразить движение маятника. 2. Изобразить пароход и закрасить его отдельные элементы различными цветами А) Составить процедуры рисования фигур. Б) Разделить графический экран с использованием заливки на 8 областей разного цвета. 4. Построить график функции y=5x2+3x-7 на отрезке [-4,16]. Рисунки с заданиями в архивеИзобразить движение маятника.rar. Все эти задания необходимо написать на Паскаль АВС. Помогите пожалуйста! Заранее спасибо) 0

@Маргарита13 0 / 0 / 0 Регистрация: 01.12.2010 Сообщений: 28
	04.04.2012, 17:58 [ТС]
	Помогите пожалуйста... очень надо( 0

@Маргарита13 0 / 0 / 0 Регистрация: 01.12.2010 Сообщений: 28
	04.04.2012, 19:13 [ТС]
	помогите пожалуйста и с остальными задачками... 0

@Маргарита13 0 / 0 / 0 Регистрация: 01.12.2010 Сообщений: 28
	05.04.2012, 17:50 [ТС]
	Спасибки) буду ждать остальной части заданий) 0