Используя стек создать другой файл в котором строки были бы записаны в обратном порядке

type stack=^internal_stack_record;
    internal_stack_record=record
      el:string;{вообще говоря, что угодно, вплоть до других стеков, принцип не меняется}
      next:stack;
    end;
    Procedure Push(var x:stack;element:string); {Положить element в стек x}
    var t:stack;
    begin
      new(t); {Создаем новый элемент списка}
      t^.el:=element; {Заполняем значение тем, которое нам подарили в параметре}
      t^.next:=x;  {Связываем новый элемент с остальным списком, даже если он пуст}
      x:=t;  {Сдвигаем голову, теперь она указывает на только что созданный элемент}
    end; {Все...}
    Procedure Pop(var x:stack;var element:string); {Обратная операция}
    var t:stack;
    begin
      t:=x; {Сохраняем голову, она еще понадобится}
      if t=nil then begin
        writeln('Error in stack operation, stack is empty in POP!');
        exit {Аварийный выход из процедуры}
      end; {Та самая проверка на ошибки. Может быть имеет смысл положить что-либо в результат...
            Сейчас он не определен, точнее не изменен.}
      element:=t^.el; {Возвращаем значение}
      x:=t^.next; {Выкидываем голову из остального списка, мы ее обработали}
      dispose(t); {Чистим за собой память, пока этого не сделали, Паскаль будет считать место занятым, хотя оно уже ни к чему не привязано}
    end;
    
    var f_in,f_out:text ;
        str:string;
        my_stack:stack;
    begin
    Assign(f_in,'in.txt');
    Reset(f_in);
    Assign(f_out, 'out.txt');
    Rewrite(f_out);
      
      while not eof(f_in) do {пока не конец файла}
      begin
       readln(f_in,str);
       push(my_stack,str);
      end;
      
      while (my_stack<>nil) do
      begin
       pop(my_stack,str);
       writeln(f_out,str);
      end;
      
      close(f_in);
      close(f_out);
    end.