Максимум функции методом золотого сечения, нужно построить график с точками

@IrinaHaes · Регистрация: 28.03.2018

Студворк — интернет-сервис помощи студентам

VB.NET
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
Public Class Form1
 
    Private Sub Button1_Click(sender As System.Object, e As System.EventArgs) Handles Button1.Click
        Dim eps As Double
        Dim a As Double
        Dim b As Double
        Dim x As Double
        Dim y As Double
 
        Dim x1 As Double
        Dim x2 As Double
        Dim y1 As Double
        Dim y2 As Double
        a = Val(TextBox1.Text)
        b = Val(TextBox2.Text)
        eps = Val(TextBox3.Text)
        x1 = a * 0.618 + 0.382 * b
        x2 = 0.382 * a + 0.618 * b
        y1 = (10 * x1) / (1 + x1 ^ 2)
        y2 = (10 * x2) / (1 + x2 ^ 2)
        While Math.Abs(b - a) < eps
            If y1 < y2 Then
                b = x2
                x2 = x1
                y2 = y1
                x1 = 0.618 * a + 0.382 * b
                y1 = (10 * x1) / (1 + x1 ^ 2)
            Else
                a = x1
                x1 = x2
                y1 = y2
                x2 = 0.382 * a + 0.618 * b
                y2 = (10 * x2) / (1 + x2 ^ 2)
            End If
        End While
        x = (a + b) / 2
        y = (10 * x) / (1 + x ^ 2)
        RichTextBox1.Text += Format(x, "0.000") + " " + Format(y, "0.000") + vbCrLf
        Chart1.Series(0).Points.AddXY(x, y)
    End Sub
 
 
End Class

@ovva · 29.03.2018, 14:14

Уважаемая IrinaHaes, я не понял о какой собственно функции идет речь. Напишите ее в явном виде. Максимум ищется на интервале [a,b] с точностью eps и результатом будет точка максимума с координатами {x,y}. И здесь тоже не очень понятно, что вы хотите отобразить в Chart1. У вас получается что точку, хотя интерес, наверное, представляет поведение функции на интервале [a,b].

@ovva · 29.03.2018, 19:57

Можно так

Кликните здесь для просмотра всего текста

VB.NET
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
Imports System.Windows.Forms.DataVisualization.Charting
'…
    Private Sub Button1_Click(sender As System.Object, e As System.EventArgs) Handles Button1.Click
        Dim a As Double = 0
        Dim b As Double = 4
        Dim eps As Double = 0.00001
        Dim ff = Function(x) 10 * x / (1 + x ^ 2)
        Dim xx As Double = miniGold(a, b, eps, ff)
        Dim yy As Double = ff(xx)
        Label2.Text = "X=" & xx.ToString
        Label3.Text = "Y=" & yy.ToString
        drawGraph(a, b, 50, ff)
    End Sub
    Private Function miniGold(ByVal A As Double, ByVal B As Double, ByVal eps As Double, ByVal ff As Func(Of Double, Double)) As Double
        Dim gs As Double = 0.6180339
        Dim xr As Double = A + (B - A) * gs
        Dim xl As Double = B - (B - A) * gs
        Dim yr As Double = ff(xr)
        Dim yl As Double = ff(xl)
        Do While (B - A) > eps
            'If yr < yl Then 'for min
            If yr > yl Then
                A = xl
                xl = xr
                yl = yr
                xr = A + (B - A) * gs
                yr = ff(xr)
            Else
                B = xr
                xr = xl
                yr = yl
                xl = B - (B - A) * gs
                yl = ff(xl)
            End If
        Loop
        Return 0.5 * (A + B)
    End Function
    Private Sub drawGraph(ByVal A As Double, ByVal B As Double, ByVal n As Integer, ByVal ff As Func(Of Double, Double))
        Dim stp As Double = Math.Abs(B - A) / n
        Dim x, y As Double
        With Chart1
            .Series.Clear()
            .Series.Add("curve")
            .ChartAreas(0).AxisX.Minimum = A
            .ChartAreas(0).AxisX.Maximum = B
            .ChartAreas(0).AxisX.Interval = 0.5
            With .Series("curve")
                x = A
                For i = 1 To n - 1
                    y = ff(x)
                    .Points.AddXY(x, y)
                    x += stp
                Next
                x = B
                y = ff(x)
                .Points.AddXY(x, y)
                .BorderWidth = 2
                .ChartType = SeriesChartType.Spline
                .Color = Color.Red
                .IsVisibleInLegend = False
            End With
            .Show()
        End With
    End Sub

Новые блоги и статьи Все статьи Все блоги /
Символьное дифференцирование igorrr37 13.02.2026 / * Логарифм записывается как: (x-2)log(x^2+2) - означает логарифм (x^2+2) по основанию (x-2). Унарный минус обозначается как ! */ #include <iostream> #include <stack> #include <cctype>. . .	Камера Toupcam IUA500KMA Eddy_Em 12.02.2026 Т. к. у всяких "хикроботов" слишком уж мелкий пиксель, для подсмотра в ESPriF они вообще плохо годятся: уже 14 величину можно рассмотреть еле-еле лишь на экспозициях под 3 секунды (а то и больше),. . .	И ясному Солнцу zbw 12.02.2026 И ясному Солнцу, и светлой Луне. В мире покоя нет и люди не могут жить в тишине. А жить им немного лет.	«Знание-Сила» zbw 12.02.2026 «Знание-Сила» «Время-Деньги» «Деньги -Пуля»
SDL3 для Web (WebAssembly): Подключение Box2D v3, физика и отрисовка коллайдеров 8Observer8 12.02.2026 Содержание блога Box2D - это библиотека для 2D физики для анимаций и игр. С её помощью можно определять были ли коллизии между конкретными объектами и вызывать обработчики событий столкновения. . . .	SDL3 для Web (WebAssembly): Загрузка PNG с прозрачным фоном с помощью SDL_LoadPNG (без SDL3_image) 8Observer8 11.02.2026 Содержание блога Библиотека SDL3 содержит встроенные инструменты для базовой работы с изображениями - без использования библиотеки SDL3_image. Пошагово создадим проект для загрузки изображения. . .	SDL3 для Web (WebAssembly): Загрузка PNG с прозрачным фоном с помощью SDL3_image 8Observer8 10.02.2026 Содержание блога Библиотека SDL3_image содержит инструменты для расширенной работы с изображениями. Пошагово создадим проект для загрузки изображения формата PNG с альфа-каналом (с прозрачным. . .	Установка Qt-версии Lazarus IDE в Debian Trixie Xfce volvo 10.02.2026 В общем, достали меня глюки IDE Лазаруса, собранной с использованием набора виджетов Gtk2 (конкретно: если набирать текст в редакторе и вызвать подсказку через Ctrl+Space, то после закрытия окошка. . .

@ovva 4708 / 3661 / 857 Регистрация: 02.02.2013 Сообщений: 3,518 Записей в блоге: 2
	29.03.2018, 14:14
	Уважаемая IrinaHaes, я не понял о какой собственно функции идет речь. Напишите ее в явном виде. Максимум ищется на интервале [a,b] с точностью eps и результатом будет точка максимума с координатами {x,y}. И здесь тоже не очень понятно, что вы хотите отобразить в Chart1. У вас получается что точку, хотя интерес, наверное, представляет поведение функции на интервале [a,b]. 0

Максимум функции методом золотого сечения, нужно построить график с точками

Решение