Поиск значения на листе и выполнение действий

Sub Procedure_1()
 
    'Здесь пишем, что ищем, чтобы в самом коде не писать (чтобы было удобнее).
    Const sWhatFind As String = "word"
 
    Dim rFind As Excel.Range
    Dim lFindRow As Long, lFindColumn As Long
    Dim lLastRow As Long
    
    Set rFind = ActiveSheet.Cells.Find(What:=sWhatFind, LookIn:=xlValues, _
        LookAt:=xlWhole, SearchOrder:=xlByRows, SearchDirection:=xlNext, _
        MatchCase:=False, SearchFormat:=False)
        
    'Если найдено.
    If Not rFind Is Nothing Then
        
        'Запоминаем строку и столбец, где было найдено искомое слово,
        'т.к. после удаления этой строки переменная rFind потеряет своё значение.
        lFindRow = rFind.Row
        lFindColumn = rFind.Column
        
        'Удаление строки.
        rFind.EntireRow.Delete
        
        'Определяем, где заканчиваются данные после найденной строки.
        lLastRow = ActiveSheet.Cells(lFindRow, lFindColumn).End(xlDown).Row
        
        'Копируем данные.
        ActiveSheet.Range(ActiveSheet.Cells(lFindRow, lFindColumn), ActiveSheet.Cells(lLastRow, lFindColumn + 12)).Copy _
            Destination:=ActiveSheet.Range("B2")
            
    End If
 
End Sub

Sub Procedure_1()
 
    'Здесь пишем, что ищем, чтобы в самом коде не писать (чтобы было удобнее).
    Const sWhatFind As String = "word"
 
    Dim rRangeB2 As Excel.Range
    Dim rFind As Excel.Range
    Dim lFindRow As Long, lFindColumn As Long
    Dim lLastRow As Long
    Dim lRowsCount As Long
    
    Set rFind = ActiveSheet.Cells.Find(What:=sWhatFind, LookIn:=xlValues, _
        LookAt:=xlWhole, SearchOrder:=xlByRows, SearchDirection:=xlNext, _
        MatchCase:=False, SearchFormat:=False)
        
    'Если найдено.
    If Not rFind Is Nothing Then
        
        'Запоминаем строку и столбец, где было найдено искомое слово,
        'т.к. после удаления этой строки переменная rFind потеряет своё значение.
        lFindRow = rFind.Row
        lFindColumn = rFind.Column
        
        'Удаление строки.
        rFind.EntireRow.Delete
        
        'Определяем, где заканчиваются данные после найденной строки.
        lLastRow = ActiveSheet.Cells(lFindRow, lFindColumn).End(xlDown).Row
        
        'Определяем количество строк.
        lRowsCount = lLastRow - lFindRow + 1
        
        'Создаём диапазон, куда вставить данные.
        Set rRangeB2 = ActiveSheet.Range("B2").Resize(lRowsCount, 13)
        
        'Копируем данные.
        ActiveSheet.Range(ActiveSheet.Cells(lFindRow, lFindColumn), ActiveSheet.Cells(lLastRow, lFindColumn + 12)).Copy _
            Destination:=rRangeB2
        
        'Для третьего столбца задаём формат даты.
        rRangeB2.Columns(3).NumberFormat = "dd mmmm yyyy"
        
        'Задаём для диапазона размер шрифта.
        rRangeB2.Font.Size = 6
        
    End If
 
End Sub