Лупа в unity3d

Shader "Hidden/Lens"
{
    Properties
    {
        _MainTex ("Texture", 2D) = "white" {}
        _LensX("LensX", float) = 0.5
        _LensY("LensY", float) = 0.5
        _Radius("Radius", float) = 0.2
        _Aspect("Aspect", float) = 1.5
        _Power("Power", float) = 0.5
    }
    SubShader
    {
        // No culling or depth
        Cull Off ZWrite Off ZTest Always
 
        Pass
        {
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            
            #include "UnityCG.cginc"
 
            struct appdata
            {
                float4 vertex : POSITION;
                float2 uv : TEXCOORD0;
            };
 
            struct v2f
            {
                float2 uv : TEXCOORD0;
                float4 vertex : SV_POSITION;
            };
 
            v2f vert (appdata v)
            {
                v2f o;
                o.vertex = UnityObjectToClipPos(v.vertex);
                o.uv = v.uv;
                return o;
            }
            
            sampler2D _MainTex;
            float _Power;
            float _Radius;
            float _Aspect;
            float _LensX;
            float _LensY;
 
            fixed4 frag (v2f i) : SV_Target
            {
                float2 center = float2(_LensX, _LensY);
                fixed4 color;
 
                float2 d = center - i.uv;
                d.y /= _Aspect;
                if (length(d) < _Radius)
                {
                    color = tex2D(_MainTex, i.uv + (center - i.uv) * _Power);
                }else
                {
                    color = tex2D(_MainTex, i.uv);
                }
                
                return color;
            }
            ENDCG
        }
    }
}