Удалить строки с пустыми ячейками в определенном столбце

@Katin · Регистрация: 07.04.2023

Студворк — интернет-сервис помощи студентам

Добрый день! Надеюсь на Вашу помощь! Необходимо удалить из формализованного отчета строки с пустыми ячейками в столбце М, начиная со строки 26 (желательно используя массив).

@Katin · 03.07.2023, 17:45 **[ТС]**

Да.. после отработки кода форма превратилась в кучу бесполезной информации…
Всем большой, большой ПРИВЕТ!
Alex77755, elixi по порядку:
Я обращала внимание, что это формализованный отчет. Унифицированные формы первичной документации, установленные уполномоченными органами на основании федеральных законов, не могут быть изменены по моему желанию или прихоти. В данном случае, в отчете потерялось построчное отображение информации по документам (табличной сетки нет).
У меня в форме данные отражаются в виде цифр, но представляют собой текстовую информацию (коды, идентификаторы, счета, да даже элементарно ИНН может начинаться с «0»). Но после выполнения кода это все без нулевых реквизитов вначале данных либо в экспоненциальном виде. Форматирование грохнулось напрочь. В общем сплошной бардак в данных.
Я конечно не сомневаюсь в Вашем высоком техническом бэкграунде и наверняка это допиливается, правится, но мне некогда было в это даже вникать (простите). Увидела результат, закрыла, забыла.
Передо мной стоят чёткие цели и задачи и мне необходимо в установленные сроки их выполнить. В любом другом случае время и силы тратятся впустую, не принося должного результата и удовлетворения (это я сейчас о том, если я буду разбираться с кодами в которых я с трудом разбираюсь, а не выполнять свои функциональные обязанности).

Lost time is never found again.

Но я буду в любом случае вникать, так как это мне помогает в работе, в том числе и с Вашей помощью.
КостяФедореев, посмотрела Ваше предложенное решение.
В коде поправила и протестировала,

Visual Basic
1
rng.AutoFilter Field:=13, Criteria1:="="

отработал одинаково с моим кодом (примерно 4-5 минут).

Visual Basic
1
Range("M26:M" & lr).SpecialCells(xlBlanks).EntireRow.Delete

Остальные коды больше 30 минут на рабочем месте.
Это ответ shanemac51.
Но предложенные варианты тоже могут мне пригодиться.

Ценю, благодарю Вас всех! Katin!

@Angry Old Man · 03.07.2023, 23:58

Сообщение от Katin

Остальные коды больше 30 минут на рабочем месте

Мой вариант как минимум не медленнее оригинального варианта уважаемого КостяФедореев (я поставил ему своё спасибо), единственное в постановке я не обратил внимание, что ячейка M26 у Вас практически задана жестко. Вот еще мой вариант. На моём допотопном ноуте при 20000 строках в таблице мой вариант отработал за 186 секунд, КостяФедореев 211 секунд, Ваш 195

Visual Basic
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
Sub Katin()
                                                        t1 = Now()
    Const iRange = "M26"
    
    i1 = Range(iRange).Row
    iCol = Range(iRange).Column
    i2 = Cells(i1, 1).End(xlDown).Row
    
    Application.ScreenUpdating = False
    n = 0: Blank = Empty
    For i = i2 To i1 Step -1
        If Cells(i, iCol).Value = Empty Then
            ii = CStr(i)
            Blank = "," + ii + ":" + ii + Blank
            n = Len(Blank)
            If n > 200 Then
                Range(Mid(Blank, 2)).Delete Shift:=xlUp
                Blank = Empty
            End If
        End If
    Next
    If n <> 0 Then Range(Mid(Blank, 2)).Delete Shift:=xlUp
    Application.ScreenUpdating = True
    Range(iRange).Select
                                                            t2 = Now()
                                                            MsgBox t2 & vbCr & t1 & vbCr & DateDiff("s", t1, t2)
End Sub

Не знаю, стОят эти танцы с бубном спаленной электроэнергии

@Katin · 04.07.2023, 14:16 **[ТС]**

