Возможно ли послать сообщение по сети

Public Class Form1
    Private Sub Button1_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button1.Click
        Call Shell("net send " & Text1.Text & " " & Text2.Text, 0)
    End Sub
End Class

Imports System.Net
 
Public Class Form1
    Friend Const LocalPort As Integer = 10101 'этот порт мы слушаем у себя на предмет входящих соединений. И на порт с этим же номером на удаленной машине мы отправляем сообщения.
    Dim Client_UDP_output As New System.Net.Sockets.UdpClient
    Dim Client_UDP_input As New System.Net.Sockets.UdpClient(LocalPort)
    Dim RemoteIpEndPoint As New IPEndPoint(IPAddress.Any, 0)
    Dim ListenerThread As Threading.Thread
 
    Private Sub Form1_FormClosed(ByVal sender As Object, ByVal e As System.Windows.Forms.FormClosedEventArgs) Handles Me.FormClosed
        Me.Client_UDP_input.Close()
    End Sub
 
    Private Sub start_thread()
        Try
            ListenerThread = New Threading.Thread(AddressOf DoListen)
            ListenerThread.Start()
        Catch ex As Exception
        End Try
    End Sub
 
    Private Sub DoListen()
        Do While Not ListenerThread Is Nothing
            Try
                Dim receiveBytes As Byte() = Client_UDP_input.Receive(RemoteIpEndPoint)
                Dim returnData As String = System.Text.Encoding.Default.GetString(receiveBytes)
                Me.ReturnData_toMainThread(returnData)
            Catch ex As Exception
                ListenerThread.Abort()
            End Try
        Loop
    End Sub
 
    Private Delegate Sub MSG_Delegate(ByVal Text As String)
 
    Private Sub ReturnData_toMainThread(ByVal Text As String)
        ' является ли вызвавший поток родным потоком окна MessageWindow?
        If Not Me.InvokeRequired Then
            ' вызвать родной, незащищенный метод формы
            Me.UDP_DataArrival(Text)
        Else
            ' косвенный вызов метода
            Dim d As System.Delegate = New MSG_Delegate(AddressOf ReturnData_toMainThread)
            ' асинхронно вызвать этот же метод, с теми же параметрами.
            Me.BeginInvoke(d, New String() {Text})
        End If
    End Sub
 
    Friend Sub SendData_to_LocalNet(ByVal strData As String, ByVal RemoteAddress As IPAddress)
        Dim sendBytes As [Byte]() = System.Text.Encoding.Default.GetBytes(strData)
        Client_UDP_output.Send(sendBytes, sendBytes.Length, New IPEndPoint(RemoteAddress, LocalPort))
    End Sub
 
    Private Sub UDP_DataArrival(ByVal DataSTR As String)
        'тут мы отображаем строковое сообщение для пользователя
        Me.TextBox3.Text = Me.TextBox3.Text & DataSTR & vbCrLf
        Me.TextBox3.SelectionLength = 0
        Me.TextBox3.SelectionStart = Me.TextBox3.TextLength
        Me.TextBox3.ScrollToCaret()
    End Sub
 
    Private Sub Form1_Load(ByVal sender As Object, ByVal e As System.EventArgs) Handles Me.Load
        Me.TextBox3.ScrollBars = ScrollBars.Vertical
        Me.TextBox3.HideSelection = False
        Me.start_thread()
    End Sub
 
    Private Sub Button1_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button1.Click
        Dim EndIP As IPAddress
        Try
            endip = IPAddress.Parse(Me.TextBox1.Text)
        Catch ex As Exception
            MsgBox(ex.Message)
            Exit Sub
        End Try
        Me.SendData_to_LocalNet("[" & Date.Now.ToShortTimeString & "] " & My.Computer.Name.ToLower & " : " & Me.TextBox2.Text, EndIP)
    End Sub
End Class