Получить доступ к Listview сторонней программы через SendMessage

Private Declare Function SendMessage Lib "user32" Alias "SendMessageA" (ByVal hwnd As Long, ByVal wMsg As Long, ByVal wParam As Long, ByVal lParam As String) As Long
    Private Declare Function FindWindow Lib "user32" Alias "FindWindowA" (ByVal lpClassName As String, ByVal lpWindowName As String) As Long
    Private Declare Function FindWindowEx& Lib "user32" Alias "FindWindowExA" (ByVal hWndParent As Long, ByVal hWndChildAfter As Long, ByVal lpClassName As String, ByVal lpWindowName As String)
 
Fhwnd = FindWindow(vbNullString, "SHARP AR-5516N")
Fhwnd2 = FindWindowEx(Fhwnd, 0, "SysListView32", vbNullString)

SendKeys.Send("{Tab}")
SendKeys.Send("{DOWN}")
SendKeys.Send("{ENTER}")

Imports System.Runtime.InteropServices
 
Public Declare Function SendMessage Lib "user32.DLL" Alias "SendMessageA" ( _
    ByVal hwnd As Integer, _
    ByVal wMsg As Integer, _
    ByVal wParam As Integer, _
    <MarshalAs(UnmanagedType.AsAny)> ByVal lParam As Object) As Integer
 
Public Declare Function FindWindow Lib "user32.DLL" Alias "FindWindowA" ( _
    ByVal lpClassName As String, _
    ByVal lpWindowName As String) As Integer
 
Public Declare Function FindWindowEx Lib "user32.DLL" Alias "FindWindowExA" ( _
    ByVal hWnd1 As Integer, _
    ByVal hWnd2 As Integer, _
    ByVal lpsz1 As String, _
    ByVal lpsz2 As String) As Integer

Public Const LVM_FIRST As Int32 = &H1000
Public Const LVM_SETITEMSTATE = (LVM_FIRST + 43)
Public Const LVIF_STATE = &H8
Public Const LVIS_SELECTED As Int32 = &H2
 
Private Const LVM_GETITEMCOUNT = (LVM_FIRST + 4)
 
Private Const LVM_GETITEMSTATE = (LVM_FIRST + 44)
 
Public Structure LV_ITEM
Dim Mask As Int32
Dim iItem As Int32
Dim iSubItem As Int32
Dim State As Int32
Dim StateMask As Int32
Dim pszText As Int32
Dim cchTextMax As Int32
Dim iImage As Int32
Dim lParam As Int32
Dim iIndent As Int32
End Structure
 
Private Declare Function SendMessage Lib "user32.dll" _
Alias "SendMessageW" ( _
ByVal hwnd As IntPtr, _
ByVal wMsg As Int32, _
ByVal wParam As Int32, _
ByRef lParam As LV_ITEM _
) As Int32
 
Private Sub Button7_Click(ByVal sender As System.Object, ByVal e As
System.EventArgs) Handles Button7.Click
Dim h As IntPtr = IntPtr.op_Explicit(&H350818)
 
Dim i As Integer = SendMessage(h, LVM_GETITEMCOUNT,
IntPtr.Zero, IntPtr.Zero) ' this works with different sendmessage
declaration
 
Dim li As LV_ITEM
With li
.Mask = LVIF_STATE
' To select item
.State = LVIS_SELECTED
' To deselect item
' .state = 0
.StateMask = LVIS_SELECTED
End With
SendMessage(h, LVM_SETITEMSTATE, 1, li)
End Sub

Imports System.Runtime.InteropServices
Imports System.Text
 
