Фотографии и .json

Option Explicit
Dim oFSO, oItems, oIPr, oImg, oStm, oRgx, F, FN, JSON, Text, D
Set oFSO = CreateObject("Scripting.FileSystemObject")
Set oItems = CreateObject("Shell.Application")._
Namespace(oFSO.GetAbsolutePathName("")).Items
oItems.Filter 8256, "*.jpg;*.jpeg"
If oItems.Count Then
   Set oIPr = CreateObject("WIA.ImageProcess")
   Set oImg = CreateObject("WIA.ImageFile")
   Set oStm = CreateObject("ADODB.Stream")
   Set oRgx = New RegExp: oRgx.Global = 1
   oIPr.Filters.Add oIPr.FilterInfos("Exif").FilterID
   oIPr.Filters(1).Properties("Type") = 1002
   oIPr.Filters(1).Properties("ID") = 36867
   oStm.Open : oStm.CharSet = "UTF-8"
   oRgx.Pattern = "\d+ [а-я]([^U]+?(?= U))"
   For Each F in oItems
      FN = F.Path: JSON = FN + ".json"
      If oFSO.FileExists(JSON) Then
         oStm.LoadFromFile JSON
         Text = oStm.ReadText
         If oRgx.Test(Text) Then
            D = CDate(Replace(oRgx.Execute(Text)(1), ChrW(8239) & "г.,", ""))
            oIPr.Filters(1).Properties.Item("Value") = Year(D) & ":" & Right("0" &_
            Month(D), 2) & ":" & Right("0" & Day(D), 2) & " " & TimeValue(D)
            oImg.LoadFile FN: oIPr.Apply(oImg).SaveFile FN & "_"
            oFSO.GetFile(FN).Delete: oFSO.GetFile(FN & "_").Name = F
            F.ModifyDate = D
         End If
      End If
   Next
   oStm.Close
   Set oStm = Nothing
   Set oIPr = Nothing
   Set oImg = Nothing
   Set oRgx = Nothing
End If
Set oItems = Nothing
Set oFSO   = Nothing