Обработка данных только на листе

@viper-x · Регистрация: 28.02.2018

Студворк — интернет-сервис помощи студентам

Здравствуйте!
есть такой вот макрос в модуле листа,
спасибо art1289
который убирает при вводе пробелы, рубли и другой мусор
и форматирует текст

Visual Basic
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
Option Explicit
 
Private Sub Worksheet_Change(ByVal Target As Range)
Dim cell As Range, c                                        'удаление_пробелов_при_вводе
For Each cell In Target                                     'проходим по всем измененным ячейкам
    If ActiveCell.Column = 4 Or ActiveCell.Column = 8 Then  'если активная ячейка в столбце D или H (4-ый или 8-ой столбец), то
        Application.ScreenUpdating = False                  'выключаем обновление экрана
        Application.Calculation = xlCalculationManual       'отключаем автопересчет формул
 
For Each c In Array("руб.", Chr(10), Chr(32), Chr(160))     'убрать руб., переходы на другую строку, пробелы, пробелы v2, пробелы из 1С
  Target.Replace What:=c, Replacement:="", LookAt:=xlPart, _
            SearchOrder:=xlByRows, MatchCase:=False, SearchFormat:=False, _
            ReplaceFormat:=False
Next c
            Target.Borders.Color = vbBlack                  'сделать цвет границ ячейки чёрным
            Target.Borders.LineStyle = False                'стереть границы
            Target.Interior.Pattern = xlNone                'убрать заливку ячейки
            With Target.Font                                'сделать шрифт
                .Color = vbBlack                            'чёрным
                .Bold = False                               'нежирным
                .Name = "Arial Cyr"                         'типа Arial Cyr
                .Size = 10                                  'размера 10
            End With
            'MsgBox Target.Address
        Application.Calculation = xlCalculationAutomatic    'возвращаем автопересчет формул
        Application.ScreenUpdating = True                   'включаем обновление экрана
    End If
Next cell
End Sub

но в какой-то момент он начинает распространять своё действие не только на нужные мне колонки
Думал, что replace имеет какой-нибудь параметр типа "заменить во всей книге",
но ничего похожего не нашёл
Как это можно исправить?
Спасибо!

@art1289 · 12.12.2019, 11:21

viper-x, привет так поправь код

Visual Basic
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
Private Sub Worksheet_Change(ByVal Target As Range)
    If Target.Column = 4 Or Target.Column = 8 Then
        Dim cell   As Range, c                                  'удаление_пробелов_при_вводе
        For Each cell In Target                             'проходим по всем измененным ячейкам
'            If ActiveCell.Column = 4 Or ActiveCell.Column = 8 Then    'если активная ячейка в столбце D или H (4-ый или 8-ой столбец), то
                Application.ScreenUpdating = False          'выключаем обновление экрана
                Application.Calculation = xlCalculationManual    'отключаем автопересчет формул
 
                For Each c In Array("руб.", Chr(10), Chr(32), Chr(160))    'убрать руб., переходы на другую строку, пробелы, пробелы v2, пробелы из 1С
                    Target.Replace What:=c, Replacement:="", LookAt:=xlPart, _
                            SearchOrder:=xlByRows, MatchCase:=False, SearchFormat:=False, _
                            ReplaceFormat:=False
                Next c
                Target.Borders.Color = vbBlack              'сделать цвет границ ячейки чёрным
                Target.Borders.LineStyle = False            'стереть границы
                Target.Interior.Pattern = xlNone            'убрать заливку ячейки
                With Target.Font                            'сделать шрифт
                    .Color = vbBlack                        'чёрным
                    .Bold = False                           'нежирным
                    .Name = "Arial Cyr"                     'типа Arial Cyr
                    .Size = 10                              'размера 10
                End With
                'MsgBox Target.Address
                Application.Calculation = xlCalculationAutomatic    'возвращаем автопересчет формул
                Application.ScreenUpdating = True           'включаем обновление экрана
'            End If
        Next cell
    End If
End Sub

сюда же можно прописать ограничение по строкам если нужно

Visual Basic
1
If Target.Column = 4 Or Target.Column = 8 Then

Добавлено через 1 минуту
эти строки нужно вынести из цикла

Visual Basic
1
2
              Application.ScreenUpdating = False          'выключаем обновление экрана
              Application.Calculation = xlCalculationManual    'отключаем автопересчет формул

Visual Basic
1
2
                Application.Calculation = xlCalculationAutomatic    'возвращаем автопересчет формул
                Application.ScreenUpdating = True

@viper-x · 24.01.2020, 11:32 **[ТС]**

art1289, в итоге у меня получился такой макрос

Visual Basic
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
Option Explicit
 
