Очередь на динамическом списке. Поместить гласные и согласные буквы в разные очереди. Исправить код.

uses crt;
type
    PSpisok=^Spisok;
    Spisok=record
    inf:char;
    link:PSpisok;
    ref:PSpisok;
    end;
var glas,soglas,sim,sn:string;
    i:integer;
    px,py:PSpisok;
    a:^char;
    gl:='уеыаоэяиюУЕЫАОЭЯИЮ';
    sogl:='йцкнгшщзхфвпрлджчсмтбЙЦКНГШЩЗХФВПРЛДЖЧСМТБ';
begin
    gotoxy(10,230);
    writeln('Введите символы, ограниченные точкой. Конец ввода +');
    py:=nil;
    read(a^);
    while a^<>'+' do
    begin
    px:=py;
    new(py);
    py^.inf:=a^;
    py^.ref:=px;
    read(a^);
    end;
    while py<>'+' do
    begin
    sn:='';
    sim:='';
    for i:=1 to length (a^) do
        begin
        if a^,sogl<>0 then sn:=sn+a^;
        if a^,gl<>0 then sim:=sim+a^;
        end;
    end;
    end;
clrscr;
writeln('Была введена следующая строка');
writeln(a^);
writeln('Согласные');
writeln(sn);
writeln('Гласные');
writeln(sim);
readln;
end.

uses crt;
type plist=^tlist;
tlist=record
    zn: string;
    prev:pList;
end;
 
procedure Push(var last:plist;a:string);
var p:plist;
begin
  new(p);
  p^.zn:=a;
  p^.prev:=nil;
  if (last=nil) then
     last:=p
  else
  begin
    p^.prev:=last;
    last:=p;
  end;
end;
 
procedure Push1(var last1 :plist;a:string);
var p:plist;
begin
  new(p);
  p^.zn:=a;
  p^.prev:=nil;
  if (last1=nil) then
     last1:=p
  else
  begin
    p^.prev:=last1;
    last1:=p;
  end;
end;
 
function Pop(var last:pList;var a:string):boolean;
var
 p:pList;
begin
  if (last=nil) then
  begin
    writeln(' ');
    pop:=false;
  end
  else
  begin
    p:=last;
    last:=last^.prev;
    a:=p^.zn;
    dispose(p);
    pop:=true;
  end;
end;
 
function Pop1(var last1:pList;var a:string):boolean;
var
 p:pList;
begin
  if (last1=nil) then
  begin
    writeln(' ');
    pop1:=false;
  end
  else
  begin
    p:=last1;
    last1:=last1^.prev;
    a:=p^.zn;
    dispose(p);
    pop1:=true;
  end;
end;
 
var  last,last1:plist;
     w,w1,s: string;
 
begin
 clrscr;
 last:=nil;
 last1:=nil;
 s:='уеыаоэяиюУЕЫАОЭЯИЮ';
 push(last, s);
 s:='йцкнгшщзхфвпрлджчсмтбЙЦКНГШЩЗХФВПРЛДЖЧСМТБ';
  push1(last1, s);
 writeln('Введите символы, признак конца ввода - символ "."');
 while s<>'.' do
  begin
   read(s);
   push(last, s);
   push1(last1, s);
  end;
  clrscr;
 writeln('Элементы первой очереди:');
 while (pop(last,s)=true) do
  writeln(s);
 writeln;
 writeln('Элементы второй очереди:');
 while (pop1(last1,s)=true) do
  writeln(s);
end.

program Project1;
 
type
  //Указатель на элемент очереди.
  TPElem = ^TElem;
  //Элемент очереди.
  TElem = record
    Data : Char;
    PNext : TPElem;
  end;
  //Очередь.
  TQueue = record
    PFirst, PLast : TPElem;
  end;
 
//Добавление элемента в конец очереди.
procedure QueuePush(var aQueue : TQueue; var aPElem : TPElem);
begin
  if aPElem = nil then Exit;
 
  aPElem^.PNext := nil;
  if aQueue.PFirst = nil then
    aQueue.PFirst := aPElem
  else
    aQueue.PLast^.PNext := aPElem
  ;
  aQueue.PLast := aPElem;
