Serialport

#!/usr/bin/perl
  
# Подключим нужные модули
use LWP::Simple;
use Encode qw(from_to _utf8_off);
use Win32::SerialPort;
use Win32::API::Prototype;
use Win32::SystemInfo;
use Win32::DriveInfo;
use constant {IDLE => 0, KERNEL => 1, USER => 2};
  
# Подключим функцию из Win32 API
 InitWin32();
  
# Стартовое значение тиков
@lasttime = SystemTimes();
  
# Установим порт для коммуникаций с Arduino
$port = InitSerial();
  
# Цикл Мёбиуса
while (1) {
  
   # Формируем строку
   $data = sprintf("CPU: %3d%%  C: %03d Gb|MEM: %3d%%  D: %03d Gb|".
     "T: %02d'C      P: %03d|%02d %-8s    %02d:%02d|&",
     CPU(), Disk('C'), MEM(), Disk('D'), Weather('Moscow'), DateTime()
   );
  
   # Выводим в порт
   while ($data =~ s/(.)//s) {
     $port -> write($1);
     $port -> lookclear;
   }
  
   # Ожидание
   sleep(10);
}
 
sub InitSerial {
# Подключение и установка параметров порта
  my $port = Win32::SerialPort->new("COM3");
  $port -> baudrate(9600);
  $port -> databits(8);
  $port -> parity('none');
  $port -> stopbits(1);
  $port -> user_msg(ON);
  if (!$port -> write_settings) {
    undef $port;
    exit;
  }
  $SIG{'TERM'} = \&closePort;
  $port;
}
 
sub closePort {
# Правильное закрытие порта, выполняется при остановке программы
  $port -> close;
  undef $port;
}
 
sub CPU {
# Подсчёт использования CPU
  @nowtime = SystemTimes();
  @deltas = map { $nowtime[$_] - $lasttime[$_] } (IDLE, KERNEL, USER);
  $busy = $deltas[KERNEL] + $deltas[USER];
  $pcUsage = ($busy - $deltas[IDLE]) * 100 / ($deltas[IDLE] || 100e5);
  @lasttime = @nowtime;
  $pcUsage;
}
 
sub InitWin32 {
# Подключение функции Win32 API для запроса системных тиков
  ApiLink(
    'kernel32', q[
      BOOL GetSystemTimes(
        LPFILETIME lpIdleTime,
        LPFILETIME lpKernelTime,
        LPFILETIME lpUserTime
      )
    ]
  ) or die $^E;
}
 
sub SystemTimes {
# Немного уличной магии
  my($idleTicks, $kernelTicks, $userTicks) = (chr(0) x 8) x 3;
  GetSystemTimes($idleTicks, $kernelTicks, $userTicks) or die $^E;
 
  return map {
      my($lo, $hi) = unpack 'VV', $_;
      ($hi * 2**32 + $lo);
  } ($idleTicks, $kernelTicks, $userTicks);
}
 
sub MEM {
# Отношение свободной физической памяти к общему количеству памяти
  Win32::SystemInfo::MemoryStatus(%res);
  $res{AvailPhys} / $res{TotalPhys} * 100;
}
 
sub Weather {
# Взять температуру и давление со страницы Яндекс.Погода
  my($city) = @_;
 
  if ($lastWeather == 0 || time() - $lastWeather > 60 * 60 * 2) {
  # Не чаще, чем раз в два часа
    $lastWeather = time();
 
    $s = get("http://pogoda.yandex.ru/$city/");
    _utf8_off($s);
    from_to($s, 'utf-8', 'windows-1251');
 
    if ($s =~ m{<div>Давление: (\d+)}) {
      $lastPres = $1;
    }
    if ($s =~ m{Weather.temperature = ([\d+-]+)}) {
      $lastTemp = $1;
    }
  }
  $temp = $lastTemp || $temp;
  $pres = $lastPres || $pres;
 
  ($temp, $pres);
}
 
sub DateTime {
# Дата и месяц
  @time = localtime();
  @mon = qw(января февраля марта апреля мая июня июля августа сентября октября ноября декабря);
  return ($time[3], $mon[$time[4]], $time[2], $time[1]);
}
 
sub Disk {
  (Win32::DriveInfo::DriveSpace($_[0].':'))[6] / 1e9;
}