Экспортировать весь список из DataGridView в Excel

Private Sub ExportToExcel()
        ' Creating a Excel object.
        Dim excel As Microsoft.Office.Interop.Excel._Application = New Microsoft.Office.Interop.Excel.Application()
        Dim workbook As Microsoft.Office.Interop.Excel._Workbook = excel.Workbooks.Add(Type.Missing)
        Dim worksheet As Microsoft.Office.Interop.Excel._Worksheet = Nothing
 
        Try
 
            worksheet = workbook.ActiveSheet
 
            worksheet.Name = "ExportedFromDatGrid"
 
            Dim cellRowIndex As Integer = 1
            Dim cellColumnIndex As Integer = 1
 
            'Loop through each row and read value from each column.
            For i As Integer = 0 To dgvCityDetails.Rows.Count - 2
                For j As Integer = 0 To dgvCityDetails.Columns.Count - 1
                    ' Excel index starts from 1,1. As first Row would have the Column headers, adding a condition check.
                    If cellRowIndex = 1 Then
                        worksheet.Cells(cellRowIndex, cellColumnIndex) = dgvCityDetails.Columns(j).HeaderText
                    Else
                        worksheet.Cells(cellRowIndex, cellColumnIndex) = dgvCityDetails.Rows(i).Cells(j).Value.ToString()
                    End If
                    cellColumnIndex += 1
                Next
                cellColumnIndex = 1
                cellRowIndex += 1
            Next
 
            'Getting the location and file name of the excel to save from user.
            Dim saveDialog As New SaveFileDialog()
            saveDialog.Filter = "Excel files (*.xlsx)|*.xlsx|All files (*.*)|*.*"
            saveDialog.FilterIndex = 2
 
            If saveDialog.ShowDialog() = System.Windows.Forms.DialogResult.OK Then
                workbook.SaveAs(saveDialog.FileName)
                MessageBox.Show("Export Successful")
            End If
        Catch ex As System.Exception
            MessageBox.Show(ex.Message)
        Finally
            excel.Quit()
            workbook = Nothing
            excel = Nothing
        End Try
 
    End Sub

Imports EX = Microsoft.Office.Interop.Excel
Public Class Form1
'…
Private Sub Button2_Click(sender As System.Object, e As System.EventArgs) Handles Button2.Click
    Dim xlApp As New EX.Application()
    xlApp.SheetsInNewWorkbook = 1
    xlApp.DisplayAlerts = False
    xlApp.Visible = True
    Dim xlBook As EX.Workbook = xlApp.Workbooks.Add()
    Dim xlSheet As EX.Worksheet = xlBook.ActiveSheet
    DataGridView1.SelectAll()
    DataGridView1.ClipboardCopyMode = DataGridViewClipboardCopyMode.EnableAlwaysIncludeHeaderText
    Clipboard.SetDataObject(DataGridView1.GetClipboardContent(), False)
    xlSheet.Range("A1").PasteSpecial(EX.XlPasteType.xlPasteAll, EX.XlPasteSpecialOperation.xlPasteSpecialOperationAdd)
    Dim rn As EX.Range = xlSheet.UsedRange
    Dim n As Integer = rn.Columns.Count
    rn.Rows(1).Font.Bold = True
    rn.Rows(1).Interior.ColorIndex = 8
    xlSheet.Range("A1").Select()
End Sub
'…
End Class

Imports Microsoft.Office.Interior.Excel
Sub dg_to_excel(ByVal dgv As DataGridView)
        Dim excel_app As New Application
        Try
            Dim my_workbook As Workbook = excel_app.Workbooks.Add
            Dim my_worksheet As Worksheet = excel_app.Worksheets.Add
            With my_worksheet
                Dim c As Integer = 1
                For i = 1 To dgv.Columns.Count
                    If dgv.Columns(i - 1).Visible = True Then
                        .Cells(1, c).Value = dgv.Columns(i - 1).Name
                        .Cells(1, c).Interior.Color = Color.LightGray
                        If dgv.Rows.Count > 0 Then
                            For e = 1 To dgv.Rows.Count
                                .Cells(1 + e, c).Value = dgv.Rows(e - 1).Cells(i - 1).Value
                            Next
                        End If
                        .Columns(c).AutoFit
                        c = c + 1
                    End If
                Next
            End With
            excel_app.Visible = True'в данном примере эксель не сохраняет в файл, а просто открывается. 
        Catch ex As Exception
            MsgBox("Не удалось выгрузить данные!", vbCritical)
            excel_app.Quit()
        End Try
    End Sub

    