Добрый день! Angry Old Man простите меня, но я когда писала, я так и не добралась до Вашего кода. А я пока сама не разберусь, что происходит с моими данными в процессе выполнения кода, я не буду его применять.
Но Вы меня победили, я отложила сейчас свои дела, села и разобралась с последним из предложенных (с помощью окна Locals). Скажу даже это было не так сложно, тем более Вы мне ранее алгоритм прописали.
Результатом я довольна! Благодарю и за код и за настойчивость, ведь я бы могла и не добраться до него. Результат выполнения на рабочем месте 04:26 при чуть более 98 тыс. строк. То есть время выполнения в том же диапазоне, о которых говорила ранее. Но решение неординарное для меня, и оно мне понравилось (танцы с бубном оказались не напрасными). My RESPECT to you!
Ваш вариант рекомендую!!!
Так, что если будут желающие поискать решение на моей страничке, у них будет прекрасный выбор, если они конечно дочитают всю переписку до конца. Уж слишком она получилась длинной.
Надеюсь вопросы все исчерпаны и вопрос будет закрыт.
Большое СПАСИБО!

@Alex77755 · 04.07.2023, 14:51

Сообщение от Katin

Результат выполнения на рабочем месте 04:26

ИМХО: я бы лучше дописал несколько строк если важно форматирование чем ждать столько на таком объме
Хотя с другой стороны можно успеть выпить кофе или пивасика с рыбасиком

@Angry Old Man · 04.07.2023, 23:18

Результат выполнения на моём древнем ноуте в таблице 100 000 строк 31 сек., на 20 000 строк 6 сек. (было 186)

Visual Basic
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
Sub Katin()
                                                        t1 = Now()
    Const iRange = "M26"
    
    i1 = Range(iRange).Row
    iCol = Range(iRange).Column
    i2 = Cells(i1, 1).End(xlDown).Row
    i2Col = 16
    
    Application.ScreenUpdating = False
    
    Arr = Range(Cells(i1, 1), Cells(i2, i2Col)).Value
    U1 = UBound(Arr, 1): U2 = UBound(Arr, 2)
    ReDim Arr2(1 To U1, 1 To U2)
    
    ii = 0
    For i = 1 To U1
        If Arr(i, iCol) <> Empty Then
            ii = ii + 1
            For j = 1 To U2
                Arr2(ii, j) = Arr(i, j)
            Next
        End If
    Next
    
    If ii > 0 Then
        Range(Cells(i1, 1), Cells(i2, i2Col)) = Arr2
        Rows(CStr(i1 + ii) + ":" + CStr(i2)).Delete Shift:=xlUp
    End If
    Application.ScreenUpdating = True
    Range(iRange).Select
                                                            t2 = Now()
                                                            MsgBox t2 & vbCr & t1 & vbCr & DateDiff("s", t1, t2)
End Sub

@Hugo121 · 04.07.2023, 23:40

Сообщение от Katin

желательно используя массив

ещё можно чуть дописать вариант Alex77755 из №13
1. к перекладыванию данных в массиве дописать удаление в этом же массиве данных ненужных строк.
Если памяти не жалко - можно перекладывать в другой массив такого же размера, тогда не надо тратить время на удаление данных.
2. выгружать не только заполненную часть, а весь массив (с уже пустым хвостом)
3. по полученным в процессе данным определяем диапазон строк под удаление, и удаляем всю группу разом.

Столбец с № п/п все корректно обрабатывают? Не уследишь... ))
В этом варианте нет проблем их проставить, а не перенести.

