Калькулятор VB, Нужно, чтобы последовательно могли выполняться более трех действий одновременно

Public Class ReversePolishNotation
#Region " Поля и свойства "
    'Операторы арифметических действий
    Private Const OPERATORS As String = "+-*/^"
    Private _expression As String
    ''' <summary>
    ''' Исходное выражение
    ''' </summary>
    Public Property Expression() As String
        Get
            Return _expression
        End Get
        Set(ByVal value As String)
            _expression = value
        End Set
    End Property
 
    Private _rpnexpression As String
    ''' <summary>
    ''' Выражение записанное в обратной польской нотации
    ''' </summary>
    Public Property RpnExpression() As String
        Get
            Return _rpnexpression
        End Get
        Set(ByVal value As String)
            _rpnexpression = value
        End Set
    End Property
 
    Private _result As Double
    ''' <summary>
    ''' Вычисленный результат
    ''' </summary>
    Public Property Result() As Double
        Get
            Return _result
        End Get
        Set(ByVal value As Double)
            _result = value
        End Set
    End Property
    'Стек для хранения выражения в ОПН
    Private _rpn As Stack
#End Region
 
    Public Sub New(expression As String)
        _expression = expression
        _rpn = New Stack()
        _rpnexpression = String.Empty
        ConvertToRPN()
        CalculRPN()
    End Sub
    ''' <summary>
    ''' Процедура преобразования в ОПН
    ''' </summary>
    Private Sub ConvertToRPN()
        Dim operand As New List(Of String) 'Список для операторов и операндов
        'Перенос из строки в список. Нужно, чтобы правильно распознать дробные числа
        For Each c As Char In _expression
            'Последнее значение списка
            If operand.Count = 0 Then
                If Not Char.IsDigit(c) And Not IsOperator(c) Then
                    operand.Add("0" & Globalization.CultureInfo.CurrentCulture.NumberFormat.NumberDecimalSeparator)
                Else
                    operand.Add(c)
                End If
                Continue For
            End If
 
            Dim lastValue As String = operand.Item(operand.Count - 1)
            If IsOperator(c) Then
                operand.Add(c)
            Else
                If IsOperator(lastValue(lastValue.Length - 1)) Then
                    If Not Char.IsDigit(c) Then
                        operand.Add("0" & Globalization.CultureInfo.CurrentCulture.NumberFormat.NumberDecimalSeparator)
                    Else
                        operand.Add(c)
                    End If
 
                Else
                    'Самое важное. Ради этого весь цикл и затеивался. Определяем введённый десятичный разделитель и,
                    'если он не соответствует системному, то вместо него записывается системный
                    If Not Char.IsDigit(c) And c <> Globalization.CultureInfo.CurrentCulture.NumberFormat.NumberDecimalSeparator Then
                        operand.Item(operand.Count - 1) &= IIf(IsOperator(lastValue(lastValue.Length - 1)), "0", "") & Globalization.CultureInfo.CurrentCulture.NumberFormat.NumberDecimalSeparator
                    Else
                        operand.Item(operand.Count - 1) &= IIf(IsOperator(lastValue(lastValue.Length - 1)), "0", "") & c.ToString()
                    End If
                End If
            End If
        Next
 
        Dim stack As New Stack() 'Вспомогательный стек
 
        'Само преобразование в ОПН
        For Each c As String In operand
            'Если символ является цифрой или открывающей скобкой, то просто помещаем его в основной стек
            If Char.IsDigit(c) Then
                _rpn.Push(c)
                Continue For
            ElseIf c = "(" Then
                stack.Push(c)
                Continue For
            End If
            'Если символ является арифметическим оператором
            If OPERATORS.Contains(c) Then
                'Проверка приоритетов
                If stack.Count > 0 AndAlso Priority(c) <= Priority(stack.Peek) Then
                    'Если стек не пустой и приоритет текущего оператора меньше или равен приоритету
                    'оператора в стеке, то оператор из временного стека помещаем в основной стек,
                    'а текущий оператор помещаем во вспомогательный стек
                    _rpn.Push(stack.Pop)
                    stack.Push(c)
                Else
                    'Иначе оператор просто помещается во вспомогательный стек
                    stack.Push(c)
                End If
                Continue For
            End If
            'Если символ является закрывающей скобкой
            If c = ")" Then
                'То перемещаем всё из вспомогательного стека в основной, пока не встретится открывающая скобка
                While stack.Peek <> "("
                    _rpn.Push(stack.Pop)
                End While
                'Удаляем открывающую скобку из вспомогательного стека
                stack.Pop()
            End If
        Next
        'Перенос всех операторов из вспомогательного стека в основной
        While (stack.Count <> 0)
            'Проверка, что во вспомогательном стеке остались только операторы. Иначе -  исключение
            If (OPERATORS.IndexOf(stack.Peek) = -1) Then
                Throw New Exception(String.Format("В выражении {0} не согласованы скобки.", _expression))
            End If
            _rpn.Push(stack.Pop)
        End While
        stack = _rpn.Clone
        'Переписываем стек в строку
        While (stack.Count <> 0) : _rpnexpression = stack.Pop.ToString() & " " & _rpnexpression.Trim() : End While
    End Sub
    ''' <summary>
    ''' Вычисление выражение в ОПН
    ''' </summary>
    Private Sub CalculRPN()
        'Клон основного стека. Если всё сделано правильно, то
        'после работы процедуры в нём будет храниться результат выражения
        Dim stack As Stack = _rpn.Clone
        Dim tempstack As Stack = New Stack 'Вспомогательный стек
        'Перегоняем из основного стека во вспомогательный в обратном порядке
        While (stack.Count > 0)
            tempstack.Push(stack.Pop)
        End While
        'Чтение вспомогательного стека. Т.е. ОПН читается слева-направо
        While (tempstack.Count > 0)
            'Цифру помещаем в основной стек
            If Char.IsDigit(tempstack.Peek) Then
                stack.Push(tempstack.Pop)
                Continue While
            End If
            'Если оператор, то выполняем соответствующее действие над последними двумя цифрами из основного стека
            If (OPERATORS.Contains(tempstack.Peek)) Then
                Dim temp As String
                temp = Calcul(Double.Parse(stack.Pop.ToString), Double.Parse(stack.Pop.ToString), tempstack.Pop.ToString)
                stack.Push(temp)
            End If
        End While
        If stack.Count = 1 Then
            _result = Double.Parse(stack.Pop)
        Else
            Throw New Exception("Несогласованное выражение")
        End If
    End Sub
 
    Private Function Calcul(b As Double, a As Double, action As String) As String
        Dim result As String = String.Empty
        Select Case action
            Case "+"
                result = (a + b).ToString()
            Case "-"
                result = (a - b).ToString()
            Case "*"
                result = (a * b).ToString()
            Case "/"
                If b = 0 Then Throw New ArgumentException("Деление на ноль")
                result = (a / b).ToString()
            Case "^"
                result = Math.Pow(a, b).ToString
        End Select
        Return result
    End Function
 
    Private Function Priority(c As String) As Integer
        Dim result As Integer = 0
        Select Case c.ToString
            Case "*", "/"
                result = 2
            Case "^"
                result = 3
            Case "+", "-"
                result = 1
        End Select
        Return result
    End Function
 
    Private Function IsOperator(c As Char) As Boolean
        Return "+-*/^()".Contains(c)
    End Function
End Class

    Sub Main()
        Do
            Console.Write("Введите выражение: ")
            Dim expr As String = Console.ReadLine()
            If (expr = String.Empty) Then Exit Do
            Dim rpn As New ReversePolishNotation(expr)
            Console.WriteLine("Обратная польская нотация: {0} = {1}", rpn.RpnExpression, rpn.Result.ToString())
        Loop While True
    End Sub[