end;
 
//Изъятие элемента из начала очереди.
function QueuePop(var aQueue : TQueue; var aPElem : TPElem) : Boolean;
begin
  QueuePop := False;
  if aQueue.PFirst = nil then Exit;
 
  aPElem := aQueue.PFirst;
  aQueue.PFirst := aPElem^.PNext;
  if aQueue.PFirst = nil then aQueue.PLast := nil;
  QueuePop := True;
end;
 
//Удаление очереди из памяти (очистка очереди).
procedure QueueFree(var aQueue : TQueue);
var
  PDel : TPElem;
begin
  while QueuePop(aQueue, PDel) do Dispose(PDel);
end;
 
//Распечатка очереди.
procedure QueuePrint(var aQueue : TQueue);
var
  Q : TQueue;
  PElem : TPElem;
  i : Integer;
begin
  if aQueue.PFirst = nil then begin
    Writeln('Очередь пуста.');
    Exit;
  end;
  //Начальная инициализация вспомогательной очереди.
  Q.PFirst := nil;
  Q.PLast := nil;
  //Переливаем элементы из исходной очереди во вспомогательную и при этом
  //выполняем распечатку.
  i := 0;
  while QueuePop(aQueue, PElem) do begin
    //Добавление элемента во вспомогательную очередь.
    QueuePush(Q, PElem);
    //Распечатка.
    Inc(i);
    if i > 1 then Write(', ');
    Write(PElem^.Data);
  end;
  Writeln;
  //Возвращаем элементы в исходную очередь.
  //При этом, вспомогательная очередь очищается.
  while QueuePop(Q, PElem) do QueuePush(aQueue, PElem);
end;
 
const
  //Множество гласных букв.
  Da = [
    'А', 'Е', 'Ё', 'И', 'О', 'У', 'Ы', 'Э', 'Ю', 'Я',
    'а', 'е', 'ё', 'и', 'о', 'у', 'ы', 'э', 'ю', 'я'
  ];
  //Множество согласных букв.
  Db = [
    'Б', 'В', 'Г', 'Д', 'Ж', 'З', 'Й', 'К', 'Л', 'М',
    'Н', 'П', 'Р', 'С', 'Т', 'Ф', 'Х', 'Ц', 'Ч', 'Ш', 'Щ',
    'б', 'в', 'г', 'д', 'ж', 'з', 'й', 'к', 'л', 'м',
    'н', 'п', 'р', 'с', 'т', 'ф', 'х', 'ц', 'ч', 'ш', 'щ'
  ];
var
  Qa, Qb : TQueue;
  PElem : TPElem;
  i : Integer;
  S : String;
begin
  //Начальная инициализация очередей.
  Qa.PFirst := nil;
  Qa.PLast := nil;
  Qb.PFirst := nil;
  Qb.PLast := nil;
 
  repeat
    Writeln('Задайте строку:');
    Readln(S);
    //Добавляем гласные и согласные буквы в разные очереди.
    Randomize;
    for i := 1 to Length(S) do begin
      if S[i] in Da then begin
        New(PElem);
        PElem^.Data := S[i];
        QueuePush(Qa, PElem);
      end else if S[i] in Db then begin
        New(PElem);
        PElem^.Data := S[i];
        QueuePush(Qb, PElem);
      end;
    end;
 
    //Распечатки.
    Writeln('Составлены очереди:');
    Writeln('Очередь гласных букв:');
    QueuePrint(Qa);
    Writeln('Очередь согласных букв:');
    QueuePrint(Qb);
 
    //Удаляем очереди из памяти.
    QueueFree(Qa);
    QueueFree(Qb);
    Writeln('Работа завершена. Очереди удалены из памяти.');
 
    Writeln('Повторить - Enter. Выход - любой символ + Enter.');
    Readln(S);
  until S <> '';
end.