Private Sub Worksheet_Change(ByVal Target As Range)
'Application.ScreenUpdating = False              'выключаем обновление экрана
'Application.Calculation = xlCalculationManual   'отключаем автопересчет формул
    If Target.Column = 4 Or Target.Column = 8 Then          'если целевая(?) ячейка в столбце D или H (4-ый или 8-ой столбец), то
        Dim cell As Range, c                                'удаление_пробелов_при_вводе
        For Each cell In Target                             'проходим по всем измененным ячейкам
                For Each c In Array("руб.", Chr(10), Chr(32), Chr(160))    'убрать руб., переходы на другую строку, пробелы, пробелы v2, пробелы из 1С
                    Target.Replace What:=c, Replacement:="", LookAt:=xlPart, _
                            SearchOrder:=xlByRows, MatchCase:=False, SearchFormat:=False, _
                            ReplaceFormat:=False
                Next c
                Target.Borders.Color = vbBlack              'сделать цвет границ ячейки чёрным
                Target.Borders.LineStyle = False            'стереть границы
                Target.Interior.Pattern = xlNone            'убрать заливку ячейки
                With Target.Font                            'сделать шрифт
                    .Color = vbBlack                        'чёрным
                    .Bold = False                           'нежирным
                    .Name = "Arial Cyr"                     'типа Arial Cyr
                    .Size = 10                              'размера 10
                End With
                'MsgBox Target.Address
        Next cell
    End If
'Application.Calculation = xlCalculationAutomatic    'возвращаем автопересчет формул
'Application.ScreenUpdating = True                   'включаем обновление экрана
End Sub

и всё равно он
время от времени (не каждый раз)
начинает удалять пробелы
во всей книге.
С чем это может быть связано?

@KoGG · 24.01.2020, 14:39

Связано это с состоянием галочки в диалоге замены при использовании руками.
Лечится просто: меняем VBA замену на VB.

Visual Basic
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
Private Sub Worksheet_Change(ByVal Target As Range)
  Dim cell As Range, c, S$                            'удаление_пробелов_при_вводе
  With Application
    .ScreenUpdating = False              'выключаем обновление экрана
    .Calculation = xlCalculationManual   'отключаем автопересчет формул
    .EnableEvents = False                'отключаем отслежевание событий (для уменьшения количества срабатываний Worksheet_Change)
    For Each cell In Target                             'проходим по всем измененным ячейкам
        If cell.Column = 4 Or cell.Column = 8 Then          'если целевая(?) ячейка в столбце D или H (4-ый или 8-ой столбец), то
            S = Target.FormulaR1C1
            For Each c In Array("руб.", Chr(10), Chr(32), Chr(160))    'убрать руб., переходы на другую строку, пробелы, пробелы v2, пробелы из 1С
                S = Replace(S, c, "")
            Next c
            Target.FormulaR1C1 = S
            Target.Borders.Color = vbBlack              'сделать цвет границ ячейки чёрным
            Target.Borders.LineStyle = False            'стереть границы
            Target.Interior.Pattern = xlNone            'убрать заливку ячейки
            With Target.Font                            'сделать шрифт
                .Color = vbBlack                        'чёрным
                .Bold = False                           'нежирным
                .Name = "Arial Cyr"                     'типа Arial Cyr
                .Size = 10                              'размера 10
            End With
        End If
    Next cell
    .Calculation = xlCalculationAutomatic    'возвращаем автопересчет формул
    .ScreenUpdating = True                   'включаем обновление экрана
    .EnableEvents = True                     'включаем отслежевание событий
  End With
End Sub

Новые блоги и статьи Все статьи Все блоги /
Автозаполнение реквизита при выборе элемента справочника Maks 27.03.2026 Программный код из решения ниже на примере нетипового документа "ЗаявкаНаРемонтСпецтехники" разработанного в конфигурации КА2. При выборе "Спецтехники" (Тип Справочник. Спецтехника), заполняется. . .	Сумматор с применением элементов трёх состояний. Hrethgir 26.03.2026 Тут. https:/ / fips. ru/ EGD/ ab3c85c8-836d-4866-871b-c2f0c5d77fbc Первый документ красиво выглядит, но без схемы. Это конечно не даёт никаких плюсов автору, но тем не менее. . . всё может быть. . .	Автозаполнение реквизитов при создании документа Maks 26.03.2026 Программный код из решения ниже размещается в модуле объекта документа, в процедуре "ПриСозданииНаСервере". Алгоритм проверки заполнения реализован для исключения перезаписи значения реквизита,. . .	Команды формы и диалоговое окно Maks 26.03.2026 1. Команда формы "ЗаполнитьЗапчасти". Программный код из решения ниже на примере нетипового документа "ЗаявкаНаРемонтСпецтехники" разработанного в конфигурации КА2. В качестве источника данных. . .
Кому нужен AOT? DevAlt 26.03.2026 Решил сделать простой ланчер Написал заготовку: dotnet new console --aot -o UrlHandler var items = args. Split(":"); var tag = items; var id = items; var executable = args;. . .	Отправка уведомления на почту при изменении наименования справочника Maks 24.03.2026 Программная отправка письма электронной почты на примере изменения наименования типового справочника "Склады" в конфигурации БП3. Перед реализацией необходимо выполнить настройку системной учетной. . .	модель ЗдравоСохранения 5. Меньше увольнений- больше дохода! anaschu 24.03.2026 Теперь система здравосохранения уменьшает количество увольнений. 9TO2GP2bpX4 a42b81fb172ffc12ca589c7898261ccb/ https:/ / rutube. ru/ video/ a42b81fb172ffc12ca589c7898261ccb/ Слева синяя линия -. . .	Midnight Chicago Blues kumehtar 24.03.2026 Такой Midnight Chicago Blues, знаешь?. . Когда вечерние улицы становятся ночными, а ты не можешь уснуть. Ты идёшь в любимый старый бар, и бармен наливает тебе виски. Ты смотришь на пролетающие. . .

Обработка данных только на листе

Решение