Как отобразить текст программы в текстовом редакторе в корректной кодировке?

10 REM "OTSP1"-программа расчета свариваемости стали и режимов сварки
20 PRINT "НЕОБХОДИМ ЛИ РАСЧЕТ СВАРИВАЕМОСТИ СТАЛИ ?"
30 INPUT "ЕСЛИ ДА ТО ВВЕДИТЕ - 1, ЕСЛИ НЕТ - 0";SXC
40 IF SXC=0 GOTO 1180
50 PRINT "*********************************************************************"
60 PRINT "*                ТАБЛИЦА МАРОК СТАЛЕЙ И ИХ КОД                      *"
70 PRINT "*********************************************************************"
80 PRINT "*                      КОД - МАРКА СТАЛИ                            *"
90 PRINT "*      1-Сталь3;   2-10Кп;   3-20;   4-45;   5-30ХГСА;              *"
100 PRINT "*             6-А12;   7-10ХСНД;   8-12Х18Н9Т                       *"
110 PRINT "*********************************************************************"
120 C=0:MN=0:SI=0:CR=0:NI=0:MO=0:V=0:AL=0:CO=0:NB=0:N=0:CU=0:W=0:TI=0:P=0:S=0:ZR=0:B=0:TA=0:ZN=0
130 PRINT "НАЙДИТЕ В ТАБЛИЦЕ СВОЮ МАРКУ СТАЛИ И ВВЕДИТЕ ЕЕ КОД
140 INPUT "(ЕСЛИ ВАШЕЙ СТАЛИ НЕТ - ВВЕДИТЕ 0) K=";K
150 PRINT " КУДА ВЫ ПРЕДПОЛОГАЕТ ВЫВОДИТЬ РЕЗУЛЬТАТЫ ?"
160 PRINT " ЕСЛИ НА БУМАГУ ВВЕДИТЕ 1, ЕСЛИ НЕТ ТО 0": INPUT GHJ
170 INPUT "ВВЕДИТЕ МАРКУ СТАЛИ ...";A$
180 IF K=0 GOTO 350
190 IF K=1 GOTO 270
200 IF K=2 GOTO 280
210 IF K=3 GOTO 290
220 IF K=4 GOTO 300
230 IF K=5 GOTO 310
240 IF K=6 GOTO 320
250 IF K=7 GOTO 330
260 IF K=8 GOTO 340
270 C=.18:MN=.5:SI=.2: GOTO 550
280 C=.1:MN=.5:SI=.11: GOTO 550
290 C=.2:MN=.4:SI=.17: GOTO 550
300 C=.45:MN=.65:SI=.27: GOTO 550
310 C=.31:MN=.95:SI=1.05:CR=.95: GOTO 550
320 C=.12:MN=.85:SI=.25:S=.14:P=.12: GOTO 550
330 C=.12:MN=.65:SI=1:CR=.75:NI=.65:CU=.5: GOTO 550
340 C=.12:MN=2:SI=.8:CR=18:NI=10:TI=.8:GOTO 550
350 PRINT "ВВЕДИТЕ СРЕДНЕЕ СОДЕРЖАНИЕ ХИМИЧЕСКИХ ЭЛЕМЕНТОВ ПО ГОСТ"
360 INPUT "C=";C
370 INPUT "Mn=";MN
380 INPUT "Si=";SI
390 INPUT "Cr=";CR
400 INPUT "Ni=";NI
410 INPUT "Mo=";MO
420 INPUT "V=";V
430 INPUT "Al=";AL
440 INPUT "Co=";CO
450 INPUT "Nb=";NB
460 INPUT "N=";N
470 INPUT "Cu=";CU
480 INPUT "W=";W
490 INPUT "Ti=";TI
500 INPUT "P=";P
510 INPUT "S=";S
520 INPUT "Zr=";ZR
530 INPUT "B=";B
540 INPUT "Zn=";ZN
550 PRINT "    МАРКА СТАЛИ ......";A$
560 IF GHJ=1 THEN LPRINT "    МАРКА СТАЛИ ......";A$
570 PRINT "    <>  ОЦЕНКА СВАРИВАЕМОСТИ . "
580 IF GHJ=1 THEN LPRINT "    <>  ОЦЕНКА СВАРИВАЕМОСТИ . "
590 INPUT "ВВЕДИТЕ ТОЛЩИНУ МЕТАЛЛА В мм, Q=";Q
600 PRINT " 1. ОЦЕНКА СВАРИВАЕМОСТИ ПО ОБРАЗОВАНИЮ ГОРЯЧИХ ТРЕЩИН :
610 IF GHJ=1 THEN LPRINT " 1. ОЦЕНКА СВАРИВАЕМОСТИ ПО ОБРАЗОВАНИЮ ГОРЯЧИХ ТРЕЩИН : "
620 HCS=C*(S+P+SI/25+NI/100)*1000/(3*MN+CR+MO+V)
630 PRINT "ВВЕДИТЕ КАКАЯ У ВАС СТАЛЬ. ЕСЛИ НУ, НЛ, ТО ВВЕДИТЕ 1;ЕСЛИ ВП, ТО 2"
640 INPUT STL
650 IF STL=2 GOTO 730
660 IF HCS<4 GOTO 700
670 PRINT "-  СКЛОННА К ОБРАЗОВАНИЮ ГОРЯЧИХ ТРЕЩИН, HCS=";HCS
680 IF GHJ=1 THEN LPRINT "-  СКЛОННА К ОБРАЗОВАНИЮ ГОРЯЧИХ ТРЕЩИН, HCS=";HCS
690 GOTO 790
700 PRINT "-  НЕ СКЛОННА К ОБРАЗОВАНИЮ ГОРЯЧИХ ТРЕЩИН, HCS=";HCS
710 IF GHJ=1 THEN LPRINT "-  НЕ СКЛОННА К ОБРАЗОВАНИЮ ГОРЯЧИХ ТРЕЩИН, HCS=";HCS
720 GOTO 790
730 IF HCS<1.6 GOTO 770
740 PRINT "-  СКЛОННА К ОБРАЗОВАНИЮ ГОРЯЧИХ ТРЕЩИН, HCS=";HCS
750 IF GHJ=1 THEN LPRINT "-  СКЛОННА К ОБРАЗОВАНИЮ ГОРЯЧИХ ТРЕЩИН, HCS=";HCS
760 GOTO 790
770 PRINT "-  НЕ СКЛОННА К ОБРАЗОВАНИЮ ГОРЯЧИХ ТРЕЩИН, HCS=";HCS
780 IF GHJ=1 THEN LPRINT "-  НЕ СКЛОННА К ОБРАЗОВАНИЮ ГОРЯЧИХ ТРЕЩИН, HCS=";HCS
790 PRINT " 2. ОЦЕНКА СВАРИВАЕМОСТИ ПО ОБРАЗОВАНИЮ ХОЛОДНЫХ ТРЕЩИН :"
800 IF GHJ=1 THEN LPRINT " 2. ОЦЕНКА СВАРИВАЕМОСТИ ПО ОБРАЗОВАНИЮ ХОЛОДНЫХ ТРЕЩИН :"
810 PRINT "    а) ПО МЕТОДУ МЕЖДУНАРОДНОГО ИНСТИТУТА СВАРКИ"
820 IF GHJ=1 THEN LPRINT "    а) ПО МЕТОДУ МЕЖДУНАРОДНОГО ИНСТИТУТА СВАРКИ"
830 C1=C+MN/6+(CR+MO+V)/5+(NI+CU)/15+P/2
840 IF C1<.45 GOTO 880
850 PRINT "-  ЕСТЬ СКЛОННОСТЬ К ОХРУПЧИВАНИЮ,C1=";C1
860 IF GHJ=1 THEN LPRINT "-  ЕСТЬ СКЛОННОСТЬ К ОХРУПЧИВАНИЮ,C1=";C1
870 GOTO 900
880 PRINT "-  НЕТ СКЛОННОСТИ К ОХРУПЧИВАНИЮ, C1=";C1
890 IF GHJ=1 THEN LPRINT "-  НЕТ СКЛОННОСТИ К ОХРУПЧИВАНИЮ, C1=";C1
900 PRINT "    б) ПО ЯПОНСКОМУ МЕТОДУ"
910 IF GHJ=1 THEN LPRINT "    б) ПО ЯПОНСКОМУ МЕТОДУ"
920 C2=C+MN/6+SI/24+NI/40+CR/5+MO/4+V/14
930 IF C2<.45 GOTO 970
940 PRINT "-  ЧУВСТВИТЕЛЬНА К ОБРАЗОВАНИЮ ХОЛОДНЫХ ТРЕЩИН,C2=";C2
950 IF GHJ=1 THEN LPRINT "-  ЧУВСТВИТЕЛЬНА К ОБРАЗОВАНИЮ ХОЛОДНЫХ ТРЕЩИН,C2=";C2
960 GOTO 990
970 PRINT "-  НЕ ЧУВСТВИТЕЛЬНА К ОБРАЗОВАНИЮ ХОЛОДНЫХ  ТРЕЩИН, C2=";C2
980 IF GHJ=1 THEN LPRINT "-  НЕ ЧУВСТВИТЕЛЬНА К ОБРАЗОВАНИЮ ХОЛОДНЫХ  ТРЕЩИН, C2=";C2
990 PRINT "   c)ОЦЕНКА ПО ТВЁРДОСТИ ЗТВ"
1000 IF GHJ=1 THEN LPRINT "   c)ОЦЕНКА ПО ТВЁРДОСТИ ЗТВ"
1010 HV=90+1050*C+47*SI+75*MN+30*NI+31*CR
1020 IF HV<350 GOTO 1060
1030 PRINT "-СКЛОННА К ОБРАЗОВАНИЮ ЗАКАЛОЧНЫХ СТРУКТУР,HV=",HV
1040 IF GHJ=1 THEN LPRINT "-СКЛОННА К ОБРАЗОВАНИЮ ЗАКАЛОЧНЫХ СТРУКТУР,HV=",HV
1050 GOTO 1080
1060 PRINT "-НЕ СКЛОННА К ОБРАЗОВАНИЮ ЗАКАЛОЧНЫХ СТРУКТУР, HV=";HV
1070 IF GHJ=1 THEN LPRINT "-НЕ СКЛОННА К ОБРАЗОВАНИЮ ЗАКАЛОЧНЫХ СТРУКТУР, HV=";HV
1080 PRINT
1090 PRINT " <> РЕКОМЕНДУЕМАЯ ТЕМПЕРАТУРА ПОДОГРЕВА:"
1100 IF GHJ=1 THEN LPRINT " <> РЕКОМЕНДУЕМАЯ ТЕМПЕРАТУРА ПОДОГРЕВА:"
1110 C3=C1*(1+.005*Q)
1120 T=350*SQR(ABS(C3-.25))
1130  IF T>150 GOTO 1150
1140 PRINT " ПОДОГРЕВ НЕ НУЖЕН":GOTO 1180
1150 PRINT "           T=";T;"град."
1160 IF GHJ=1 THEN LPRINT "           T=";T;"град.":LPRINT
1170 PRINT
1180 PRINT "ЕСЛИ НЕОБХОДИМ РАСЧЕТ ПО ДИАГРАММЕ ШЕФЛЕРА ВВЕДИТЕ 1,ЕСЛИ НЕТ 0"
1190 INPUT SHF
1200 IF SHF=0 GOTO 1553
1210 PRINT "ОЦЕНКА СВАРИВАЕМОСТИ ПО ДИАГРАММЕ ШЕФФЛЕРА"
1220 IF GHJ=1 THEN LPRINT "ОЦЕНКА СВАРИВАЕМОСТИ ПО ДИАГРАММЕ ШЕФФЛЕРА"
1230 F=CR+2*SI+2*MO+5*V+1.75*NB+5*TI+.75*W
1240 A=NI+30*C+.5*MN+25*N
1250 PRINT "ЭКВИВАЛЕНТНОЕ СОДЕРЖАНИЕ ФЕРРИТООБРАЗУЮЩИХ, ФЭК=";F
1253 IF GHJ=1 THEN LPRINT "ЭКВИВАЛЕНТНОЕ СОДЕРЖАНИЕ ФЕРРИТООБРАЗУЮЩИХ, ФЭК=";F
1263 PRINT "ЭКВИВАЛЕНТНОЕ СОДЕРЖАНИЕ АУСТЕНИТООБРАЗУЮЩИХ, АЭК=";A
1273 IF GHJ=1 THEN LPRINT "ЭКВИВАЛЕНТНОЕ СОДЕРЖАНИЕ АУСТЕНИТООБРАЗУЮЩИХ, АЭК=";A
1283 Y1=26-.845*F
1293 Y2=1.333*F-10
1303 Y3=20-.858*F
1313 Y4=.285*F-3.43
1323 IF A<30 THEN IF A>=11 THEN IF F<30 THEN IF A>=Y1 THEN IF A>=Y2 GOTO 1413
1333 IF A<=20 THEN IF F<=14 THEN IF A<=Y3 THEN IF A>=Y2 THEN IF GHJ=1 GOTO 9233:GOTO 1423
1343 IF A>=8 THEN IF A<=26 THEN IF A>=Y3 THEN IF A<=Y1 THEN IF A>=Y2 THEN IF GHJ=1 THEN GOTO 9243:GOTO 1433
1353 IF A<=30 THEN IF A>=4 THEN IF F>=16.5 THEN IF A<=Y2 GOTO 1363
1363 IF A>=Y1 THEN IF A>=Y4 THEN IF GHJ=1 THEN GOTO 9253:GOTO 1443
1373 IF F>12 THEN IF A<=8 THEN IF A<=Y4 THEN IF GHJ=1 THEN GOTO 9263:GOTO 1453
1383 IF F>=8 THEN IF F<=21 THEN IF A<=Y2 THEN IF A<=Y3 THEN IF A>=Y4 THEN IF A<=8 THEN IF GHJ=1 THEN GOTO 9273:GOTO 1463
1393 IF A<=11 THEN IF A>2.5 THEN IF F>=14 THEN IF F<=25 GOTO 1403
1403 IF A<=Y2 THEN IF A>=Y4 THEN IF A<=Y1 THEN IF A>=Y3 THEN IF GHJ=1 THEN GOTO 9283:GOTO 1473
1413 PRINT "СТАЛЬ АУСТЕНИТНАЯ, ОБЛАСТЬ ДИАГРАММЫ 02": GOTO 1483
1423 PRINT "СТАЛЬ МАРТЕНСИТНАЯ, ОБЛАСТЬ ДИАГРАММЫ 01": GOTO 1493
1433 PRINT "СТАЛЬ ПЕРЕХОДНОГО КЛАССА АУСТЕНИТНО-МАРТЕНСИТНАЯ, ОБЛАСТЬ ДИАГРАММЫ 03": GOTO 1503
1443 PRINT "СТАЛЬ АУСТЕНИТНО-ФЕРРИТНАЯ, ОБЛАСТЬ ДИАГРАММЫ 04": GOTO 1503
1453 PRINT "СТАЛЬ ФЕРРИТНАЯ, ОБЛАСТЬ ДИАГРАММЫ 05": GOTO 1523
1463 PRINT "СТАЛЬ МАРТЕНСИТНО-ФЕРРИТНАЯ, ОБЛАСТЬ ДИАГРАММЫ 06": GOTO 1513
1473 PRINT "СТАЛЬ АУСТЕНИТНО-МАРТЕНСИТНО-ФЕРРИТНАЯ, ОБЛАСТЬ ДИАГРАММЫ 07": GOTO 1523
1483 PRINT "ВОЗМОЖНО ОБРАЗОВАНИЕ ГОРЯЧИХ (КРИСТАЛИЗАЦИОННЫХ ТРЕЩИН. СВАРКА БЕЗ   ПРЕДВАРИТЕЛЬНОГО ПОДОГРЕВА. ПРИМЕНЯТЬ СВАРОЧНЫЕ МАТЕРИАЛЫ, ОБЕСПЕЧИВАЮЩИЕ В НАПЛАВЛЕННОМ МЕТАЛЛЕ СОДЕРЖАНИЕ ФЕРРИТА 5-8%": GOTO 1553
1493 PRINT "ВОЗМОЖНО ОБРАЗОВАНИЕ ХОЛОДНЫХ ТРЕЩИН В ШВЕ И ОКОЛОШОВНОЙ ЗОНЕ. НЕОБХОДИМ ПРЕДВАРИТЕЛЬНЫЙ ПОДОГРЕВ":PRINT: GOTO 1553
1503 PRINT "ВОЗМОЖНО ПОЯВЛЕНИЕ ХРУПКОСТИ ПОСЛЕ НАГРЕВА ДО 400-900 ГРАД. ТЕМПЕРАТУРА АУСТЕНИТНОГО И МАРТЕНСИТНОГО ПРЕВРАЩЕНИЯ АС3=900 ТМ=500 ГРАД."
1513 PRINT "МЕТАЛЛ ШВА В ОКОЛОШОВНОЙ ЗОНЕ ПОДВЕРЖЕН ЗАКАЛКЕ": GOTO 1493
1523 PRINT "ВОЗМОЖНО ПОЯВЛЕНИЕ ВЫСОКОТЕМПЕРАТУРНОЙ ХРУПКОСТИ"
1533 IF GHJ=1 THEN GOTO 9223
1543 PRINT
1553 INPUT "ПРОДОЛЖЕНИЕ РАБОТЫ - 1, ОКОНЧАНИЕ - 0 ";NAT
1563 IF NAT=0 GOTO 9213
1573 PRINT "ГДЕ ЖЕЛАЕТЕ ПОЛУЧИТЬ РЕЗУЛЬТАТ НА БУМАГЕ ИЛИ НА МОНИТОРЕ  ?"
1583 PRINT "ЕСЛИ НА БУМАГЕ ВВЕДИТЕ - 1, ЕСЛИ НА МОНИТОРЕ - 0 ":INPUT GHJ
1593 PRINT "ВЫБИРИТЕ СПОСОБ СВАРКИ "
1603 PRINT "********************************************************************"
1613 PRINT "* ТОЧЕЧНАЯ-1,РЕЛЬЕФНАЯ (ПО КОЛЬЦУ)-2,ШОВНАЯ-3,РДС-4, ПОД ФЛЮСОМ-5, *"
1623 PRINT "* СВАРКА В AR-6,СВАРКА В СО2-7, РЕЛЬЕФНАЯ (ОСТРОЙ ГРАНЬЮ)-8, ЭШС-9 *"
1633 PRINT "********************************************************************"
1643 INPUT "ВВЕДИТЕ КОД СПОСОБА СВАРКИ К=";KW
1653 IF KW=1 GOTO 2943
1663 IF KW=2 GOTO 3673
1673 IF KW=3 GOTO 4723
1683 IF KW=4 GOTO 5303
1693 IF KW=5 GOTO 5723
1703 IF KW=6 GOTO 6223
1713 IF KW=7 GOTO 7523
1723 IF KW=8 GOTO 1743
1733 IF KW=9 GOTO 8013
1743 PRINT "  <> РАСЧЕТ РЕЖИМА РЕЛЬЕФНОЙ СВАРКИ МЕТОДОМ ОСТРОЙ ГРАНИ "
1753 PRINT "     ДЛЯ НИЗКОУГЛЕРОДИСТЫХ И АВТОМАТНЫХ СТАЛЕЙ."
1763 IF GHJ=1 THEN LPRINT "  <> РАСЧЕТ РЕЖИМА РЕЛЬЕФНОЙ СВАРКИ МЕТОДОМ ОСТРОЙ ГРАНИ "
1773 PRINT "ВВЕДИТЕ РАЗМЕРЫ ДЕТАЛЕЙ В мм:":PRINT "   НУЖЕН ЧЕРТЕЖ ? "
1783 PRINT" ЕСЛИ ДА ВВЕДИ -1":INPUT VB:IF VB=1 GOTO 8303
1793 INPUT "   НАРУЖНЫЙ ДИАМЕТР ДЕТАЛИ   D=";D
1803 INPUT "   ДИАМЕТР ОТВЕРСТИЯ В ДЕТАЛИ D1=";D1
1813 INPUT "   ВНУТРЕННИЙ ДИАМЕТР РЕЛЬЕФА D2=";D2
1823 INPUT "   ВЫСОТА ДЕТАЛИ H=";H:INPUT "   ВВЕДИ ТЕМПЕРАТУРУ ПЛАВЛЕНИЯ МАТЕРИАЛА Т=";T
1833 INPUT "   ДИАМЕТР ОТВЕРСТИЙ В ПЛАСТИНЕ D3=";D3
1843 INPUT "   ТОЛЩИНУ ПЛАСТИНЫ S=";S
1853 INPUT "   УГОЛ ПРОФИЛЯ В град X=";X
1863 B=(D-D3)/2
1873 D=D/10:D1=D1/10:D2=D2/10:D3=D3/10:B=B/10
1883 H=H/10:S=S/10
1893 REM Т1 - ВРЕМЯ СВАРКИ
1903 A1=.08:T6=1200:D4=(D+D3)/2:K1=(10*S)^S
1913 C=3.14*D4*B:T1=.1*D4*K1:P3=600/(T1^.15)
1923 REM Р1 - СВАРОЧНОЕ УСИЛИЕ
1933 X1=1.25:P1=P3*C*K1:F1=(D^2-D1^2)+(D2^2-D1^2):F2=D-D2:Y=3.14*X/180
1943 Q1=T*X1*3.14*F1*F2*TAN(Y)/48:F3=SQR(2*A1*T1):F4=S/F3:IF F4<1.5 GOTO 1963
1953 F5=.88:GOTO 1973
1963 F5=F4*(1-F4^2/3+F4^4/10-F4^6/42+F4^8/216-F4^10/1320)
1973 T5=T6*F5/F4:G=.5*B/S
1983 IF G<1 THEN W=.52: GOTO 2033
1993 IF G<1.5 THEN W=.63: GOTO 2033
2003 IF G<2 THEN W=.7: GOTO 2033
2013 IF G<3 THEN W=.78: GOTO 2033
2023 IF G<4 THEN W=.85
2033 B1=B+B/W
2043 REM Q2 - ТЕПЛОТА, НЕОБХОДИМАЯ ДЛЯ ПРОГРЕВА ЧАСТИ ПЛАСТИНЫ
2053 Q2=T5*X1*3.14*((D3+B1)^2-D3^2)*S/4:Q3=67*SQR(3.14*.1*X1*T1)*(D^2-D1^2):F6=S/(A1*T1)
2063 T4=S^2/(A1*6):C1=3.14*((D3+2*B/W)^2-D3^2)/4
2073 Q4=.1*T6*EXP(-F6*S/2)*F6*C1*(T1-T4)
2083 REM Q5 - ТЕПЛОТА, УШЕДШАЯ В ПЛАСТИНУ В РАДИАЛЬНОМ НАПРАВЛЕНИИ
2093 REM      ИЗ ЗОНЫ ПРЕИМУЩЕСТВЕННОГО ТЕПЛОВЫДЕЛЕНИЯ
2103 Q5=.1*3.14*(D3+B1)*S*T5*SQR(T1)/(6*SQR(A1))
2113 REM Q - ОБЩЕЕ КОЛИЧЕСТВО ТЕПЛА, ВЫДЕЛЕВШЕГОСЯ НА УЧАСТКЕ
2123 Q=Q1+Q2+Q3+Q4+Q5
2133 IF T5>700 THEN X4=100:GOTO 2153
2143 X4=8+.12*T5
2153 X2=S-(B*TAN(Y))/4:X3=(D3+2*B)^2-D3^2:R1=X4*X2*W/(3.14*X3):X5=F2/2*TAN(Y):K2=79:K3=1.1
2163 R2=.8*K2*X5/(3.14*F1/2):R=(R1+R2)*K3*10:I=SQR(Q/(.24*T1*R))
2173 D7=D/D1:D8=D/(2*H):R5=(D7+1)/2-.47*LOG(D7)/(D8+1/D7):S1=3.14*(D^2-D1^2)/4
2183 G1=263*(EXP(.057*I^2*T1/(S1^2))-1):G2=G1*(1-.28*SQR(T1)/H):U=I/P1
2193 D=D*10:D1=D1*10:D2=D2*10:D3=D3*10:B=B*10:H=H*10:S=S*10
2203 PRINT "********************************************************************"
2213 PRINT "D=";D;"D1=";D1;"D2=";D2;"D3=";D3;"B=";B;"H=";H;"S=";S
2223 PRINT "R1=";R1;"R2=";R2;"R=";R;"I=";I
2233 PRINT "T1=";T1;"P1=";P1
2243 PRINT "Q=";Q;"Q1=";Q1;"Q2=";Q2
2253 PRINT "Q3=";Q3;"Q4=";Q4;"Q5=";Q5
2263 PRINT "U=";U;"G=";G;"G1=";G1
2273 PRINT "G2=";G2;"S1=";S1
2283 PRINT "********************************************************************"
2293 PRINT
2303 GOSUB 2333
2313 INPUT "НУЖЕН ЭСКИЗ ДЕТАЛИ НА БУМАГЕ ? (ДА - 1, НЕТ - 0) ==>";I5
2323 IF I5=1 GOTO 2533
2333 PRINT:PRINT
2343 PRINT "%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%"
2353 PRINT:PRINT
2363 PRINT "                         РЕЗУЛЬТАТЫ РАСЧЕТА :"
2373 PRINT
2383 IF R5<1.05 GOTO 2413
2393 PRINT "СТЕНКА БОНКИ УСТОЙЧИВА"
2403 GOTO 2453
2413 PRINT "СТЕНКА БОНКИ НЕУСТОЙЧИВА"
2423 IF U<=.04 THEN PRINT "ВЫПЛЕСКОВ НЕТ":GOTO 2453
2433 PRINT "ВЫПЛЕСКИ ЕСТЬ"
2443 PRINT:PRINT
2453 PRINT "                         РЕЖИМ СВАРКИ"
2463 PRINT "СВАРОЧНЫЙ ТОК, КА I=";I;";+-5%"
2473 PRINT "СВАРОЧНОЕ УСИЛИЕ, ДАН Р=";P1;";+-10%"
2483 PRINT "ВРЕМЯ СВАРКИ, С Т=";T1;"+-0.02 С"
2493 PRINT "ВРЕМЯ ПРОКОВКИ, С Т=";T7;"+-0.02 С"
2503 PRINT "ПРОКОВОЧНОЕ УСИЛИЕ, ДАН Р(К)=";R7;";+-10%"
2513 PRINT "ТЕМПЕРАТУРА НАГРЕВА СТЕНКИ ДЕТАЛИ Т=";G2 :GOTO 2823
2523 RETURN
2533 LPRINT:LPRINT "                      ЭСКИЗ СВАРИВАЕМЫХ ДЕТАЛЕЙ":LPRINT
2543 LPRINT "          H=";H
2553 LPRINT " !-----------------------"
2563 LPRINT " !"
2573 LPRINT " ---------********************************************"
2583 LPRINT " !        *///////////////*        */////////////////*"
2593 LPRINT " !        *///////////////*        */////////////////*"
2603 LPRINT " !        *///////////////*        */////////////////*   D=";D
2613 LPRINT " !        *<--------------*--------*---------------->*------------"
2623 LPRINT " !        *///////////////*        */////////////////*"
2633 LPRINT " !        *///////////////*        */////////////////*"
2643 LPRINT " !        *///////////////*        */////////////////*   D1=";D1
2653 LPRINT " !        *///////////////*<------>*/////////////////*------------"
2663 LPRINT " !        *///////////////*        */////////////////*"
2673 LPRINT " !        *///////////////*        */////////////////*"
2683 LPRINT " !         *//////////////*        *////////////////*"
2693 LPRINT " !          */////////////*        *///////////////*"
2703 LPRINT " !===========*////////////*        *//////////////*==============="
2713 LPRINT " !----------=**************************************=--------------"
2723 LPRINT " !          =!                                    !="
2733 LPRINT " !          =!                                    !="
2743 LPRINT " !===========!                                    !==============="
2753 LPRINT " !          !!                                    !!     D2=";D2
2763 LPRINT " !          !!<---------------------------------->!!--------------"
2773 LPRINT " !          !                                      !"
2783 LPRINT " !          !                                      !     D3=";D3
2793 LPRINT " !          !<------------------------------------>!--------------"
2803 LPRINT " !   S=";S
2813 LPRINT " !---------------":LPRINT:GOTO 2333
2823 IF GHJ=1 THEN LPRINT "%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%":LPRINT
2833 IF GHJ=1 THEN LPRINT "                         РЕЗУЛЬТАТЫ РАСЧЕТА :"
2843 IF GHJ=1 AND R5>1.05 THEN LPRINT "СТЕНКА БОНКИ УСТОЙЧИВА":GOTO 2863
2853 IF GHJ=1 THEN LPRINT "СТЕНКА БОНКИ НЕУСТОЙЧИВА"
2863 IF GHJ=1 THEN LPRINT "                         РЕЖИМ СВАРКИ"
2873 IF GHJ=1 THEN LPRINT "СВАРОЧНЫЙ ТОК, КА I=";I;";+-5%"
2883 IF GHJ=1 THEN LPRINT "СВАРОЧНОЕ УСИЛИЕ, ДАН Р=";P1;";+-10%"
2893 IF GHJ=1 THEN LPRINT "ВРЕМЯ СВАРКИ, С Т=";T1;"+-0.02 С"
2903 IF GHJ=1 THEN LPRINT "ВРЕМЯ ПРОКОВКИ, С Т=";T7;"+-0.02 С"
2913 IF GHJ=1 THEN LPRINT "ПРОКОВОЧНОЕ УСИЛИЕ, ДАН Р(К)=";R7;";+-10%"
2923 IF GHJ=1 THEN LPRINT "ТЕМПЕРАТУРА НАГРЕВА СТЕНКИ ДЕТАЛИ Т=";G2:LPRINT
2933 GOTO 1553
2943 PRINT "РАСЧЕТ ПАРАМЕТРОВ РЕЖИМА ТОЧЕЧНОЙ СВАРКИ"
2953 IF GHJ=1 THEN LPRINT "РАСЧЕТ ПАРАМЕТРОВ РЕЖИМА ТОЧЕЧНОЙ СВАРКИ"
2963 INPUT "ВВЕДИТЕ ТОЛЩИНУ БОЛЕЕ ТОНКОЙ ДЕТАЛИ, мм S=";S
2973 INPUT "ВВЕДИТЕ ШАГ МЕЖДУ ТОЧКАМИ, мм S1=";S1
2983 GOTO 8673
2993 PRINT "ВВЕДИТЕ СВОЙСТВА СВАРИВАЕМЫХ МАТЕРИАЛОВ"
3003 INPUT "УДЕЛЬНАЯ ТЕПЛОЕМКОСТЬ ДЖ/КГ*ГРАД C1=";C1
3013 INPUT "ПЛОТНОСТЬ КГ/КУБ.М G1=";G1
3023 INPUT "ТЕМПЕРАТУРОПРОВОДНОСТЬ M2/C A1=";A1
3033 A1=A1*E6
3043 INPUT "ТЕМПЕРАТУРА ПЛАВЛЕНИЯ ГРАД T=";T
3053 INPUT "УДЕЛЬНОЕ СОПРОТИВЛЕНИЕ ПРИ 20 ГРАД МКОМ*M  RQ=";R0
3063 INPUT "КОЭФФИЦИЕНТ ВОЗРАСТАНИЯ УДЕЛЬНОГО СОПРОТИВЛЕНИЯ W=";W
3073 PRINT "ВВЕДИТЕ УСЛОВНОЕ СОПРОТИВЛЕНИЕ ПЛАСТИЧЕСКОЙ"
3083 INPUT "ДЕФОРМАЦИИ МАТЕРИАЛА ДЕТАЛЕЙ МПА E=";E
3093 REM C2-УДЕЛЬНАЯ ТЕПЛОЕМКОСТЬ,ДЖ/КГ*ГРАД
3103 REM G2-ПЛОТНОСТЬ, КГ/М3
3113 REM А2-ТЕМПЕРАТУРОПРОВОДНОСТЬ, М2/C
3123 C2=450: G2=8900: A2=7.500001E-05
3133 A1=A1*.000001
3143 IF KW=3 THEN RETURN
3153 PRINT:PRINT "ВВЕДИТЕ КОЭФФИЦИЕНТ ФОРМЫ ЭЛЕКТРОДА"
3163 PRINT "ЦИЛЛИНДРИЧЕСКИЙ ЭЛЕКТРОД K2=1"
3173 PRINT "КОНИЧЕСКИЙ ЭЛЕКТРОД К2=1.5"
3183 PRINT "ЭЛЕКТРОД СО СФЕРИЧЕСКОЙ РАБОЧКЙ ЧАСТЬЮ K2=2"
3193 INPUT  "K2=";K2:IF K2<2 THEN GOTO 3203
3203 K6=1.25
3213 PRINT:PRINT "ВВЕДИТЕ ТИП РЕЖИМА СВАРКИ"
3223 PRINT "ЖЕСТКИЙ X=0, МЯГКИЙ X=1":INPUT "X=";X
3233 K4=1.6:IF X=1 THEN K4=1
3243 K1=.8:K3=.85:E=250
3253 REM РАСЧЁТ ДИАМЕТРА ЭЛЕКТРОДА И УСИЛИЯ СЖАТИЯ
3263 D1=2*S+3
3273 F=2500*S:IF X=1 THEN F=1500*S
3283 IF K=10 THEN F=6*S^2*E
3293 IF K2=2 THEN D1=SQR(4*F/(3.14*E))
3303 D1=INT(D1)+.5
3306 PRINT " ДИАМЕТР ЭЛЕКТРОДА D=";D1;" ЕСЛИ ВЫ СОГЛАСНЫ ВВЕДИТЕ 0"
3308 INPUT " ЕСЛИ НЕТ, ВВЕДИТЕ НОВОЕ ЗНАЧЕНИЕ ДИАМЕТРА >>>=";CVBN
3310 IF CVBN=0 THEN GOTO 3323
3312 D1=CVBN
3320 REM РАСЧЕТ ВРЕМЕНИ СВАРКИ
3323 B1=.1*S:IF X=1 THEN B1=.3*S
3333 B2=.2*S:IF X=1 THEN B2=.5*S
3343 B1=INT(50*(B1+.01))/50:B2=INT(50*(B2+.01))/50
3350 IF GHJ=1 THEN LPRINT "СВАРОЧНОЕ УСИЛИЕ F=";F;" H"
3353 PRINT "СВАРОЧНОЕ УСИЛИЕ F="F;"H"
3360 IF GHJ=1 THEN LPRINT "ДИАМЕТР ЭЛЕКТРОДА Д=";D1;" ММ"
3363 PRINT "ДИАМЕТР ЭЛЕКТРОДА Д="D1;"мм"
3373 REM ВВОД КОЭФФ. РАСТЕКАНИЯ ТОКА И ОТНОСИТЕЛЬНОГО СОПРОТИВЛЕНИЯ ШУНТА
3383 H1=(2*S+K4*S)/4:H2=S-H1:D2=D1+K4*S
3393 PRINT "ЕСЛИ ВЫ СОГЛАСНЫ,ЧТО КОЭФФ. РАСТЕКАНИЯ ТОКА 0.76 И 0.95"
3403 INPUT "ВВЕДИТЕ 0,ЕСЛИ НЕТ 1";NAT
3413 IF NAT=0 THEN A3=.76:A4=.95:IF KW=3 THEN RETURN:GOTO 3473
3415 IF NAT=0 THEN A3=.76:A4=.95:GOTO 3473
3423 PRINT "ВВЕДИТЕ КОЭФФ. РАСТЕКАНИЯ ТОКА А ДЛЯ D/S=";D1/(2*H1)
3433 INPUT "A=";A3
3443 PRINT "ВВЕДИТЕ КОЭФФ. РАСТЕКАНИЯ ТОКА A ДЛЯ D/S=";D2/(2*H2)
3453 INPUT "A=";A4
3463 IF KW=3 THEN RETURN
3473 S2=3.14*S1/LOG(2*S1/D1)
3483 PRINT"S2=";S2
3493 R2=1.6
3503 REM ЦИКЛ ПО ВРЕМЕНИ, ВЫЧИСЛЕНИЕ СИЛЫ ТОКА
3513 S=S/1000:S1=S1/1000:S2=S2/1000
3523 D1=D1/1000:H1=H1/1000:H2=H2/1000:D2=D2/1000
3533 R6=R0*(1+W*T*4/5):R7=R0*(1+W*T)
3543 FOR B=B1 TO B2 STEP .02
3553 Q1=K1*3.14*4*SQR(A1*B)*(D1+4*SQR(A1*B))*2*S*C1*G1*T/4
3563 Q2=2*K2*3.14*D1^2*SQR(A2*B)*C2*G2*T/8:Q3=3.14*D1^2*S*C1*G1*T/2:Q=Q1+Q2+Q3
3573 R=8*(A3*K3*R6*H1/(D1^2)+A4*K3*R7*H2/(D2^2))/(3.14)
3583 J1=SQR(Q/(K6*R*B))
3593 J1=J1*1000!
3603 REM РАСЧЕТ ТОКА ШУНТИРОВАНИЯ И ВТОРИЧНОГО ТОКА
3613 T2=T*SQR(A1*B)/(S1-D1):R8=R0*(1+W*T2):R1=2*R2*R8/(S):J2=J1*R/R1:J=J1+J2
3623 IF GHJ=0 GOTO 3643
3633 LPRINT "ВРЕМЯ СВАРКИ ";B;"C, ТОК СВАРКИ ";J1;"A, ТОК ВТОРИЧНЫЙ ";J;"A"
3643 PRINT "ВРЕМЯ СВАРКИ ";B;"C, ТОК СВАРКИ ";J1;"A, ТОК ВТОРИЧНЫЙ ";J;"A"
3653 NEXT B:PRINT
3663 GOTO 1553
3673 PRINT "   <>  РЕЛЬЕФНАЯ СВАРКА ПО КОЛЬЦЕВОМУ РЕЛЬЕФУ"
3683 IF GHJ=1 THEN LPRINT "   <>  РЕЛЬЕФНАЯ СВАРКА ПО КОЛЬЦЕВОМУ РЕЛЬЕФУ"
3693 PRINT "ВВЕДИТЕ РАЗМЕРЫ СВ. ДЕТАЛЕЙ В мм"
3703 INPUT "ДИАМЕТР ПО ВЕРШИНЕ РЕЛЕФА D1=";D1
3713 INPUT "ДИАМЕТР ДЕТАЛИ D2=";D2
3723 INPUT "ДИАМЕТР ОТВЕРСТИЯ В ДЕТАЛИ D3=";D3
3733 INPUT "ШИРИНА ОСНОВАНИЯ РЕЛЬЕФА B=";B
3743 INPUT "ВЫСОТА ДЕТАЛИ H=";H
3753 INPUT "ТОЛЩИНА ПЛАСТИНЫ S=";S
3763 D1=D1/10:D2=D2/10:D3=D3/10:B=B/10:H=H/10:S=S/10
3773 D4=D2/D3:R6=D3/(2*H):R5=(D4+1)/2-.47*LOG(D4)/(R6+1/D4)
3783 IF R5<1.05 THEN PRINT "- СТЕНКА БОНКИ НЕ УСТОЙЧИВА":GOTO 3803
3793 PRINT "- СТЕНКА БОНКИ УСТОЙЧИВА"
3803 T1=.1*D1*(10*S)^S:T1=INT(50*(T1+.01))/50
3813 P3=600/(T1^.15):K1=(10*S)^S:C=3.14*D1*B:P1=P3*C*K1:T=1200
3823 Q1=.982*T*D1*B^2:F1=SQR(.08*T1):F2=S/F1
3833 IF F2<1.5 GOTO 3853
3843 F=.88:GOTO 3863
3853 F3=F2*(1-F2^2/3+F2^4/10-F2^6/42+F2^8/216-F2^10/1320)
3863 T5=T*F3/F2:G=.5*B/S
3873 IF G<1 THEN W=.52:GOTO 3923
3883 IF G<1.5 THEN W=.63:GOTO 3923
3893 IF G<2 THEN W=.7:GOTO 3923
3903 IF G<3 THEN W=.78:GOTO 3923
3913 IF G<5 THEN W=.85
3923 B1=B*(1+1/W)/2:Q2=3.93*D1*S*B1*T5:Q3=.417*T*D1*B*SQR(T1):F4=S*S/(.08*T1):T4=S*S/.2
3933 IF T4>T1 THEN T4=T1
3943 Q4=7.854*T*S*D1*B*(T1-T4)*EXP(-F4)/(W*T1):Q5=.37*T5*D1*S*SQR(T1)
3953 Q=Q1+Q2+Q3+Q4+Q5:R1=14.49/D1
3963 IF S<1.6 THEN F5=1.1:GOTO 4013
3973 IF S<2.2 THEN F5=1.2:GOTO 4013
3983 IF S<3 THEN F5=1.3:GOTO 4013
3993 IF S<3.5 THEN F5=1.4:GOTO 4013
4003 IF S<5 THEN F5=1.5
4013 IF T5>700 THEN F6=100:GOTO 4033
4023 F6=S+.12*T5
4033 R2=F5*S*W*F6/C:R=1.2*(R1+R2):I=SQR(Q/(.24*T1*R))
4043 PRINT "==================================================================="
4053 PRINT "D1=";D1*10,"D2=";D2*10,"D3=";D3*10
4063 PRINT "B=";B*10,"S=";S*10,"H=";H*10
4073 PRINT "T1=";T1
4083 PRINT "P1=";P1,"Q=";Q,"Q1=";Q1
4093 PRINT "Q2=";Q2,"Q3=";Q3,"Q4=";Q4,"Q5=";Q5
4103 PRINT "I=";I,"R=";R,"R1=";R1,"R2=";R2
4113 PRINT "==================================================================="
4123 S1=3.14*(D2^2-D3^2)/4:G1=263*(EXP(.057*I^2*T1/(S1^2))-1)
4133 G2=G1*(1-.28*SQR(T1)/H):U=I/P1:PRINT
4143 PRINT "U=";U,"S1=";S1:PRINT "G=";G,"G1=";G1,"G2=";G2
4153 IF U<.04 GOTO 4193
4163 PRINT "ВСПЛЕСКИ ЕСТЬ "
4173 IF GHJ=1 THEN LPRINT "ВСПЛЕСКИ ЕСТЬ "
4183 GOTO 4233
4193 PRINT "ВСПЛЕСКОВ НЕТ "
4203 IF GHJ=1 THEN LPRINT "ВСПЛЕСКОВ НЕТ "
4213 D1=D1*10:D2=D2*10:B=B*10:S=S*10:H=H*10
4223 D3=D3*10
4233 PRINT
4243 R7=1.5*P1:T7=2*T1:PRINT:PRINT:PRINT
4253 PRINT "                          РЕЗУЛЬТАТЫ РАСЧЕТА":PRINT:PRINT:PRINT
4263 IF GHJ=1 THEN LPRINT "                          РЕЗУЛЬТАТЫ РАСЧЕТА":LPRINT:LPRINT:LPRINT
4273 PRINT "СВАРОЧНЫЙ ТОК, КА I=";I;" +-5%"
4283 IF GHJ=1 THEN LPRINT "СВАРОЧНЫЙ ТОК, КА I=";I;" +-5%"
4293 PRINT "СВАРОЧНОЕ УСИЛИЕ, ДАН Р=";P1;" +-10%"
4303 IF GHJ=1 THEN LPRINT "СВАРОЧНОЕ УСИЛИЕ, ДАН Р=";P1;" +-10%"
4313 PRINT "КОВОЧНОЕ УСИЛИЕ, ДАН Р(К)=";R7
4323 IF GHJ=1 THEN LPRINT "КОВОЧНОЕ УСИЛИЕ, ДАН Р(К)=";R7
4333 PRINT "ВРЕМЯ СВАРКИ, С Т=";T1;" +-0.02 C"
4343 IF GHJ=1 THEN LPRINT "ВРЕМЯ СВАРКИ, С Т=";T1;" +-0.02 C"
4353 PRINT "ВРЕМЯ СЖАТИЯ, С Т=";T7
4363 IF GHJ=1 THEN LPRINT "ВРЕМЯ СЖАТИЯ, С Т=";T7
4373 PRINT "ВРЕМЯ ПРОКОВКИ, С Т=";T7
4383 IF GHJ=1 THEN LPRINT "ВРЕМЯ ПРОКОВКИ, С Т=";T7
4393 PRINT "ТЕМПЕРАТУРА НАГРЕВА СТЕНКИ БОНКИ Т=";G2
4403 IF GHJ=1 THEN LPRINT "ТЕМПЕРАТУРА НАГРЕВА СТЕНКИ БОНКИ T=";G2
4413 INPUT "  ЭСКИЗ СВАРИВАЕМЫХ ДЕТАЛЕЙ  (ДА - 1, НЕТ - 0)  ";I5
4423 IF I5=1 GOTO 4453
4433 GOTO 1553
4443 GHJ=0
4453 PRINT "ЭСКИЗ СВАРИВАЕМЫХ ДЕТАЛЕЙ"
4463 IF GHJ=1 THEN LPRINT "ЭСКИЗ СВАРИВАЕМЫХ ДЕТАЛЕЙ"
4473 PRINT "      H=";H
4483 IF GHJ=1 THEN LPRINT "      H=";H
4493 PRINT "!-----------------"
4503 PRINT "!                                           D2=";D2
4513 PRINT "!     !<------------------------------->!--------------------"
4523 PRINT "!     !                                 !"
4533 PRINT "!-----***********************************"
4543 PRINT "!     **         **         **         **   D3=";D3
4553 PRINT "!     **         **<------->**---------**--------------------"
4563 PRINT "!     **         **         **         **"
4573 PRINT "!     **         **         **         **   D1=";D1
4583 PRINT "!     **   !<----**---------**-----!---**--------------------"
4593 PRINT "!     **   !     **         **     !   **"
4603 PRINT "------**   !   *****************   !   **"
4613 PRINT "      !  * !  * !                * !   **"
4623 PRINT "      !    *    !                  *"
4633 PRINT "------!---------!---------------------/----------------------"
4643 PRINT "//////!/////////!/////////////////////!//////////////////////"
4653 PRINT "------!---------!---------------------/----------------------"
4663 PRINT "      !         !                     !    S=";S
4673 PRINT "      !         !                     !----------------------"
4683 PRINT "      !         !    B=";B
4693 PRINT "      !<------->!--------------------"
4703 IF GHJ=1 THEN GOTO 8973
4713 GOTO 1553
4723 PRINT "  <>  РАСЧЕТ РЕЖИМА ШОВНОЙ СВАРКИ"
4733 IF GHJ=1 THEN LPRINT "  <>  РАСЧЕТ РЕЖИМА ШОВНОЙ СВАРКИ"
4743 PRINT "      С ПРЕРЫВИСТЫМ ВКЛЮЧЕНИЕМ ТОКА."
4753 IF GHJ=1 THEN LPRINT "      С ПРЕРЫВИСТЫМ ВКЛЮЧЕНИЕМ ТОКА."

