Конвертировать из OEM в UTF 8

Import "user32.lib"
    OemToCharBuffA(*Buff, *Buff1, SizeBuff)
    CharToOemBuffA(*Buff, *Buff1, SizeBuff)
EndImport
 
; 866 в Windows1251
Procedure.s ToChar(String$)
    Protected Ret$, *Buff, SizeBuff
    If Asc(String$)
        SizeBuff = Len(String$)
        *Buff = AllocateMemory(SizeBuff + 1)
        PokeS(*Buff, String$, SizeBuff, #PB_Ascii)
        OemToCharBuffA(*Buff, *Buff, SizeBuff) ; 866 в Windows1251
        Ret$ = PeekS(*Buff, SizeBuff, #PB_Ascii)
        FreeMemory(*Buff)
    EndIf
    ProcedureReturn Ret$
EndProcedure
 
; Windows1251 в 866
Procedure.s ToOem(String$)
    Protected Ret$, *Buff, SizeBuff
    If Asc(String$)
        SizeBuff = Len(String$)
        *Buff = AllocateMemory(SizeBuff + 1)
        PokeS(*Buff, String$, SizeBuff, #PB_Ascii)
        CharToOemBuffA(*Buff, *Buff, SizeBuff) ; Windows1251 в 866
        Ret$ = PeekS(*Buff, SizeBuff, #PB_Ascii)
        FreeMemory(*Buff)
    EndIf
    ProcedureReturn Ret$
EndProcedure
 
s.s = "Привет"
Debug s
s = ToOem(s)
Debug s
s = ToChar(s)
Debug s

Import "user32.lib"
    OemToCharBuffA(*Buff, *Buff1, SizeBuff)
    CharToOemBuffA(*Buff, *Buff1, SizeBuff)
EndImport
 
Procedure.s cp866_to_cp1251(String$)
    Protected *Buff
    If Asc(String$)
        *Buff = Ascii(String$)
        OemToCharBuffA(*Buff, *Buff, MemorySize(*Buff))
        String$ = PeekS(*Buff, MemorySize(*Buff), #PB_Ascii)
        FreeMemory(*Buff)
    EndIf
    ProcedureReturn String$
EndProcedure
 
Procedure.s cp1251_to_cp866(String$)
    Protected *Buff
    If Asc(String$)
        *Buff = Ascii(String$)
        CharToOemBuffA(*Buff, *Buff, MemorySize(*Buff))
        String$ = PeekS(*Buff, MemorySize(*Buff), #PB_Ascii)
        FreeMemory(*Buff)
    EndIf
    ProcedureReturn String$
EndProcedure
 
s.s = "Привет"
Debug s
s = cp1251_to_cp866(s)
Debug s
s = cp866_to_cp1251(s)
Debug s

String$ = "ЏаЁўҐв" ; строка, которая должна быть в 866, но кроме того она ещё и в UTF-16
*a = Ascii(String$) ; делаем буфер 866, хотя я был не уверен, по какой таблице он будет UTF-16 превращать в Ascii, ожидалось 1251
b$ = Space(Len(String$) * 2) ; создаём буфер для копирования, который должен быть минимум в 2 раза больше исходного в Ascii
MultiByteToWideChar_(866, 0, *a, MemorySize(*a), @b$, StringByteLength(b$)) ; преобразуем в UTF-16, опять же не UTF-8 как многие думают
FreeMemory(*a) ; освобождаем память
Debug b$       ; показываем что строка стала нормальной переменной в UTF-16
; *m = UTF8(b$) ; так мы получаем буфер UTF8 (не строку, не переменную)

EnableExplicit
 
Procedure.s WinAPI_MultiByteToWideChar(String$, CodePage)
    Protected *a, *m, Result$, size
    *a = Ascii(String$)
    size = MultiByteToWideChar_(CodePage, 0, *a, MemorySize(*a), 0, 0)
    If size
        *m = AllocateMemory(size)
        If *m
            If MultiByteToWideChar_(CodePage, 0, *a, MemorySize(*a), *m, size)
                Result$ = PeekS(*m)
            EndIf
            FreeMemory(*m)
        EndIf
    EndIf
    FreeMemory(*a)
    ProcedureReturn Result$
EndProcedure
 
Debug WinAPI_MultiByteToWideChar("ЏаЁўҐв", 866) ; 866
Debug WinAPI_MultiByteToWideChar("рТЙЧЕФ", 20866) ; KOI8
Debug WinAPI_MultiByteToWideChar("їаШТХв", 28595) ; ISO-8859-5
Debug WinAPI_MultiByteToWideChar("Привет", 65001) ; UTF8