Про ведущие нули не говорили, и в примере их нет. Но это решаемо, если эти нули не забиты индивидуальным форматом каждой ячейки (видал кто такое? Я видал (( )

@Angry Old Man · 05.07.2023, 09:18

Hugo121,

Сообщение от Hugo121

Если памяти не жалко - можно перекладывать в другой массив такого же размера, тогда не надо тратить время на удаление данных.

В моём 25 посте так и сделано. Но в одном массиве тоже не надо удалять данные, просто сделать его аккуратную выгрузку на лист.
Katin, Вот слегка изменённый предыдущий вариант, но с одним массивом, он еще быстрее: 100 000 строк 27 сек. (Возможно, это в рамках погрешности замера). Без спроса и без заявки с Вашей стороны добавил перенумерацию строк в столбце A.

Visual Basic
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
Sub Katin()
                                                        t1 = Now()
    Const iRange = "M26"
    
    i1 = Range(iRange).Row
    iCol = Range(iRange).Column
    i2 = Cells(i1, 1).End(xlDown).Row
    i2Col = 16
    
    Application.ScreenUpdating = False
    
    Arr = Range(Cells(i1, 1), Cells(i2, i2Col)).Value
    U1 = UBound(Arr, 1): U2 = UBound(Arr, 2)
    
    ii = 0
    For i = 1 To U1
        If Arr(i, iCol) <> Empty Then
            ii = ii + 1
            Arr(ii, 1) = ii
            For j = 2 To U2
                Arr(ii, j) = Arr(i, j)
            Next
        End If
    Next
    
    If ii > 0 Then
        Rows(CStr(i1 + ii) + ":" + CStr(i2)).Delete Shift:=xlUp
        Range(Cells(i1, 1), Cells(i1 + ii - 1, i2Col)) = Arr
    End If
    Application.ScreenUpdating = True
    Range(iRange).Select
                                                            t2 = Now()
                                                            MsgBox t2 & vbCr & t1 & vbCr & DateDiff("s", t1, t2)
End Sub

@Hugo121 · 05.07.2023, 09:28

Сообщение от Angry Old Man

В моём 25 посте так и сделано.

извиняюсь, не заметил, вероятно очень долго писал свой пост ((
Удаление лишних данных я упоминал для того чтоб при выгрузке этой частью массива затереть данные листа.
Если выгружать только созданную верхушку - то конечно затирать лишнее не нужно.

@MikeVol · 05.07.2023, 11:48

Angry Old Man, Приветсвую вас. Ваш код из #27 поста отработал за 4 секунды. С учотом характеристик ноутбука (RAM 16Gb, i7-6700HQ, NVIDIA GeForce GTX 1060). Может у Katin будет быстрее. Удачи вам!

@Katin · 05.07.2023, 17:39 **[ТС]**

Добрый день, Всем!
Я не поняла, здесь производственная летучка?
И что решили?
Не расходимся… "Лыко-мочало — начинай сначала".
Продолжаем удалять пустые строки без шанса на чашку кофе?
Я вижу, Вам здесь без меня хорошо… Я в садик за дочкой.
Может за это время еще кто-нибудь заглянет со своими идеями…

Добавлено через 3 часа 46 минут
Angry Old Man извините меня за мой тон. Простите, простите, простите!!!!!
Благодарю за Вашу безграничную доброту ко мне, желание помочь, когда этого уже не ждут.
Вы мне преподали жизненный урок. Спасибо, ВАМ!

@MikeVol · 05.07.2023, 21:36

Да, хочу уточнить. Размножил количество строк до 113165 строк. На основе файла из #1 поста
Вот код слегка модифицированный для более чёткого отображения времени работы кода. Также объявил все переменные, думаю Angry Old Man не будет против. Возможно быстрее и не получиться ни у кого.

Кликните здесь для просмотра всего текста

Visual Basic
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
Option Explicit
 
Sub Katin()
    Dim i As Long, j As Long, U1 As Long, U2 As Long
    Dim i1 As Long, i2 As Long, ii As Long
    Dim iCol As Long, i2Col As Long
    Dim t1 As Variant, t2 As Variant, Arr As Variant
    Dim totalTime   As Double
    t1 = Now()
    Const iRange = "M26"
 
    i1 = Range(iRange).Row
    iCol = Range(iRange).Column
    i2 = Cells(i1, 1).End(xlDown).Row
    i2Col = 16
 
    Application.ScreenUpdating = False
 
    Arr = Range(Cells(i1, 1), Cells(i2, i2Col)).Value
    U1 = UBound(Arr, 1): U2 = UBound(Arr, 2)
    ii = 0
 
    For i = 1 To U1
 
        If Arr(i, iCol) <> Empty Then
            ii = ii + 1
            Arr(ii, 1) = ii
 
            For j = 2 To U2
                Arr(ii, j) = Arr(i, j)
            Next
 
        End If
 
    Next
 
    If ii > 0 Then
        Rows(CStr(i1 + ii) + ":" + CStr(i2)).Delete Shift:=xlUp
        Range(Cells(i1, 1), Cells(i1 + ii - 1, i2Col)) = Arr
    End If
 
    Range(iRange).Select
    t2 = Now()
    
    ' Разница времени в секундах
    totalTime = (t2 - t1) * 24 * 60 * 60    
    MsgBox "Время выполнения: " & Format(totalTime, "#0.00") & " секунд"
    '    MsgBox t2 & vbCr & t1 & vbCr & DateDiff("s", t1, t2)
    Application.ScreenUpdating = True
End Sub

@Hugo121 · 05.07.2023, 21:51

Помнится был быстрый способ от ZVI ещё от 2009 года на сайте которого уже нет
Алгоритм - анализ столбца данных в массиве, в другом созданном массиве ставятся метки, массив выгружается, диапазон сортируется по меткам, удаляется (или очищается) слитная группа строк. Затем можно отсортировать назад.

@Katin · 06.07.2023, 14:57 **[ТС]**

Добрый день!
Ждать, что код отработает на моем ПК за 7 сек, это нереально. И это не только из-за того, что допотопный или нет ПК. На нем установлен и Касперский, и программы в части обеспечения защиты информации. И с ними ПК тормозит. Код отработал за 26 сек. Это успех, но пришлось включить в код форматирование. Спасибо за перенумерацию строк.
Angry Old Man, Вы удивительный человек, Вы затронули меня своей добротой, чуткостью, вовлеченностью в задачу, которую я здесь создала. От которой я в некоторый момент даже устала. Благодаря только Вам получился этот желаемый результат. Спасибо, что Вы здесь, Вы рядом и надеюсь увидеть и общаться с Вами в дальнейшем!
Благодарю Всех неравнодушных кто участвовал в решении задачи!

@Alex77755 · 08.07.2023, 15:10

Сообщение от Hugo121

ещё можно чуть дописать вариант Alex77755 из №13

почти все реализовано кроме удаления строк

Visual Basic
1
2
3
4
5
                For c = 1 To UBound(m, 2)
                    m(i, c) = m(r, c)
                    m(r, c) = "" ' очистка 
                Next c
.Cells(26, 1).Resize(i, 16) = m ' вставка только значимых элементов массива

А чтобы не терялось форматирование достаточно просто изменить

Visual Basic
1
 .Cells(26, 1).Resize(lr - 25, 16).Clear

на

Visual Basic
1
 .Cells(26, 1).Resize(lr - 25, 16).ClearContents

Добавлено через 1 час 8 минут
MikeVol, у меня только 4 с.
в дебаггере:

00:04
Строк: 113164

с сохранением форматирования и дописыванием формулы внизу таблицы

Visual Basic
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
Sub udalit()
    Dim r, c, lr, m, i, j, ttt
    ttt = Time
    With ActiveSheet
        lr = .Cells(.Rows.Count, 13).End(xlUp).Row
        m = .Cells(26, 1).Resize(lr - 23, 16).Value
'        .Cells(26, 1).Resize(lr - 23, 16).ClearContents
 
        For r = 1 To UBound(m) - 1
            If Len(m(r, 13)) > 0 Then
                i = i + 1
                For c = 1 To UBound(m, 2)
                    m(i, c) = m(r, c)
                    m(r, c) = ""
                Next c
            End If
        Next r
        .Rows(27 + i & ":" & lr).Delete
        .Cells(26, 1).Resize(i, 16) = m
        .Cells(28 + i, 13) = "=SUM(R[-" & i & "]C:R[-1]C)"
    End With
    Debug.Print Format(Time - ttt, "nn:ss")
    Debug.Print "Строк: " & lr
    MsgBox Format(Time - ttt, "nn:ss")
 
End Sub

@MikeVol · 08.07.2023, 15:31

Alex77755, Приветсвую вас. Ваш код отработал за 3 скунды. Скрин прилагаю ниже. Утащил себе в копилку. Спасибо.

@Alex77755 · 08.07.2023, 15:33

Сообщение от MikeVol

отработал за 3 скунды

комп у меня дремучий

@MikeVol · 08.07.2023, 15:41

Alex77755, Только заметил. Посмотрите скриншоты ниже. Первый после работы вашего кода, второй после работы кода от Angry Old Man. У него всё ровно.

@Katin · 04.09.2023, 17:26 **[ТС]**

Angry Old Man, добрый день! мне необходимо изменить условие

Visual Basic
1
If Arr(i, iCol) <> Empty Then

В столбце (1) должны быть только строки соответствующие маске "???208*",
Столбец (1) и (2) с форматированием "текст".
Я же разобрала в свое время Ваш код, применяю. Но все свои комментарии видимо были в тестовом файле и удалила.
В таком бешенном ритме, голова кругом идет.
Строк много, поэтому мне нужен этот вариант.

@Katin · 04.09.2023, 17:40 **[ТС]**

Здесь я поправила

Visual Basic
1
2
3
4
 Const iRange = "A13"
        i1 = Range(iRange).Row
    i2 = Cells(i1, 3).End(xlDown).Row
    i2Col = 22

Visual Basic
1
  For j = 1 To U2

@Angry Old Man · 04.09.2023, 22:59

Не уверен, что подойдет, у Вас таблица неудобная: в строках разное форматирование (объединение ячеек}

Visual Basic
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
Sub Katin()
                                                        t1 = Now()
    Const iRange = "A13"                    'Начальная ячейка в рассматриваемой колонке
    Const i2Col = 22                        'Номер последней колонки
    Const Mask = "???208*"                  'Маска что должно остаться
    Const Merge = "A:B"                     'В каких столбцах убрать объединение и сделать центрирование
    
    i1 = Range(iRange).Row
    iCol = Range(iRange).Column
    i2 = Cells(i1, 1).End(xlDown).Row
 
    Application.ScreenUpdating = False
    
    With Columns(Merge)
        .MergeCells = False
        .HorizontalAlignment = xlCenter
    End With
    
    Arr = Range(Cells(i1, 1), Cells(i2, i2Col)).Value
    U1 = UBound(Arr, 1): U2 = UBound(Arr, 2)
    
    ii = 0
    For i = 1 To U1
        If Arr(i, iCol) Like Mask Then
            ii = ii + 1
            For j = 1 To 2
                Arr(ii, j) = "'" + Arr(i, j)
            Next
            For j = 3 To U2
                Arr(ii, j) = Arr(i, j)
            Next
        End If
    Next
    
    If ii > 0 Then
        Rows(CStr(i1 + ii) + ":" + CStr(i2)).Delete Shift:=xlUp
        Range(Cells(i1, 1), Cells(i1 + ii - 1, i2Col)) = Arr
    End If
    Application.ScreenUpdating = True
    Range(iRange).Select
                                                            t2 = Now()
                                                            MsgBox t2 & vbCr & t1 & vbCr & DateDiff("s", t1, t2)
End Sub

Новые блоги и статьи Все статьи Все блоги /
сукцессия 37. Внедрил дипсик в свой оркестр из ИИ. У него закончилось пространство чата, потому опубликую выводы из его работы здесь anaschu 21.07.2026 ==================================================================== КОНТЕКСТ: Моделирование микоризной сукцессии (AM → ECM) ==================================================================== . . .	сукцессия 36. Делаю прогоны модели около порога бифуркации (превращения эндо микоризы в экто микоризу) anaschu 21.07.2026 СУКЦЕССИЯ МИКОРИЗ: КАК МАТЕМАТИКА ОБЪЯСНЯЕТ ПОДЗЕМНУЮ ВОЙНУ Мы привыкли думать, что лес — это деревья. А грибы — это то, что мы собираем в корзинку осенью. Но если заглянуть под землю, окажется,. . .	ИИ и человечность kumehtar 21.07.2026 Забавно, что общаясь с ИИ, я замечаю, насколько он высказывается умно, и насколько верит в людей. Он умеет прощать. Он знает как отвечать не обесценивая опыт других людей, даже если сам не верит. Он. . .	Нейтральные знания ..., ... чистая наука. Пока что-то проходит модерацию на Хабре, стоит развить мысль ... Hrethgir 20.07.2026 К таким радикальным взглядам я конечно в той публикации не приходил, но чтобы скоротать вечер, решил углубиться немного. 1. Почему показания термометра заряжены целью? Цель заложена в самом. . .
Установка нескольких штампов электронной подписи в строго определенных местах файла docx ВладимирСамохин 19.07.2026 (В!) Работа с Электронной подписью - это неотъемлемая часть современного документооборота. Но что делать, если нужно поставить несколько штампов электронной подписи в строго определенных местах. . .	сукцессия 35. Научная статья о проделанной работе anaschu 19.07.2026 Написал в формате латекс и пдф	Вангую, что это не пройдёт модерацию, и на неделе я запущу свой сервер. Hrethgir 19.07.2026 Эта публикация сейчас в песочнице и ждёт приглашения. https:/ / habr. com/ ru/ sandbox/ 295048/ По ссылке 403. Не очень информативно такую ссылку постить. Запись от Usaga размещена Сегодня в 06:46 . . .	сукцессия 33. открытые вопросы от клауде anaschu 19.07.2026 "Что накопилось за эту часть А — тринадцать правок, из которых шесть пришли из ваших вопросов и каждая оказалась реальной ошибкой, а не калибровкой: односторонний симбиоз, отсутствующий листопад,. . .

@Katin 3 / 3 / 0 Регистрация: 07.04.2023 Сообщений: 180
	04.07.2023, 14:16 [ТС]
	Добрый день! Angry Old Man простите меня, но я когда писала, я так и не добралась до Вашего кода. А я пока сама не разберусь, что происходит с моими данными в процессе выполнения кода, я не буду его применять. Но Вы меня победили, я отложила сейчас свои дела, села и разобралась с последним из предложенных (с помощью окна Locals). Скажу даже это было не так сложно, тем более Вы мне ранее алгоритм прописали. Результатом я довольна! Благодарю и за код и за настойчивость, ведь я бы могла и не добраться до него. Результат выполнения на рабочем месте 04:26 при чуть более 98 тыс. строк. То есть время выполнения в том же диапазоне, о которых говорила ранее. Но решение неординарное для меня, и оно мне понравилось (танцы с бубном оказались не напрасными). My RESPECT to you! Ваш вариант рекомендую!!! Так, что если будут желающие поискать решение на моей страничке, у них будет прекрасный выбор, если они конечно дочитают всю переписку до конца. Уж слишком она получилась длинной. Надеюсь вопросы все исчерпаны и вопрос будет закрыт. Большое СПАСИБО! 0

@MikeVol Одесса - Украина 523 / 201 / 70 Регистрация: 01.04.2020 Сообщений: 624
	05.07.2023, 11:48
	Angry Old Man, Приветсвую вас. Ваш код из #27 поста отработал за 4 секунды. С учотом характеристик ноутбука (RAM 16Gb, i7-6700HQ, NVIDIA GeForce GTX 1060). Может у Katin будет быстрее. Удачи вам! 1

@Katin 3 / 3 / 0 Регистрация: 07.04.2023 Сообщений: 180
	05.07.2023, 17:39 [ТС]
	Добрый день, Всем! Я не поняла, здесь производственная летучка? И что решили? Не расходимся… "Лыко-мочало — начинай сначала". Продолжаем удалять пустые строки без шанса на чашку кофе? Я вижу, Вам здесь без меня хорошо… Я в садик за дочкой. Может за это время еще кто-нибудь заглянет со своими идеями… Добавлено через 3 часа 46 минут Angry Old Man извините меня за мой тон. Простите, простите, простите!!!!! Благодарю за Вашу безграничную доброту ко мне, желание помочь, когда этого уже не ждут. Вы мне преподали жизненный урок. Спасибо, ВАМ! 0

@Hugo121 6998 / 2896 / 555 Регистрация: 19.10.2012 Сообщений: 8,804
	05.07.2023, 21:51
	Помнится был быстрый способ от ZVI ещё от 2009 года на сайте которого уже нет Алгоритм - анализ столбца данных в массиве, в другом созданном массиве ставятся метки, массив выгружается, диапазон сортируется по меткам, удаляется (или очищается) слитная группа строк. Затем можно отсортировать назад. 0

@Katin 3 / 3 / 0 Регистрация: 07.04.2023 Сообщений: 180
	06.07.2023, 14:57 [ТС]
	Добрый день! Ждать, что код отработает на моем ПК за 7 сек, это нереально. И это не только из-за того, что допотопный или нет ПК. На нем установлен и Касперский, и программы в части обеспечения защиты информации. И с ними ПК тормозит. Код отработал за 26 сек. Это успех, но пришлось включить в код форматирование. Спасибо за перенумерацию строк. Angry Old Man, Вы удивительный человек, Вы затронули меня своей добротой, чуткостью, вовлеченностью в задачу, которую я здесь создала. От которой я в некоторый момент даже устала. Благодаря только Вам получился этот желаемый результат. Спасибо, что Вы здесь, Вы рядом и надеюсь увидеть и общаться с Вами в дальнейшем! Благодарю Всех неравнодушных кто участвовал в решении задачи! 0

Удалить строки с пустыми ячейками в определенном столбце

Решение