Public Class Form1
    Private Const LVM_FIRST As UInteger = &H1000
    Private Const LVM_GETITEMCOUNT As UInteger = (LVM_FIRST + 4)
    Private Const LVM_SETITEM As UInteger = (LVM_FIRST + 6)
    Private Const LVM_SETITEMSTATE As UInteger = (LVM_FIRST + 43)
    Private Const LVIS_SELECTED As UInteger = &H2
    Private Const LVIF_STATE As UInteger = &H8
 
 
    Private Const MEM_COMMIT As UInteger = &H1000
    Private Const MEM_RELEASE As UInteger = &H8000
    Private Const PAGE_READWRITE As UInteger = &H4
 
    Private Const PROCESS_VM_READ As UInteger = &H10
    Private Const PROCESS_VM_WRITE As UInteger = &H20
    Private Const PROCESS_VM_OPERATION As UInteger = &H8
 
    <DllImport("kernel32.dll", SetLastError:=True)> Private Shared Function CloseHandle(ByVal handle As IntPtr) As Boolean
    End Function
    <DllImport("kernel32.dll", SetLastError:=True)> Private Shared Function OpenProcess(ByVal dwDesiredAccess As UInteger, ByVal bInheritHandle As Boolean, ByVal dwProcessId As Integer) As IntPtr
    End Function
    <DllImport("user32.dll", SetLastError:=True)> Private Shared Function SendMessage(ByVal hWnd As IntPtr, ByVal message As UInteger, ByVal wParam As Integer, ByVal lParam As IntPtr) As Integer
    End Function
    <DllImport("kernel32.dll", SetLastError:=True)> Private Shared Function VirtualAllocEx(ByVal hProcess As IntPtr, ByVal lpAddress As IntPtr, ByVal dwSize As Integer, ByVal flAllocationType As UInteger, ByVal flProtect As UInteger) As IntPtr
    End Function
    <DllImport("kernel32.dll", SetLastError:=True)> Private Shared Function VirtualFreeEx(ByVal hProcess As IntPtr, ByVal lpAddress As IntPtr, ByVal dwSize As Integer, ByVal dwFreeType As UInteger) As <MarshalAs(UnmanagedType.Bool)> Boolean
    End Function
    <DllImport("kernel32.dll", SetLastError:=True)> Private Shared Function WriteProcessMemory(ByVal hProcess As IntPtr, ByVal lpBaseAddress As IntPtr, ByRef lpBuffer As LV_ITEM, ByVal nSize As Integer, ByRef lpNumberOfBytesWritten As Integer) As <MarshalAs(UnmanagedType.Bool)> Boolean
    End Function
    <DllImport("user32.dll", SetLastError:=True)> Private Shared Function GetWindowThreadProcessId(<InAttribute()> ByVal hWnd As IntPtr, ByRef lpdwProcessId As Integer) As Integer
    End Function
    <DllImport("user32.dll", SetLastError:=True)> Private Shared Function FindWindowExW(ByVal hwndParent As IntPtr, ByVal hwndChildAfter As IntPtr, <InAttribute(), MarshalAs(UnmanagedType.LPTStr)> ByVal lpszClass As String, <InAttribute(), MarshalAs(UnmanagedType.LPTStr)> ByVal lpszWindow As String) As IntPtr
    End Function
 
    <StructLayout(LayoutKind.Sequential, CharSet:=CharSet.Unicode)> _
    Public Structure LV_ITEM
        Public mask As UInteger
        Public iItem As Integer
        Public iSubItem As Integer
        Public state As UInteger
        Public stateMask As UInteger
        Public pszText As IntPtr
        Public cchTextMax As Integer
        Public iImage As Integer
        Public lParam As IntPtr
        Public iIndent As Integer
        Public iGroupId As Integer
        Public cColumns As Integer
        Public puColumns As IntPtr
        Public piColFmt As IntPtr
        Public iGroup As Integer
    End Structure
 
 
    Private Sub Button_SelectItem_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button_SelectItem.Click
        SelectItem(1, True) 'Sets the 2nd item in the listview to the Selected state if 2 items exist in the listview
    End Sub
 
    Private Sub Button_UnSelectItem_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button_UnSelectItem.Click
        SelectItem(1, False) 'Sets the 2nd item in the listview to the Un-Selected state if 2 items exist in the listview
    End Sub
 
    Private Sub SelectItem(ByVal iIndex As Integer, ByVal selState As Boolean)
 
        Dim hLstVw As IntPtr = GetListViewHandle() 'Get the listview`s handle
 
        If Not hLstVw.Equals(IntPtr.Zero) Then 'Check if the listview handle was found
 
            Dim itemCount As Integer = SendMessage(hLstVw, LVM_GETITEMCOUNT, 0, IntPtr.Zero)
            If itemCount < iIndex Then Exit Sub 'If the item index to be set is higher than the listview`s item count then exit the sub now
 
            Dim procId As Integer = Nothing
            GetWindowThreadProcessId(hLstVw, procId) 'Get the listview`s process Id
 
            'Open the process id and set access rights to read and write to the process`s memory
            Dim hProc As IntPtr = OpenProcess(PROCESS_VM_OPERATION Or PROCESS_VM_READ Or PROCESS_VM_WRITE, False, procId)
 
            Dim lvi As New LV_ITEM 'Create a new LV_ITEM structure set to select or unselect the item depending on the selState parameter
            lvi.mask = LVIF_STATE
            lvi.stateMask = LVIS_SELECTED
            If selState Then
                lvi.state = &HF
            Else
                lvi.state = 0
            End If
 
            'Reserve space in the processes memory and write the new LV_ITEM structure`s data to it
            Dim LvItemPtr As IntPtr = VirtualAllocEx(hProc, IntPtr.Zero, Marshal.SizeOf(lvi), MEM_COMMIT, PAGE_READWRITE)
            WriteProcessMemory(hProc, LvItemPtr, lvi, Marshal.SizeOf(lvi), 0)
 
            SendMessage(hLstVw, LVM_SETITEMSTATE, iIndex, LvItemPtr) 'Send the message to set the items state
 
            VirtualFreeEx(hProc, LvItemPtr, 0, MEM_RELEASE) 'Release the processes memory used for the LV_ITEM structure`s data
            CloseHandle(hProc)
        Else
            MessageBox.Show("ListView handle not found.")
        End If
    End Sub
 
    'This is the function i used to get the SysListView32 handle of an explorer window
    Private Function GetListViewHandle() As IntPtr
        Dim hParent As IntPtr = FindWindowExW(IntPtr.Zero, IntPtr.Zero, "CabinetWClass", Nothing)
        If Not hParent.Equals(IntPtr.Zero) Then
            Dim hChld_1 As IntPtr = FindWindowExW(hParent, IntPtr.Zero, "SHELLDLL_DefView", Nothing)
            If Not hChld_1.Equals(IntPtr.Zero) Then
                Dim hChld_2 As IntPtr = FindWindowExW(hChld_1, IntPtr.Zero, "DUIViewWndClassName", Nothing)
                If Not hChld_2.Equals(IntPtr.Zero) Then
                    Dim hChld_3 As IntPtr = FindWindowExW(hChld_2, IntPtr.Zero, "DirectUIHWND", Nothing)
                    If Not hChld_3.Equals(IntPtr.Zero) Then
                        Dim hChld_4 As IntPtr = FindWindowExW(hChld_3, IntPtr.Zero, "CtrlNotifySink", Nothing)
                        If Not hChld_4.Equals(IntPtr.Zero) Then
                            Dim hChld_5 As IntPtr = FindWindowExW(hChld_4, IntPtr.Zero, "SysListView32", "FolderView")
                            If Not hChld_5.Equals(IntPtr.Zero) Then
                                Return hChld_5 'Return the handle to the SysListView32
                            End If
                        End If
                    End If
                End If
            End If
        End If
        Return IntPtr.Zero
    End Function
End Class