Что нужно, чтобы работать с графикой

uses graph;
const
x1=-2;{начало и конец графика в реальных значениях}
x2=2;
function Y(x:real):real;{функция определяется вычислением суммы ряда }
var s,t:real;
    n:integer;
begin
s:=1;{начальное значение суммы}
t:=1;{нулевой член ряда}
n:=0;
while abs(t)>0.001 do {пока очередной член ряда больше 0.001,
                        можно взять другое значение}
 begin
  n:=n+1;{увеличиваем счетчик}
  t:=-t*x*x/n;{вычисляем очередной член ряда}
  s:=s+t;{прибавляем}
 end;
Y:=s;{значение функции}
end;
function Z(x:real):real;
begin
Z:=exp(-x*x)+4;{взял b=4, можно другое}
end;
var x0,y0:integer;{начало координат}
    grD,grM:integer;{переменные для инициализации граф. режима}
    px,py,i:integer;{экранные координаты точек графиков и счетчик циклов}
    mx,my:real;{масштабы по осям}
    x,dx,y1,y2,y3,y4:real;{реальные текущие координаты точек графиков}
    s,s1:string;{строки для вывода числовых значений на экран}
begin
grD:=detect;
initgraph(grD,grM,'');
x0:=getmaxX div 2;{начало координат в центре экрана}
y0:=getmaxY-50;
{коэффициенты по осям для перевода реальных координат в экранные}
mx:=(x0-30)/x2;{длина в пикселах по оси Х/реальная длина}
my:=(y0-60)/Z(0);{длина оси по У/(макс}
setbkcolor(15); {цвет фона}
setcolor(8);{цвет линий осей}
line(0,y0,getmaxX,y0); {ось Х}
line(x0,getmaxy,x0,0); {ось У}
for i:=1 to 10*trunc(x2)+1 do {максимальное количество засечек в одну сторону
                              = целой части значения Z при х=0 +1}
 begin
  line(x0-3,y0-round(i*my/2),x0+3,y0-round(i*my/2));{засечки на оси У}
  line(x0+round(i*mx/10),y0-3,x0+round(i*mx/10),y0+3); {засечки на оси Х}
  line(x0-round(i*mx/10),y0-3,x0-round(i*mx/10),y0+3);
  str(i/2:0:1,s);
  {подпись оси У}
  settextstyle(0,0,1);
  outtextXY(x0-30,y0-round(i*my/2),s);{соответственно засечкам}
  {подпись оси Х}
  settextstyle(0,1,1);
  str(i/10:0:1,s);
  if i mod 2=0 then
   begin
    outtextXY(x0+round(i*mx/10),y0+10,s);
    outtextXY(x0-round(i*mx/10),y0+10,'-'+s);
   end;
  end;
{центр}
settextstyle(0,0,1);
outtextXY(x0+5,y0+10,'0');
{подписи концов осей}
outtextXY(getmaxX-10,y0-10,'X');
outtextXY(x0+10,10, 'Y');
dx:=0.001;
{график}
x:=x1;
while x<=x2 do
   begin
     px:=x0+round(x*mx); {изменение по оси Х}
     y1:=Y(x); {график в реальных координатах}
     py:=y0-round(y1*my);{в экранных}
     putpixel(px,py,9);
     y2:=Z(x); {график в реальных координатах}
     py:=y0-round(y2*my);{в экранных}
     putpixel(px,py,5);
     x:=x+dx; {наращиваем х}
   end;
setlinestyle(0,0,1);
setcolor(9);
outtextXY(30,30,'Grafik functii Y=e^(-x^2)');
setcolor(5);
outtextXY(30,60,'Grafik functii Z=e^(-x^)+4');
readln
end.

x0:=getmaxX div 2;
y0:=getmaxY div 2;

x0:=getmaxX div 2;{начало координат по Х в центре экрана}
y0:=getmaxY-50;{по Y в нижней части экрана}