4763 INPUT "ВВЕДИТЕ ТОЛЩИНУ СВАРИВАЕМЫХ ДЕТАЛЕЙ, мм S=";S
4773 GOSUB 8673
4783 PRINT " Н У С       АУСТ СТАЛЬ        AL-СПЛАВЫ"
4793 PRINT "K5=3          K5=2.6            K5=2.2"
4803 PRINT "K6=1.2        K6=1.1            K6=1.3"
4813 PRINT "K7=0.04       K7=0.03           K7=0.02"
4823 PRINT "K8=0.6        K8=0.46           K8=0.26"
4833 PRINT "ДЛЯ СТАЛИ С ПОКРЫТИЕМ K8=0.82"
4843 TLX=0:INPUT "КОЭФФ. ШАГА ТОЧЕК К5=";K5
4853 INPUT "КОЭФФ. ВРЕМ. ИМП. К7=";K7
4863 INPUT "ВЕЛИЧИНА Т СВАРКИ/ Т ЦИКЛА К8=";K8
4873 PRINT "КОЭФФ. УЧ. ИЗМЕНЕНИЕ"
4883 INPUT "СОПР. ВО ВРЕМЯ СВАРКИ К6=";K6
4893 K2=2:K4=1.6:K1=.8:K3=.85:E=250
4903 REM РАСЧЕТ ШАГА ТОЧЕК И УСИЛИЯ
4913 S1=K5*S:S1=INT(S1+.5):F=1800*S+500
4923 IF E>300 THEN F=3500*S+1000
4933 D1=SQR(4*F/(3.14*E))
4943 PRINT "ТОЛЩИНА СВАРИВАЕМЫХ ДЕТАЛЕЙ S=";S;"мм"
4953 IF GHJ=1 THEN LPRINT "ТОЛЩИНА СВАРИВАЕМЫХ ДЕТАЛЕЙ S=";S;"мм"
4963 PRINT "ШАГ МЕЖДУ ТОЧКАМИ S1=";S1
4973 IF GHJ=1 THEN LPRINT "ШАГ МЕЖДУ ТОЧКАМИ S1=";S1
4983 PRINT "ДИАМ. КОНТ. ПОВ. ЭЛЕМЕНТА  D1=";D1;"  мм"
4993 IF GHJ=1 THEN LPRINT "ДИАМ. КОНТ. ПОВ. ЭЛЕМЕНТА  D1=";D1;"  мм"
5003 PRINT "УСИЛИЕ F=";F;"  H"
5013 IF GHJ=1 THEN LPRINT "УСИЛИЕ F=";F;"  H"
5023 REM ВРЕМЯ ЦИКЛА И СВАРКИ
5033 B1=K7*(1+S^2):B2=B1/K8
5043 B1=INT(50*(B1+.01))/50:B2=INT(50*(B2+.01))/50:B3=B2-B1:V=3.6*S1/B2:B=B1*D1/(D1+V*B1)
5053 REM ВВОД КОЭФФ. РАСТЕКАНИЯ ТОКА
5063 GOSUB 3373
5073 REM ЦИКЛ ПО ВРЕМЕНИ, ВЫЧ. СИЛЫ ТОКА
5083 S=S/1000:S1=S1/1000:D1=D1/1000:H1=H1/1000:H2=H2/1000:D2=D2/1000
5093 R6=R0*(1+W*T*4/5):R7=R0*(1+W*T)
5103 Q1=K1*3.14*4*SQR(A1*B)*(D1+4*SQR(A1*B))*2*S*C1*G1*T/4
5113 Q2=2*K2*3.14*D1*D1*SQR(A2*B)*C2*G2*T/8:Q3=3.14*D1^2*S*C1*G1*T/2:Q=Q1+Q2+Q3
5123 R=8*(A3*K3*R6*H1/(D1^2)+A4*K3*R7*H2/(D2^2))/(3.14*1000000!):J1=SQR(Q/(K6*R*B))
5133 REM РАСЧЕТ ТОКА ШУНТИРОВ. И ВТОР. ТОКА
5143 J2=J1*(.64/(1-1/SQR(D1^2/(4*S^2)+1))-.5):J=J1+J2
5153 PRINT "ВРЕМЯ ИМПУЛЬСА        B1=";B1;"  C"
5163 IF GHJ=1 THEN LPRINT "ВРЕМЯ ИМПУЛЬСА        B1=";B1;"  C"
5173 PRINT "ВРЕМЯ ПАУЗЫ           B3=";B3;"  C"
5183 IF GHJ=1 THEN LPRINT "ВРЕМЯ ПАУЗЫ           B3=";B3;"  C"
5193 PRINT "ВРЕМЯ ЦИКЛА           B2=";B2;"  C"
5203 IF GHJ=1 THEN LPRINT "ВРЕМЯ ЦИКЛА           B2=";B2;"  C"
5213 PRINT "СКОРОСТЬ СВАРКИ       V=";V;"  м/ч"
5223 IF GHJ=1 THEN LPRINT "СКОРОСТЬ СВАРКИ       V=";V;"  м/ч"
5233 PRINT "ТОК                   J1=";J1;"  A"
5243 IF GHJ=1 THEN LPRINT "ТОК                   J1=";J1;"  A"
5253 PRINT "ТОК ВТОРИЧНЫЙ         J=";J;"  A"
5263 IF GHJ=1 THEN LPRINT "ТОК ВТОРИЧНЫЙ         J=";J;"  A"
5273 PRINT " (СВАРОЧНЫЙ И ТОК ШУНТРОВАНИЯ)"
5283 IF GHJ=1 THEN LPRINT " (СВАРОЧНЫЙ И ТОК ШУНТРОВАНИЯ)"
5293 GOTO 1553
5303 PRINT "   <>  РЕЖИМ РУЧНОЙ ДУГОВОЙ СВАРКИ"
5313 IF GHJ=1 THEN LPRINT "   <>  РЕЖИМ РУЧНОЙ ДУГОВОЙ СВАРКИ"
5323 PRINT "ВВЕДИТЕ РАЗМЕРЫ В ММ : S - ТОЛЩИНА ДЕТАЛИ "
5333 INPUT "S=";S
5343 PRINT "A-ЗАЗОР, Р-ПРИТУПЛЕНИЕ, С-ВЫСОТА УСИЛИЕ, В-ШИРИНА ШВА, Y-УГОЛ, ГРАД."
5353 INPUT "A,P,C,B,Y ";A,P,C,B,Y
5363 PRINT "ВВЕДИТЕ ДИАМЕТР ЭЛЕКТРОДА В ММ"
5373 INPUT "D=";D
5383 PRINT "ДЛЯ УГЛОВОГО СОЕДИНЕНИЯ ВВЕДИТЕ К, ДЛЯ СТЫКОВОГО K=0"
5393 INPUT "K=";K
5403 Y=Y*3.14/180:F=S*A+((S-P)^2)*TAN(Y/2)+.75*C*B
5413 IF K<>0 THEN F=.5*K^2+1.05*K*C
5423 N=F/(10*D)
5433 IF F>10*D THEN F=10*D
5443 I=(20+6*D)*D:U=24:U1=1.15*I/F
5453 PRINT "ТОЛЩИНА ДЕТАЛИ S=";S;"  мм"
5463 PRINT "ДИАМЕТР ЭЛЕКТРОДА D=";D;"  мм"
5473 PRINT "ЗАЗОР А=";A;"  мм"
5483 PRINT "ШИРИНА ШВА B=";B;"  мм"
5493 IF GHJ=1 THEN LPRINT "ТОЛЩИНА ДЕТАЛИ S=";S;"  мм"
5503 IF GHJ=1 THEN LPRINT "ДИАМЕТР ЭЛЕКТРОДА D=";D;"  мм"
5513 IF GHJ=1 THEN LPRINT "ЗАЗОР А=";A;"  мм"
5523 IF GHJ=1 THEN LPRINT "ШИРИНА ШВА B=";B;"  мм"
5533 PRINT "ПРИТУПЛЕНИЕ P=";P;"  мм"
5543 PRINT "УСИЛЕНИЕ C=";C;"  мм"
5553 PRINT "K=";K;"  угол Y=";Y*180/3.14;"  град"
5563 IF GHJ=1 THEN LPRINT "ПРИТУПЛЕНИЕ P=";P;"  мм"
5573 IF GHJ=1 THEN LPRINT "УСИЛЕНИЕ C=";C;"  мм"
5583 IF GHJ=1 THEN LPRINT "K=";K;"  угол Y=";Y*180/3.14;"  град"
5593 PRINT "ПАРАМЕТРЫ РЕЖИМА"
5603 PRINT "ТОК СВАРКИ I=";I;" A"
5613 PRINT "НАПРЯЖЕНИЕ U=";U;" B"
5623 PRINT "СКОРОСТЬ СВАРКИ U1=";U1;" м/ч"
5633 IF GHJ=1 THEN LPRINT "ПАРАМЕТРЫ РЕЖИМА"
5643 IF GHJ=1 THEN LPRINT "ТОК СВАРКИ I=";I;" A"
5653 IF GHJ=1 THEN LPRINT "НАПРЯЖЕНИЕ U=";U;" B"
5663 IF GHJ=1 THEN LPRINT "СКОРОСТЬ СВАРКИ U1=";U1;" м/ч"
5673 PRINT "ПЛОЩАДЬ ПОПЕРЕЧНОГО СЕЧЕНИЯ ШВА F=";F;" MM^2"
5683 IF GHJ=1 THEN LPRINT "ПЛОЩАДЬ ПОПЕРЕЧНОГО СЕЧЕНИЯ ШВА F=";F;" MM^2"
5693 PRINT "ЧИСЛО ПРОХОДОВ N=";N
5703 IF GHJ=1 THEN LPRINT "ЧИСЛО ПРОХОДОВ N=";N
5713 GOTO 1553
5723 PRINT "   <>  РЕЖИМ СВАРКИ ПОД ФЛЮСОМ."
5733 IF GHJ=1 THEN LPRINT "   <>  РЕЖИМ СВАРКИ ПОД ФЛЮСОМ."
5743 INPUT "ВВЕДИТЕ ТОЛЩИНУ ДЕТАЛИ В ММ  S=";S
5753 INPUT "ВВЕДИТЕ ГЛУБИНУ ПРОВАРА В ММ  H0=";H0
5763 INPUT "ВВЕДИТЕ ДИАМЕТР ПРОВОЛОКИ В ММ  D=";D
5773 PRINT "ВВЕДИТЕ РОД И ПОЛЯРНОСТЬ ТОКА"
5783 INPUT "ПЕРЕМЕННЫЙ ТОК Т=1, ОБРАТНАЯ ПОЛЯРНОСТЬ Т=0, ПРЯМАЯ Т=2 ";T
5793 IF T=1 THEN K1=1.45-.1*D:GOTO 5823
5803 IF T=2 THEN K1=1.41-.125*D:GOTO 5823
5813 IF T=0 THEN K1=1.6-.1*D
5823 IF S<8 THEN I=100*H0/K1:GOTO 5843
5833 I=75*H0/K1
5843 P=3.14*D^2/4:J=I/P:X=140/D:Z=220/(D-1)
5853 IF Z>200 THEN Z=200
5863 PRINT "НЕОБХОДИМО X<J<Z"
5873 PRINT X;" < ";J;" < ";Z;"  -ЕСЛИ НЕРАВЕНСТВО НЕ ВЕРНО "
5883 PRINT "    РЕКОМЕНДУЕМ ИЗМЕНТЬ ГЛУБИНУ ПРОВАРА ДЛЯ ЭТОГО НАБЕРИТЕ -1"
5893 PRINT "    ЕСЛИ УСТРАИВАЕТ -0"
5903 INPUT FGH:IF FGH=1 GOTO 5753
5913 U=20+.05*I/(D^.5)
5923 IF T<>1 THEN U=.9*U
5933 V1=6250*D/I:F1=1.92*I/V1:V2=V1*F1/P
5943 IF T=1 THEN K2=1:GOTO 6003
5953 IF J<120 GOTO 5983
5963 IF T=0 THEN K2=.92:GOTO 6003
5973 IF T=2 THEN K2=1.12:GOTO 6003
5983 IF T=0 THEN K2=.367*(J^.1925):GOTO 6003
5993 IF T=2 THEN K2=2.82/(J^.1925):GOTO 6003
6003 W=K2*(19-.01*I)*D*U/I:Q=3060*I*U*.85/V1:A=SQR(.24*Q/W):H1=.0156*A:B=W*H1:C=F1/(.73*B)
6013 PRINT "ТОЛЩИНА ДЕТАЛИ S=";S;"  мм"
6023 IF GHJ=1 THEN LPRINT "ТОЛЩИНА ДЕТАЛИ S=";S;"  мм"
6033 PRINT "ДИАМЕТР ПРОВОЛОКИ D=";D;"  мм"
6043 IF GHJ=1 THEN LPRINT "ДИАМЕТР ПРОВОЛОКИ D=";D;"  мм"
6053 PRINT "ГЛУБИНА ПРОПЛАВЛЕНИЯ В ММ H0=";H0
6063 IF GHJ=1 THEN LPRINT "ГЛУБИНА ПРОПЛАВЛЕНИЯ В ММ H0=";H0
6073 PRINT "ДЕЙСТВИТЕЛЬНАЯ H1=";H1
6083 IF GHJ=1 THEN LPRINT "ДЕЙСТВИТЕЛЬНАЯ H1=";H1
6093 IF T=1 THEN PRINT "СВАРКА НА ПЕРЕМЕННОМ ТОКЕ"
6103 IF T=1 AND GHJ=1 THEN LPRINT "СВАРКА НА ПЕРЕМЕННОМ ТОКЕ":GOTO 6153
6113 IF T=2 THEN PRINT "СВАРКА НА ПРЯМОЙ ПОЛЯРНОСТИ":GOTO 6153
6123 IF T=2 AND GHJ=1 THEN LPRINT "СВАРКА НА ПРЯМОЙ ПОЛЯРНОСТИ":GOTO 6153
6133 IF T=0 THEN PRINT "СВАРКА НА ОБРАТНОЙ ПОЛЯРНОСТИ"
6143 IF T=0 AND GHJ=1 THEN LPRINT "СВАРКА НА ОБРАТНОЙ ПОЛЯРНОСТИ"
6153 PRINT "I=";I;" A","U=";U;" B":PRINT "СКОРОСТЬ СВАРКИ V1=";V1;" М/Ч"
6163 IF GHJ=1 THEN LPRINT "I=";I;" A","U=";U;" B":LPRINT "СКОРОСТЬ СВАРКИ V1=";V1;" М/Ч"
6173 PRINT "ШИРИНА ШВА B=";B;" мм","УСИЛЕНИЕ C=";C;" мм"
6183 IF GHJ=1 THEN LPRINT "ШРИНА ШВА B=";B;" мм","УСИЛЕНИЕ C=";C;" мм"
6193 PRINT "V2=";V2;" м/ч","W=";W,"ПЛОЩАДЬ ШВА F1=";F1;" мм^2"
6203 IF GHJ=1 THEN LPRINT "V2=";V2;" м/ч","W=";W,"ПЛОЩАДЬ ШВА F1=";F1;" мм^2"
6213 GOTO 1553
6223 REM 6
6233 PRINT "РАСЧЕТ ПАРАМЕТРОВ РЕЖИМА СВАРКИ В СРЕДЕ АРГОНА НЕПЛАВЯЩИМСЯ ЭЛ-ДОМ"
6243 IF GHJ=1 THEN LPRINT "РАСЧЕТ ПАРАМЕТРОВ РЕЖИМА СВАРКИ В СРЕДЕ АРГОНА НЕПЛАВЯЩИМСЯ ЭЛ-ДОМ"
6253 PRINT "КОД. ОБОЗНАЧЕНИЯ СПОСОБОВ СВАРКИ"
6263 PRINT "Q=4 - KRAS.4-AR-ДУГОВАЯ СВАРКА СТЫКОВОГО СОЕДИНЕНИЯ"
6273 PRINT " С ДВУХ СТОРОН БЕЗ РАЗДЕЛКИ КРОМОК"
6283 PRINT "Q=5 - ПОДПРОГРАММА KRAS.5 - AR-ДУГОВАЯ СВАРКА СТЫКОВОГО СОЕДИНЕНИЯ"
6293 PRINT " С ОДНОЙ СТОРОНЫ БЕЗ РАЗДЕЛКИ КРОМОК"
6303 INPUT "ВВЕДИТЕ КОД СПОСОБА СВАРКИ Q=";Q
6313 IF Q=5 GOTO 7113
6323 PRINT "ПОДПРОГРАММА KRAS.4"
6333 PRINT "РАСЧЕТ ПАРАМЕТРОВ РЕЖИМА AR-ДУГОВОЙ СВАРКИ СТЫКОВОГО СОЕДИНЕНИЯ"
6343 IF GHJ=1 THEN LPRINT "РАСЧЕТ ПАРАМЕТРОВ РЕЖИМА AR-ДУГОВОЙ СВАРКИ СТЫКОВОГО СОЕДИНЕНИЯ"
6353 PRINT "С ДВУХ СТОРОН БЕЗ РАЗДЕЛКИ КРОМОК"
6363 IF GHJ=1 THEN LPRINT "С ДВУХ СТОРОН БЕЗ РАЗДЕЛКИ КРОМОК"
6373 INPUT "ТОЛЩИНА МЕТАЛЛА S=";S
6383 INPUT "ДЛИНА ШВА       L=";L
6393 PRINT "                            ИСХОДНЫЕ ДАННЫЕ"
6403 IF GHJ=1 THEN LPRINT "                            ИСХОДНЫЕ ДАННЫЕ"
6413 PRINT "ТОЛЩИНА МЕТАЛЛА             S=";S;"MM"
6423 IF GHJ=1 THEN LPRINT "ТОЛЩИНА МЕТАЛЛА             S=";S;"MM"
6433 PRINT "ДЛИНА ШВА                   L=";L;"MM"
6443 IF GHJ=1 THEN LPRINT "ДЛИНА ШВА                   L=";L;"MM"
6453 IF S>6 THEN IF S<1.5 AND GHJ=1 THEN LPRINT "НЕТ РАСЧЕТА":STOP
6463 IF S>6 THEN IF S<1.5 THEN PRINT "НЕТ РАСЧЕТА":STOP
6473 B1=S:B2=B1+2:B3=S-.5:B4=B3+2
6483 PRINT "ПАРАМЕТРОВ РЕЖИМА ПО ОСТ-3-3086-75"
6493 H1=S/4:H2=H1+1:H3=S/5:H4=H3+.8
6503 IF S<=2 THEN I=50*S+10:GOTO 6553
6513 IF S<=2.5 THEN I=10*S+90:GOTO 6553
6523 IF S<=3.5 THEN I=35*S+27.5:GOTO 6553
6533 IF S<=4.5 THEN I=70*S-95:GOTO 6553
6543 I=1.333*S+160
6553 U=.364+S*10.456
6563 IF S<=2 THEN V=14:GOTO 6623
6573 IF S<=2.5 THEN V=22-4*S:GOTO 6623
6583 IF S<=3 THEN V=12:GOTO 6623
6593 IF S<=3.5 THEN V=18-2*S:GOTO 6623
6603 IF S<=4 THEN V=12.75-.5*S:GOTO 6623
6613 V=15-S
6623 IF S<=2.5 THEN P=3*S+1:GOTO 6643
6633 P=.777*S+6.555
6643 IF S<=2 THEN D1=3:GOTO 6683
6653 IF S<=2.5 THEN D1=3.5:GOTO 6683
6663 IF S<=4.5 THEN D1=4:GOTO 6683
6673 D1=5
6683 I1=INT(I/10)*10:I2=I1+10
6693 I4=I1:I3=I4-10
6703 U1=INT(U):U2=U1+1
6713 V1=INT(V):V2=V1+1
6723 Q1=INT(P):Q2=Q1:D2=2
6733 V3=INT(V*.7*(B1+B2+B3+B4)*(H1+H2+H3+H4)/4/(3.14*D2^2))
6743 Q3=L*V3*3.14*D2^2*7.85/V/2000000!
6753 IF S<=3 THEN D3=18:GOTO 6773
6763 D3=22
6773 PRINT
6783 PRINT "                             РЕЗУЛЬТАТЫ РАСЧЕТА "
6793 IF GHJ=1 THEN LPRINT "                             РЕЗУЛЬТАТЫ РАСЧЕТА "
6803 PRINT "   ТОЛЩИНА МЕТАЛЛА                         S=";S;"MM"
6813 IF GHJ=1 THEN LPRINT "   ТОЛЩИНА МЕТАЛЛА                         S=";S;"MM"
6823 PRINT "   СИЛА СВАРОЧНОГО ТОКА - ПЕРВЫЙ ШОВ       I1=";I1;" - ";I2;"A"
6833 IF GHJ=1 THEN LPRINT "   СИЛА СВАРОЧНОГО ТОКА - ПЕРВЫЙ ШОВ       I1=";I1;" - ";I2;"A"
6843 PRINT "   СИЛА СВАРОЧНОГО ТОКА - ВТОРОЙ ШОВ       I2=";I3;" - ";I4;"A"
6853 IF GHJ=1 THEN LPRINT "   СИЛА СВАРОЧНОГО ТОКА - ВТОРОЙ ШОВ       I2=";I3;" - ";I4;"A"
6863 PRINT "   НАПРЯЖЕНИЕ ДУГИ                         U1=U2=";U1;" - ";U2;"B"
6873 IF GHJ=1 THEN LPRINT "   НАПРЯЖЕНИЕ ДУГИ                         U1=U2=";U1;" - ";U2;"B"
6883 PRINT "   СКОРОСТЬ СВАРКИ                         V1=V2=";V1;" - ";V2;"М/Ч"
6893 IF GHJ=1 THEN LPRINT "   СКОРОСТЬ СВАРКИ                         V1=V2=";V1;" - ";V2;"М/Ч"
6903 PRINT "   ДИАМЕТР W-ЭЛЕКТРОДА                     D1=";D1;"MM"
6913 IF GHJ=1 THEN LPRINT "   ДИАМЕТР W-ЭЛЕКТРОДА                     D1=";D1;"MM"
6923 PRINT "   ДИАМЕТР ПРИСАДОЧНОЙ ПРОВОЛОКИ           D2=";D2;"MM"
6933 IF GHJ=1 THEN LPRINT "   ДИАМЕТР ПРИСАДОЧНОЙ ПРОВОЛОКИ           D2=";D2;"MM"
6943 PRINT "   ДИАМЕТР СОПЛА ГОРЕЛКИ                   D3=";D3;"MM"
6953 IF GHJ=1 THEN LPRINT "   ДИАМЕТР СОПЛА ГОРЕЛКИ                   D3=";D3;"MM"
6963 PRINT "   РАСХОД AR В ГОРЕЛКЕ                     Q1=Q2=";Q1;"Л/МИН"
6973 IF GHJ=1 THEN LPRINT "   РАСХОД AR В ГОРЕЛКЕ                     Q1=Q2=";Q1;"Л/МИН"
6983 PRINT "   СКОРОСТЬ ПОДАЧИ ПРИСАДОЧНОЙ ПРОВОЛОКИ   V3=";V3;"М/Ч"
6993 IF GHJ=1 THEN LPRINT "   СКОРОСТЬ ПОДАЧИ ПРИСАДОЧНОЙ ПРОВОЛОКИ   V3=";V3;"М/Ч"
7003 PRINT "   РАСХОД ПРИСАДОЧНОЙ ПРОВОЛОКИ            Q3=";Q3;"КГ"
7013 IF GHJ=1 THEN LPRINT "   РАСХОД ПРИСАДОЧНОЙ ПРОВОЛОКИ            Q3=";Q3;"КГ"
7023 PRINT "   ШИРИНА ПЕРВОГО ШВА                      B1=";B1;"-";B2;"MM"
7033 IF GHJ=1 THEN LPRINT "   ШИРИНА ПЕРВОГО ШВА                      B1=";B1;"-";B2;"MM"
7043 PRINT "   ШИРИНА ВТОРОГО ШВА                      B2=";B3;"-";B4;"MM"
7053 IF GHJ=1 THEN LPRINT "   ШИРИНА ВТОРОГО ШВА                      B2=";B3;"-";B4;"MM"
7063 PRINT "   ВЫСОТА УСИЛЕНИЯ ПЕРВОГО ШВА             H1=";H1;"-";H2;"MM"
7073 IF GHJ=1 THEN LPRINT "   ВЫСОТА УСИЛЕНИЯ ПЕРВОГО ШВА             H1=";H1;"-";H2;"MM"
7083 PRINT "   ВЫСОТА УСИЛЕНИЯ ВТОРОГО ШВА             H2=";H3;"-";H4;"MM"
7093 IF GHJ=1 THEN LPRINT "   ВЫСОТА УСИЛЕНИЯ ВТОРОГО ШВА             H2=";H3;"-";H4;"MM"
7103 GOTO 7513
7113 PRINT "AR ДУГОВАЯ СВ. СТЫК. СОЕДИНЕНИЯ С 1 СТОР. НА ВЕСУ С ПОДДУВОМ AR"
7123 IF GHJ=1 THEN LPRINT "AR ДУГОВАЯ СВ. СТЫК. СОЕДИНЕНИЯ С 1 СТОР. НА ВЕСУ С ПОДДУВОМ AR"
7133 PRINT "РАСЧЕТНАЯ ТОЛЩИНА МЕТАЛЛА ОТ 1.5 ДО 4.5 ММ"
7143 INPUT "ТОЛЩИНА МЕТАЛЛА S=";S
7153 INPUT "ДЛИНА ШВА       L=";L
7163 PRINT "                       ИСХОДНЫЕ ДАННЫЕ"
7173 PRINT " ТОЛЩИНА МЕТАЛЛА     S=";S
7183 PRINT " ДЛИНА ШВА           L=";L;"MM"
7193 IF S<1.5 THEN IF S>4.5 THEN PRINT "НЕТ РАСЧЕТА":STOP
7203 B1=S+1:B2=B1+2.5
7213 H1=S/4:H2=H1+1:I=40*(S+1)-.81*S^2:U=.364*S+10.564:V=15-((S^3-3.98)/S^2)
7223 I1=I-10:I2=I+10:U1=U-.5:U2=U+.5:V1=V-1:V2=V+1
7233 I1=(INT((I1*2+5)/10))*5:I2=(INT((I2*2+5)/10))*5
7243 IF S<=2.5 GOTO 7283
7253 IF S<=3.5 GOTO 7293
7263 D1=4:D2=22:Q1=10:Q2=12
7273 Q3=7:Q4=9:D3=2:GOTO 7323
7283 D1=3:D2=18:Q1=6:Q2=7
7293 Q3=3:Q4=4:D3=1.6:GOTO 7323
7303 D1=4:D2=22:Q1=7:Q2=8
7313 Q3=4:Q4=5:D3=2
7323 A=.5
7333 F=S*A+.7*(B1+B2)*(H1+H2)/4
7343 V3=V*F/3.14*D3^2/4
7353 C=L*V3*(3.14*D3^2/4)*7.85/(V*2000000!)
7363 PRINT "                            РЕЗУЛЬТАТЫ РАСЧЕТА "
7373 PRINT "  ДИАМЕТР ЭЛЕКТРОДА                           D1=";D1;"MM"
7383 PRINT "  ДИАМЕТР СОПЛА ГОРЕЛКИ                       D2=";D2;"MM"
7393 PRINT "  ДИАМЕТР ПРИСАДОЧНОЙ ПРОВОЛОКИ               D3=";D3";MM"
7403 PRINT "  СИЛА СВАРОЧНОГО ТОКА                        I=";I1;"-";I2;"A"
7413 PRINT "  НАПРЯЖЕНИЕ ДУГИ                             U=";U1;"-";U2;"B"
7423 PRINT "  СКОРОСТЬ СВАРКИ                             V=";V1;"-";V2;"М/Ч"
7433 PRINT "  РАСХОД AR В ГОРЕЛКЕ                         Q=";Q1;"-";Q2;"Л/МИН"
7443 PRINT "  РАСХОД AR НА ПОДДУВ                         Q3=";Q3;"-";Q4;"Л/МИН"
7453 PRINT "  ВЫСОТА УСИЛЕНИЯ                             H=";H1;"-";H2;"MM"
7463 PRINT "  ШИРИНА ШВА                                  B=";B1;"-";B2;"MM"
7473 PRINT "  МАКСИМ. ДОПУСТИМЫЙ ЗАЗОР                    A=";A;"MM"
7483 PRINT "  СКОРОСТЬ ПОДАЧИ ПРИСАДОЧНОЙ ПРОВОЛОКИ       V3=";V3;"М/Ч"
7493 PRINT "  РАСХОД ПРИСАДОЧНОГО МЕТАЛЛА                 C=";C;"КГ"
7503 IF GHJ=1 GOTO 8523
7513 GOTO 1553
7523 REM 5
7533 PRINT "     <>  РЕЖИМ СВАРКИ В СО2"
7543 IF GHJ=1 THEN LPRINT "     <>  РЕЖИМ СВАРКИ В СО2"
7553 PRINT "ВВЕДИТЕ ТОЛЩИНУ ДЕТАЛИ И ДИАМЕТР ПРОВОЛОКИ В ММ"
7563 INPUT "S=";S:INPUT "D=";D
7573 PRINT "ВВЕДИТЕ РАЗМЕРЫ ШВА В ММ"
7583 PRINT "Z-ЗАЗОР, P-ПРИТУПЛЕНИЕ, C-УСИЛЕНИЕ, B-ШИРИНА ШВА, Y-УГОЛ, ГРАД."
7593 INPUT "Z,P,C,B,Y";Z,P,C,B,Y
7603 Y=Y*3.14/180
7613 L=10*D:I1=90*D^2:I2=245*(D^1.25)
7623 F=S*Z+((S-P)^2)*TAN(Y/2)+.75*C*B
7633 U1=3.65*(I1^.37):U2=3.65*(I2^.37)
7643 E=3.14*D*D/4:J1=I1/E:J2=I2/E
7653 W1=.176*J1-.000448*J1*J1-4.72:W2=.176*J2-.000448*J2*J2-4.72
7663 A1=1.12*(I1^.32)*(D^(-.64))*(L^.38)
7673 A2=1.12*(I2^.32)*(D^(-.64))*(L^.38)
7683 IF J1<120 THEN K=.367*(J1^.1925):GOTO 7703
7693 K=.92
7703 H1=K*(19-.01*I1)*D*U1/I1
7713 IF J2<120 THEN K=.367*(J2^.1925):GOTO 7733
7723 K=.92
7733 H2=K*(19-.01*I2)*D*U2/I2
7743 W1=W1/100:W2=W2/100
7753 V1=.13*A1*(1-W1)*I1/F
7763 V2=.13*A2*(1-W2)*I2/F
7773 V3=.163*A1*I1/(D^2):V4=.163*A2*I2/(D^2)
7783 B1=13*((I1*U1)^.308)*(V1^(-.846))/((SQR(D)^.308))
7793 B2=13*((I2*U2)^.308)*(V2^(-.846))/((SQR(D)^.308))
7803 X1=B1/H1:X2=B2/H2
7813 C1=F/(.73*B1):C2=F/(.73*B2)
7823 PRINT "РЕЖИМ СВАРКИ"
7833 IF GHJ=1 THEN LPRINT "РЕЖИМ СВАРКИ"
7843 PRINT "ТОЛЩИНА ДЕТАЛИ S=";S,"ДИАМЕТР ПРОВОЛОКИ D=";D,"Imin=";I1,"Imax=";I2
7853 IF GHJ=1 THEN LPRINT "ТОЛЩИНА ДЕТАЛИ S=";S,"ДИАМЕТР ПРОВОЛОКИ D=";D,"Imin=";I1,"Imax=";I2
7863 PRINT "L=";L;"MM","F=";F;"MM2","Y=";Y*180/3.14
7873 IF GHJ=1 THEN LPRINT "L=";L;"MM","F=";F;"MM2","Y=";Y*180/3.14
7883 PRINT "ПРИ Imin U=";U1;"B","V1=";V1;"M/Ч","V2=";V3;"M/Ч"
7893 IF GHJ=1 THEN LPRINT "ПРИ Imin U=";U1;"B","V1=";V1;"M/Ч","V2=";V3;"M/Ч"
7903 PRINT "W1=";W1,"A1=";A1,"H1=";H1,"B1=";B1
7913 IF GHJ=1 THEN LPRINT "W1=";W1,"A1=";A1,"H1=";H1,"B1=";B1
7923 PRINT "X1=";X1,"C1=";C1
7933 IF GHJ=1 THEN LPRINT "X1=";X1,"C1=";C1
7943 PRINT "ПРИ Imax U=";U2;"B","V1=";V2;"M/Ч","V2=";V4;"M/Ч"
7953 IF GHJ=1 THEN LPRINT "ПРИ Imax U=";U2;"B","V1=";V2;"M/Ч","V2=";V4;"M/Ч"
7963 PRINT "W2=";W2,"A2=";A2,"H2=";H2,"B2=";B2
7973 IF GHJ=1 THEN LPRINT "W2=";W2,"A2=";A2,"H2=";H2,"B2=";B2
7983 PRINT "X2=";X2,"ВЫСОТА УСИЛЕНИЯ C2=";C2
7993 IF GHJ=1 THEN LPRINT "X2=";X2,"ВЫСОТА УСИЛЕНИЯ C2=";C2
8003 GOTO 1553
8013 PRINT "    <>  РЕЖИМ ЭЩС"
8023 IF GHJ=1 THEN LPRINT "    <>  РЕЖИМ ЭЛЕКТРО-ШЛАКОВАЯ СВАРКА"
8033 PRINT "ВВЕДИТЕ ТОЛЩИНУ ДЕТАЛЕЙ S И ЗАЗОР Z В ММ"
8043 INPUT "S,Z  ";S,Z
8053 INPUT "ВВЕДИТЕ растояние между электродами М1 В ММ  М1=";M1
8063 INPUT "ВВЕДИТЕ КОЭФФИЦИЕНТЫ А,В,К  ";A,B,K
8073 INPUT "ВВЕДИТЕ КОЭФФИЦИЕНТ НАПЛАВКИ L В Г/(А*Ч)  L=";L
8083 INPUT "ВВЕДИТЕ ПЛОТНОСТЬ G В Г/(СМ^3)  G=";G
8093 N=INT(S/(M1-8)+.5)
8103 I=A+B*(S/N)
8113 V1=I/1.9
8123 U=12+SQR(125+S/(.075*N))
8133 H=I*((.0000375)*I-(.0025))+30
8143 V2=(N*L*I)/(G*Z*S*K)
8153 V3=66-.22*(S/N)
8163 T=(.0375)*(S/N)+.75
8173 M2=S/N+8
8183 PRINT "S=";S,"Z=";Z,"M1=";M1,"A=";A
8193 IF GHJ=1 THEN LPRINT "S=";S,"Z=";Z,"M1=";M1,"A=";A
8203 PRINT "B=";B,"K=";K,"L=";L,"G=";G
8213 IF GHJ=1 THEN LPRINT "B=";B,"K=";K,"L=";L,"G=";G
8223 PRINT "N=";N,"I=";I,"V1=";V1,"U=";U
8233 IF GHJ=1 THEN LPRINT "N=";N,"I=";I,"V1=";V1,"U=";U
8243 PRINT "H=";H,"V2=";V2,"V3=";V3
8253 IF GHJ=1 THEN LPRINT "H=";H,"V2=";V2,"V3=";V3
8263 PRINT "T=";T,"M2=";M2
8273 IF GHJ=1 THEN LPRINT "T=";T,"M2=";M2
8283 PRINT
8293 GOTO 1240
8303 PRINT:PRINT "                      ЭСКИЗ СВАРИВАЕМЫХ ДЕТАЛЕЙ":PRINT
8313 PRINT " !          H="
8323 PRINT " !"
8333 PRINT " ---------********************************************"
8343 PRINT " !        *///////////////*        */////////////////*"
8353 PRINT " !        *///////////////*        */////////////////*   D="
8363 PRINT " !        *<--------------*--------*---------------->*------------"
8373 PRINT " !        *///////////////*        */////////////////*"
8383 PRINT " !        *///////////////*        */////////////////*   D1="
8393 PRINT " !        *///////////////*<------>*/////////////////*------------"
8403 PRINT " !        *///////////////*        */////////////////*"
8413 PRINT " !         *//////////////*        *////////////////*"
8423 PRINT " !          */////////////*        *///////////////*"
8433 PRINT " !===========*////////////*        *//////////////*==============="
8443 PRINT " !----------=**************************************=--------------"
8453 PRINT " !          =!                                    !="
8463 PRINT " !===========!                                    !==============="
8473 PRINT " !          !!                                    !!     D2="
8483 PRINT " !          !!<---------------------------------->!!--------------"
8493 PRINT " !          !                                      !     D3="
8503 PRINT " !          !<------------------------------------>!--------------"
8513 PRINT:GOTO 1793
8523 LPRINT "                            РЕЗУЛЬТАТЫ РАСЧЕТА "
8533 LPRINT "  ДИАМЕТР ЭЛЕКТРОДА                           D1=";D1;"MM"
8543 LPRINT "  ДИАМЕТР СОПЛА ГОРЕЛКИ                       D2=";D2;"MM"
8553 LPRINT "  ДИАМЕТР ПРИСАДОЧНОЙ ПРОВОЛОКИ               D3=";D3";MM"
8563 LPRINT "  СИЛА СВАРОЧНОГО ТОКА                        I=";I1;"-";I2;"A"
8573 LPRINT "  НАПРЯЖЕНИЕ ДУГИ                             U=";U1;"-";U2;"B"
8583 LPRINT "  СКОРОСТЬ СВАРКИ                             V=";V1;"-";V2;"М/Ч"
8593 LPRINT "  РАСХОД AR В ГОРЕЛКЕ                         Q=";Q1;"-";Q2;"Л/МИН"
8603 LPRINT "  РАСХОД AR НА ПОДДУВ                         Q3=";Q3;"-";Q4;"Л/МИН"
8613 LPRINT "  ВЫСОТА УСИЛЕНИЯ                             H=";H1;"-";H2;"MM"
8623 LPRINT "  ШИРИНА ШВА                                  B=";B1;"-";B2;"MM"
8633 LPRINT "  МАКСИМ. ДОПУСТИМЫЙ ЗАЗОР                    A=";A;"MM"
8643 LPRINT "  СКОРОСТЬ ПОДАЧИ ПРИСАДОЧНОЙ ПРОВОЛОКИ       V3=";V3;"М/Ч"
8653 LPRINT "  РАСХОД ПРИСАДОЧНОГО МЕТАЛЛА                 C=";C;"КГ"
8663 GOTO 1553
8673 PRINT "*****************************************************************"
8683 PRINT "*           ТАБЛИЦА МАРОК СТАЛЕЙ И ИХ КОД                       *"
8693 PRINT "******************************************************************"
8703 PRINT "*                 КОД - МАРКА СТАЛИ                              *"
8713 PRINT "*     1-СТАЛЬ3;  2-10Кп;  3-20;  4-45;  5-30ХГСА;  6-А12         *"
8723 PRINT "* 7-10ХСНД; 8-12Х18Н9Т; 9-Ti сплавы; 10-Al сплавы; 11-Латунь     *"
8733 PRINT "******************************************************************"
8743 PRINT "НАЙДИТЕ В ТАБЛИЦЕ  МАРКУ МАТЕРИАЛА И ВВЕДИТЕ ЕЕ КОД"
8753 INPUT "(ЕСЛИ ВАШЕЙ СТАЛИ НЕТ, ТО ВВЕДИТЕ 0) K=";K
8763 INPUT "ВВЕДИТЕ МАРКУ МАТЕРИАЛА ...";A$
8773 IF K=0 GOTO 2993
8783 IF K=1 GOTO 8893
8793 IF K=2 GOTO 8893
8803 IF K=3 GOTO 8893
8813 IF K=4 GOTO 8893
8823 IF K=5 GOTO 8903
8833 IF K=6 GOTO 8903
8843 IF K=7 GOTO 8903
8853 IF K=8 GOTO 8913
8863 IF K=9 GOTO 8923
8873 IF K=10 GOTO 8933
8883 IF K=11 GOTO 8943
8893 C1=670:G1=7830:A1=8:T=1530:R0=.13:W=.0064:E=200:GOTO 3123
8903 C1=670:G1=7830:A1=8:T=1480:R0=.22:W=.003:E=280:GOTO 3123
8913 C1=670:G1=7860:A1=6:T=1440:R0=1:W=6.000001E-04:E=400:GOTO 3123
8923 C1=620:G1=4550:A1=4.5:T=1700:R0=1.3:W=.001:E=350:GOTO 3123
8933 C1=1100:G1=2400:A1=50:T=638:R0=.05:W=.002:E=100:GOTO 3123
8943 C1=450:G1=8900:A1=74:T=1083:R0=.028:W=.0028:E=130:GOTO 3123
8953 RETURN
8963 GOTO 3123
8973 LPRINT "!-----------------"
8983 LPRINT "!                                           D2=";D2
8993 LPRINT "!     !<------------------------------->!--------------------"
9003 LPRINT "!     !                                 !"
9013 LPRINT "!-----***********************************"
9023 LPRINT "A     **         **         **         **"
9033 LPRINT "!     **         **         **         **"
9043 LPRINT "!     **         **         **         **   D3=";D3
9053 LPRINT "!     **         **<------->**---------**--------------------"
9063 LPRINT "!     **         **         **         **"
9073 LPRINT "!     **         **         **         **   D1=";D1
9083 LPRINT "!     **   !<----**---------**-----!---**--------------------"
9093 LPRINT "!     **   !     **         **     !   **"
9103 LPRINT "------**   !   *****************   !   **"
9113 LPRINT "      !  * !  * !                * !   **"
9123 LPRINT "      !    *    !                  *"
9133 LPRINT "------!---------!---------------------/----------------------"
9143 LPRINT "//////!/////////!/////////////////////!//////////////////////"
9153 LPRINT "------!---------!---------------------/----------------------"
9163 LPRINT "      !         !                     !    S=";S
9173 LPRINT "      !         !                     !----------------------"
9183 LPRINT "      !         !    B=";B
9193 LPRINT "      !<------->!--------------------"
9203 GOTO 1553
9213 END
9223 LPRINT "СТАЛЬ АУСТЕНИТНАЯ, ОБЛАСТЬ ДИАГРАММЫ 02": GOTO 9293
9233 LPRINT "СТАЛЬ МАРТЕНСИТНАЯ, ОБЛАСТЬ ДИАГРАММЫ 01": GOTO 9303
9243 LPRINT "СТАЛЬ ПЕРЕХОДНОГО КЛАССА АУСТЕНИТНО-МАРТЕНСИТНАЯ, ОБЛАСТЬ ДИАГРАММЫ 03": GOTO 9313
9253 LPRINT "СТАЛЬ АУСТЕНИТНО-ФЕРРИТНАЯ, ОБЛАСТЬ ДИАГРАММЫ 04": GOTO 9313
9263 LPRINT "СТАЛЬ ФЕРРИТНАЯ, ОБЛАСТЬ ДИАГРАММЫ 05": GOTO 9323
9273 LPRINT "СТАЛЬ МАРТЕНСИТНО-ФЕРРИТНАЯ, ОБЛАСТЬ ДИАГРАММЫ 06": GOTO 9323
9283 LPRINT "СТАЛЬ АУСТЕНИТНО-МАРТЕНСИТНО-ФЕРРИТНАЯ, ОБЛАСТЬ ДИАГРАММЫ 07": GOTO 9333
9293 IF GHJ=1 THEN LPRINT "ВОЗМОЖНО ОБРАЗОВАНИЕ ГОРЯЧИХ (КРИСТАЛИЗАЦИОННЫХ ТРЕЩИН. СВАРКА БЕЗ   ПРЕДВАРИТЕЛЬНОГО ПОДОГРЕВА. ПРИМЕНЯТЬ СВАРОЧНЫЕ МАТЕРИАЛЫ, ОБЕСПЕЧИВАЮЩИЕ В НАПЛАВЛЕННОМ МЕТАЛЛЕ СОДЕРЖАНИЕ ФЕРРИТА 5-8%": GOTO 1553
9303 LPRINT "ВОЗМОЖНО ОБРАЗОВАНИЕ ХОЛОДНЫХ ТРЕЩИН В ШВЕ И ОКОЛОШОВНОЙ ЗОНЕ. НЕОБХОДИМ ПРЕДВАРИТЕЛЬНЫЙ ПОДОГРЕВ":PRINT: GOTO 1553
9313 LPRINT "ВОЗМОЖНО ПОЯВЛЕНИЕ ХРУПКОСТИ ПОСЛЕ НАГРЕВА ДО 400-900 ГРАД. ТЕМПЕРАТУРА АУСТЕНИТНОГО И МАРТЕНСИТНОГО ПРЕВРАЩЕНИЯ АС3=900 ТМ=500 ГРАД.":GOTO 1553
9323 LPRINT "МЕТАЛЛ ШВА В ОКОЛОШОВНОЙ ЗОНЕ ПОДВЕРЖЕН ЗАКАЛКЕ": GOTO 9303
9333 LPRINT "ВОЗМОЖНО ПОЯВЛЕНИЕ ВЫСОКОТЕМПЕРАТУРНОЙ ХРУПКОСТИ"
9343 GOTO 1543