Совет по выбору БД (не Access), взаимодействующей с VBA

Private Sub CreateTable(ByVal withConnection As ADODB.Connection)
  'Процедура создание Таблицы
    Dim pCom As New ADODB.Command 'Переменная для SQL запроса
    pCom.ActiveConnection = withConnection: pCom.CommandType = adCmdText 'создаем активное соеденение с БД
    pCom.CommandText = "Create Table Table_Ustroistva(FId Integer Primary Key, ComboText Text(32) Not Null Unique)" ' Создаем таблицу устроиства с двумя полями для нумерации и Наименование устроиства(поле не должно быть пустым)
    pCom.Execute 'Выполняем запрос
End Sub
 
Private Sub FillTable(ByVal withConnection As ADODB.Connection)
    Dim pRSet As New ADODB.Recordset ' переменная для работы с таблицами
    pRSet.CursorLocation = adUseClient: pRSet.LockType = adLockOptimistic
    pRSet.CursorType = adOpenKeyset
    pRSet.Open "Select * From main.Table_Ustroistva", withConnection 'Выполняем запрос для занесение значений в поля
    pRSet.AddNew: pRSet(0).Value = 1: pRSet(1).Value = "1" ' число и строка
    pRSet.AddNew: pRSet(0).Value = 2: pRSet(1).Value = "2"
    pRSet.Update: pRSet.Close ' Записываем в таблицу значения
End Sub
 
Private Function CreateSQLiteDatabase() As ADODB.Connection
     'Подключаемся к SQLodbc  и создаем БД
     Const sConn As String = "Provider=MSDASQL.1;Persist Security Info=True;Extended Properties=""Driver={SQLite3 ODBC Driver};Database=c:\Test\MyDatabase.db3;StepAPI=;SyncPragma=Normal;NoTXN=;Timeout=300;ShortNames=;LongNames=;NoCreat=False;NoWCHAR=;FKSupport=;JournalMode=;OEMCP=;LoadExt=;BigInt=;"""
    'Создаем соединение для системых настроек
    Dim pConn As New ADODB.Connection
    pConn.Mode = adModeShareDenyNone: pConn.Open sConn
    'Устанавливаем кодировку
    pConn.Execute "PRAGMA encoding=""UTF-8"""
    Set CreateSQLiteDatabase = pConn
 
End Function
 
Private Sub CommandButton1_Click()
 
 Dim ForPrace As String 'Переменная для списка
 Dim pConn As ADODB.Connection ' Переменная для работы соед с ADO
 
    Dim pRSet As New ADODB.Recordset
    'Set это вроде создание объекта (Создать БД) или устнавливаем эту базу для работы
    Set pConn = CreateSQLiteDatabase
    CreateTable pConn 'Соеденяемся и создаем Запрос для создание таблицы
    FillTable pConn ' Соеденяемся и заполняем поля таблицы в нашем случае только второе поле
    pRSet.CursorLocation = adUseClient 'точно не знаю но прошу прокомментировать это поле , по моему мнению, устанавливаем курсор на первую строку
    
    pRSet.Open "Select * From main.Table_Ustroistva", pConn 'Открываем таблицу для работы
    'Условие если строк нету, то установить в начальное положение
    If pRSet.RecordCount > 0 Then
        pRSet.MoveFirst
        'Делаем цикл до конца таблицы
        Do Until pRSet.EOF
        'Заносим каждое значение в переменную ForPrace  из поля два (хотя при создание полей можно было не создовать первое поле)
                        ForPrace = pRSet(1).Value
                    'Этот метод я не понял оставил на месте
                    Debug.Print CStr(pRSet(0).Value) & " = " & pRSet(1).Value
        
        'Заносим каждое поле в список
               ComboBox1.AddItem (ForPrace) ' Занесение значении из второго поля таблицы
            
            pRSet.MoveNext ' перемещаемся на следующую строку и так до конца
        Loop
    End If
    pRSet.Close: pConn.Close ' закрываем соед и все изменения
End Sub

Private Sub TestCSV()
    Dim cn As ADODB.Connection
    Dim rs As ADODB.Recordset
    
    Set cn = New ADODB.Connection
    cn.ConnectionString = "Driver={Microsoft Text Driver (*.txt; *.csv)}; DriverId=27; DefaultDir=" & ThisWorkbook.Path & "\ado-csv; DBQ=" & ThisWorkbook.Path & "\ado-csv; Extensions=csv;"
    cn.Open
    
    Set rs = New ADODB.Recordset
    rs.Open "SELECT * FROM TABLE1.CSV", cn, adOpenDynamic, adLockOptimistic
 
    Debug.Print rs.Fields(0).name, rs.Fields(1).name
    Do While Not rs.EOF
        Debug.Print rs.Fields(0).Value, rs.Fields(1).Value
        rs.MoveNext
    Loop
    
    rs.AddNew
    rs.Fields(0) = 8
    rs.Fields(1) = "Text string 8"
    rs.Update
    
    rs.Close
    Set rs = Nothing
    
    cn.Close
    Set cn = Nothing
End Sub

rs.MoveFirst
rs.MoveNext
' обновить запись
rs.Fields(0) = 8
rs.Fields(1) = "Update string 8"
' или удалить
rs.Delete