Анимация разворачивания окна в режиме без рамки

Public Class aniWindow
    <Runtime.InteropServices.DllImport("user32.dll")>
    Shared Function AnimateWindow(hWnd As IntPtr, time As Integer, flags As AnimateWindowFlags) As Boolean
    End Function
    Public Enum AnimateWindowFlags
        AW_SLIDE = &H40000  'Эффект слайда. Данный параметр игнорируется при использовании AW_CENTER
        AW_ACTIVATE = &H20000   'Активизирует окно. Не используйте с AW_HIDE
        AW_BLEND = &H80000  'Эффект проявления. Может использоваться, только, если окно поверх остальных
        AW_HIDE = &H10000   'Скрытие окна. По умолчанию окно видимо
        AW_CENTER = &H10    'Сжимание окна по центру
        AW_HOR_POSITIVE = &H1   'Анимация окна слева направо. Флаг игнорируется при использовании AW_CENTER или AW_BLEND
        AW_HOR_NEGATIVE = &H2   'Анимация окна справа налево. Флаг игнорируется при использовании AW_CENTER или AW_BLEND
        AW_VER_POSITIVE = &H4   'Анимация окна сверху вниз. Флаг игнорируется при использовании AW_CENTER или AW_BLEND
        AW_VER_NEGATIVE = &H8   'Анимация окна снизу вверх. Флаг игнорируется при использовании AW_CENTER или AW_BLEND
    End Enum
    Private isLoad As Boolean = False
    Private isMini As Boolean = False
    Protected Overrides ReadOnly Property CreateParams As CreateParams
        Get
            Dim cp As CreateParams = MyBase.CreateParams
            cp.Style = cp.Style And Not &HC00000
            Return cp
        End Get
    End Property
 
    Private Sub aniWindow_Load(sender As System.Object, e As System.EventArgs) Handles MyBase.Load
        AnimateWindow(Me.Handle, 400, AnimateWindowFlags.AW_HOR_POSITIVE)
        isLoad = True
    End Sub
 
    Private Sub Close_Click(sender As System.Object, e As System.EventArgs) Handles Button1.Click
        AnimateWindow(Me.Handle, 400, AnimateWindowFlags.AW_CENTER Or AnimateWindowFlags.AW_HIDE)
        Me.Close()
    End Sub
 
    Private Sub Minimized_Click(sender As System.Object, e As System.EventArgs) Handles Button2.Click
        AnimateWindow(Me.Handle, 400, AnimateWindowFlags.AW_CENTER Or AnimateWindowFlags.AW_HIDE)
        Me.WindowState = FormWindowState.Minimized
        isMini = True
    End Sub
 
    Private Sub aniForm_Resize(sender As System.Object, e As System.EventArgs) Handles MyBase.Resize
        If Not isLoad Then Exit Sub
        If isMini AndAlso Me.WindowState = FormWindowState.Normal Then
            Me.Hide()
            AnimateWindow(Me.Handle, 400, AnimateWindowFlags.AW_ACTIVATE Or AnimateWindowFlags.AW_HOR_POSITIVE)
        End If
        Me.Visible = True
        isMini = False
    End Sub
 
End Class