Если слово in входит в строку то переменной t присвоить значение true

uses crt;
var s:string;
    i:integer;
    t:boolean;
begin
 writeln('Ââåäèòå ñòðîêó :');
  readln(s);
  for i:=1 to length(s) do
   if (s[i]='i')and (s[i+1]='n') then
    t:=true;
  writeln('T=',t);
end.

t:=Pos(' in ',' '+s+' ')<>0;

program Project1;
 
{Задача:
Проверить - присутствует ли заданное слово в строке.}
 
{Перевод букв строки в верхний регистр. Для кодовой страницы CP866 (DOS).}
function UpCase866(const aStr : String) : String;
var
  S : String;
  i : Integer;
begin
  S := aStr;
  for i := 1 to Length(S) do
    if S[i] in ['а'..'п'] then
      S[i] := Chr(Ord(S[i]) - 32)
    else if s[i] in ['р'..'я'] then
      S[i] := Chr(Ord(S[i]) - 80)
    else if S[i] = 'ё' then
      S[i]:='Ё'
    else
      S[i] := UpCase(S[i]);
  UpCase866 := S;
end;
 
const
  {Множество разделителей слов.}
  D = ['.', ',', ':', ';', '!', '?', '-', ' ', #9, #10, #13];
var
  S, Sf : String;
  i, Len, LenW, LenF : Integer;
  F : Boolean;
begin
  repeat
    Writeln('Задайте строку:');
    Readln(S);
    Writeln('Задайте искомое слово:');
    Readln(Sf);
    Sf := UpCase866(Sf); {Приведение букв к верхнему регистру.}
 
    {Решение.}
    Len := Length(S); {Длина строки.}
    LenF := Length(Sf); {Длина искомого слова.}
    LenW := 0; {Длина текущего слова.}
    F := False; {True - слово найдено, иначе - False.}
    for i := 1 to Len do {Перебор символов строки слева - направо.}
      if not (S[i] in D) then {Если символ принадлежит слову.}
      begin
        Inc(LenW); {Учитываем очередной символ в длине текущего слова.}
        if (i = Len) or (S[i + 1] in D) then {Отслеживаем конец слова.}
        begin
          {Если текущее слово совпало с искомым словом.}
          if (LenW = LenF) and (Sf = UpCase866(Copy(S, i - LenW + 1, LenW))) then
          begin
            F := True;
            Break;
          end;
          LenW := 0;
        end;
      end;
 
    {Ответ.}
    if F then
      Writeln('Слово найдено.')
    else
      Writeln('Слово не найдено.');
 
    Writeln('Повторить - Enter. Выход - любой символ + Enter.');
    Readln(S);
  until S <> '';
end.

          if (LenW = LenF) and (Sf = UpCase866(Copy(S, i - LenW + 1, LenW))) then