Триггер с SCOPE_IDENTITY()

CREATE TRIGGER Manager
  ON EmployeeINFO --VIEW
  INSTEAD OF INSERT AS
  BEGIN 
     DECLARE @Newid INT 
     SET @Newid = SCOPE_IDENTITY() 
    declare @Table table (Name nvarchar(15), Post nvarchar(25),
                      BirthDate date, [Address] nvarchar(50),Phone char(12));
     merge into Employees 
    using inserted s on 1 = 0
      when not matched then
      insert
      ( Name,Post,Salary) 
       values
      (s.Name,s.Post,s.Salary,)       
       output
        s.BirthDate, s.[Address],s.Phone into @Table ( BirthDate,[Address],Phone); 
      insert into dbo.EmployeesInfo 
      (ID, BirthDate,[Address],Phone)
     select
      @Newid, BirthDate,[Address],Phone       
       from @Table;              
       END

 INSERT INTO  EmployeeINFO (Name,Post,Salary,BirthDate,Address,Phone) VALUES ( 'Хрюша',
    'Генеральный поросёнок',90000,'2009-12-01', 'Помидоркина 9', '(031)3219821')

create table dbo.t1 (id int identity primary key, a int);
create table dbo.t2 (id int primary key, b int);
go
 
create view dbo.vt
as
select
 t1.id, t1.a, t2.b
from
 dbo.t1 t1 join
 dbo.t2 t2 on t2.id = t1.id;
go
 
create trigger dbo.trvt
on dbo.vt
instead of insert
as
begin
 set nocount on;
 
 declare @t table (id int, b int);
 
 merge into dbo.t1 t
 using inserted s on 1 = 0
 when not matched then
  insert
   (a)
  values
   (s.a)
  output
   inserted.id, s.b into @t (id, b);
 
 insert into dbo.t2
  (id, b)
  select
   id, b
  from
   @t;
end;
go
 
insert into dbo.vt (a, b) values (10, 20);
 
select * from dbo.t1;
select * from dbo.t2;
select * from dbo.vt;
go
 
drop view dbo.vt;
drop table dbo.t1, dbo.t2;
go