Таблица со сложным заголовком

Public Class Form3
    Private daysInMonths() As Integer
    Private Sub Form3_Load(sender As Object, e As EventArgs) Handles MyBase.Load
        Dim year As Integer = Date.Now.Year
        daysInMonths = New Integer(11) {}
 
        For month As Integer = 1 To 12
            daysInMonths(month - 1) = Date.DaysInMonth(year, month)
 
            Dim day As Integer = 1
            Do While day <= daysInMonths(month - 1)
                Dim [date] As New Date(year, month, day)
                Dim col As New DataGridViewTextBoxColumn() With {
                .Name = [date].ToString(),
                .HeaderText = day.ToString(),
                .Width = 20
            }
 
                Me.DataGridView1.Columns.Add(col)
                day += 1
            Loop
        Next month
 
        For r As Integer = 0 To 3
            Dim row As New DataGridViewRow()
            row.CreateCells(Me.DataGridView1)
            row.HeaderCell.Value = $"Project {r + 1}"
            Me.DataGridView1.Rows.Add(row)
        Next r
 
        Me.DataGridView1.AllowUserToAddRows = False
        Me.DataGridView1.RowHeadersWidthSizeMode = DataGridViewRowHeadersWidthSizeMode.AutoSizeToAllHeaders
        Me.DataGridView1.ColumnHeadersHeightSizeMode = DataGridViewColumnHeadersHeightSizeMode.EnableResizing
        Me.DataGridView1.ColumnHeadersHeight = Me.DataGridView1.ColumnHeadersHeight * 2
        Me.DataGridView1.ColumnHeadersDefaultCellStyle.Alignment = DataGridViewContentAlignment.BottomCenter
 
        AddHandler Me.DataGridView1.Paint, AddressOf DataGridView1_Paint
        AddHandler Me.DataGridView1.Scroll, AddressOf DataGridView1_Scroll
        AddHandler Me.DataGridView1.ColumnWidthChanged, AddressOf DataGridView1_ColumnWidthChanged
        AddHandler Me.DataGridView1.Resize, AddressOf DataGridView1_Resize
 
    End Sub
    Private Sub InvalidateHeader()
        Dim rtHeader As Rectangle = Me.DataGridView1.DisplayRectangle
        rtHeader.Height = Me.DataGridView1.ColumnHeadersHeight / 2
        Me.DataGridView1.Invalidate(rtHeader)
    End Sub
 
    Private Sub DataGridView1_Resize(ByVal sender As Object, ByVal e As EventArgs)
        Me.InvalidateHeader()
    End Sub
 
    Private Sub DataGridView1_ColumnWidthChanged(ByVal sender As Object, ByVal e As DataGridViewColumnEventArgs)
        Me.InvalidateHeader()
    End Sub
 
    Private Sub DataGridView1_Scroll(ByVal sender As Object, ByVal e As ScrollEventArgs)
        Me.InvalidateHeader()
    End Sub
 
    Private Sub DataGridView1_Paint(ByVal sender As Object, ByVal e As PaintEventArgs)
        Dim col As Integer = 0
 
        ' For each month, create the display rectangle for the main title and draw it.
        For Each daysInMonth As Integer In daysInMonths
            Dim r1 As Rectangle = Me.DataGridView1.GetCellDisplayRectangle(col, -1, True)
 
            ' Start the rectangle from the first visible day of the month,
            ' and add the width of the column for each following day.
            For day As Integer = 0 To daysInMonth - 1
                Dim r2 As Rectangle = Me.DataGridView1.GetCellDisplayRectangle(col + day, -1, True)
 
                If r1.Width = 0 Then ' Cell is not displayed.
                    r1 = r2
                Else
                    r1.Width += r2.Width
                End If
            Next day
 
            r1.X += 1
            r1.Y += 1
            r1.Height = r1.Height \ 2 - 2
            r1.Width -= 2
 
            Using back As Brush = New SolidBrush(Me.DataGridView1.ColumnHeadersDefaultCellStyle.BackColor)
                Using fore As Brush = New SolidBrush(Me.DataGridView1.ColumnHeadersDefaultCellStyle.ForeColor)
                    Using p As New Pen(Me.DataGridView1.GridColor)
                        Using format As New StringFormat()
                            Dim month As String = Date.Parse(Me.DataGridView1.Columns(col).Name).ToString("MMMM")
 
                            format.Alignment = StringAlignment.Center
                            format.LineAlignment = StringAlignment.Center
 
                            e.Graphics.FillRectangle(back, r1)
                            e.Graphics.DrawRectangle(p, r1)
                            e.Graphics.DrawString(month, Me.DataGridView1.ColumnHeadersDefaultCellStyle.Font, fore, r1, format)
                        End Using
                    End Using
                End Using
            End Using
 
            col += daysInMonth ' Move to the first column of the next month.
        Next daysInMonth
    End Sub
 
End Class