Imports Microsoft.Office.Interior.Excel
Sub save_to_excel(dgv As DataGridView)
        Dim excel_app As New Application
        Try
            Dim dialog As New SaveFileDialog
            Dim file_path As String
            dialog.Filter = "файлы excel 97-2003 (*.xls)|*.xls"
            If dialog.ShowDialog = DialogResult.OK Then
                file_path = dialog.FileName
            Else
                Exit Sub
            End If
            Dim my_workbook As Workbook = excel_app.Workbooks.Add
            Dim my_worksheet As Worksheet = excel_app.Worksheets.Add
            With my_worksheet
                Dim c As Integer = 1
                For i = 1 To dgv.Columns.Count
                    If dgv.Columns(i - 1).Visible = True Then
                        .Cells(1, c).Value = dgv.Columns(i - 1).Name
                        .Cells(1, c).Interior.Color = Color.LightGray
                        If dgv.Rows.Count > 0 Then
                            For e = 1 To dgv.Rows.Count
                                .Cells(1 + e, c).Value = dgv.Rows(e - 1).Cells(i - 1).Value
                            Next
                        End If
                        .Columns(c).AutoFit
                        c = c + 1
                    End If
                Next
            End With
            my_workbook.SaveAs(file_path)
            excel_app.Visible = True
        Catch ex As Exception
            MsgBox("Не удалось выгрузить данные!", vbCritical)
            excel_app.Quit()
        End Try
    End Sub

Imports System.Drawing.Imaging
 
Public Class Form1
    Private Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load
        DataGridView1.AutoSizeColumnsMode = DataGridViewAutoSizeColumnsMode.AllCells
    End Sub
    Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click
        Dim sw = New Stopwatch() ' объявл.перем. секундомера отработки программы
        sw.Start() ' запускаем секундомер
        Dim bm As New Bitmap("30.11.3.png")
        Dim tb As DataTable = getColorCode(bm, 10)
        If tb IsNot Nothing Then DataGridView1.DataSource = tb
        sw.Stop() ' остановили секундомер
 
        Label1.Text = " ms " & sw.ElapsedMilliseconds.ToString ' вывели милисекунды на форму
    End Sub
    Private Function getColorCode(ByVal bmp As Bitmap, tpCodeColor As Byte) As DataTable
 
        Dim sz As Size = bmp.Size
        Dim cl As Color
        Dim tb As New DataTable()
        For i = 0 To sz.Width - 1
            tb.Columns.Add("C" & (i + 1).ToString, System.Type.GetType("System.String"))
        Next
        If bmp.PixelFormat <> PixelFormat.Format32bppArgb Then FastPix.ConvertFormat(bmp)
        Try
            Dim SW As New Stopwatch
            SW.Start()
            Using fp As New FastPix(bmp)
                For y = 0 To sz.Height - 1
                    Dim lst(sz.Width - 1) As String
                    For x = 0 To sz.Width - 1
                        cl = fp.GetPixel(x, y)
                        'Select Case tpCodeColor
                        '        Case 1 'целое
                        '            lst(x) = cl.ToArgb.ToString
                        '    Case 2 'шестнадцатеричное
                        '        lst(x) = cl.Name
                        '         Case Else 'строка R,G,B
                        lst(x) = cl.R.ToString & "," & cl.G.ToString & "," & cl.B.ToString
                        ' End Select
                    Next
                    tb.Rows.Add(lst)
                Next
                SW.Stop()
                Me.Text = SW.ElapsedMilliseconds
            End Using
            Return tb
        Catch ex As Exception
            MsgBox(ex.Message)
            Return Nothing
        End Try
 
    End Function

Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click
    Dim tb As DataTable = createTable(20) 'моделирование таблицы
    DataGridView1.DataSource = tb
    tableToExcel(tb, 3, 2, IO.Path.Combine(Application.StartupPath, "test.xlsx"))
End Sub
 
Private Sub tableToExcel(ByVal dt As DataTable, ByVal iStartRowIndex As Integer, ByVal iStartColumnIndex As Integer, ByVal fName As String)
    Dim sl As SLDocument = New SLDocument()
    ' + 1, поскольку строка заголовка включена
    ' - 1 потому что это подсчет, потому что начальная строка подсчитывается.
    Dim iEndRowIndex As Integer = iStartRowIndex + dt.Rows.Count + 1 - 1
    '- 1 потому что это подсчет, потому что начальный столбец подсчитывается.
    Dim iEndColumnIndex As Integer = iStartColumnIndex + dt.Columns.Count - 1
    sl.ImportDataTable(iStartRowIndex, iStartColumnIndex, dt, True)
    Dim table As SLTable = sl.CreateTable(iStartRowIndex, iStartColumnIndex, iEndRowIndex, iEndColumnIndex)
    table.SetTableStyle(SLTableStyleTypeValues.Medium17)
    sl.InsertTable(table)
    sl.SaveAs(fName)
End Sub

 Case Else 'строка R,G,B
                                lst(x) = cl.R.ToString & "," & cl.G.ToString & "," & cl.B.ToString

 Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click
        Dim sw = New Stopwatch() ' объявл.перем. секундомера отработки программы
        sw.Start() ' запускаем секундомер
        Dim bm As New Bitmap("30.11.3.png")
        Dim tb As DataTable = getColorCode(bm, 10)
        If tb IsNot Nothing Then DataGridView1.DataSource = tb
        sw.Stop() ' остановили секундомер
        ' DataGridView1.DataSource = tb
        tableToExcel(tb, 3, 2, IO.Path.Combine(Application.StartupPath, "test.xlsx"))
        Label1.Text = " ms " & sw.ElapsedMilliseconds.ToString ' вывели милисекунды на форму
    End Sub