Удаление совпадающих записей в двух столбцах

Sub Procedure_1()
    
    'Tools - References... Microsoft Scripting Runtime.
    Dim myDictionary As New Scripting.Dictionary
    
    Dim myArray_1() As Variant, myArray_2() As Variant
    Dim myLastRow As Variant
    Dim i As Long, j As Long
    
    '1. Определяем последнюю строку с данными в столбце "B".
        'Чтобы знать: со скольки строками работать.
    myLastRow = Columns("B").Find(What:="?", LookIn:=xlValues, LookAt:=xlPart, _
        SearchOrder:=xlByColumns, SearchDirection:=xlPrevious, _
        MatchCase:=False, SearchFormat:=False).Row
        
    '2. Быстрее работать с VBA-массивами, чем с Excel-ячейками.
        'Поэтому помещаем данные из Excel-листа в VBA-массив.
    myArray_1() = Range("B1:B" & myLastRow).Value
    
    '3. Для поиска одинаковых данных удобно и быстрее использовать
        'объект "Dictionary".
    'Помещам данные из массива "myArray_1" в объект "myDictionary".
    For i = 1 To UBound(myArray_1, 1) Step 1
        'Добавляем только уникальные данные.
        If myDictionary.Exists(Key:=myArray_1(i, 1)) = False Then
            'Item в данном случае не нужно, но этот параметр
            'обязательно нужно указать. Помещаем туда ноль.
            myDictionary.Add Key:=myArray_1(i, 1), Item:=0
        End If
    Next i
    
    'Берём с Excel-листа данные из столбца "A".
    
    '4. Определяем последнюю строку с данными в столбце "A".
    myLastRow = Columns("A").Find(What:="?", LookIn:=xlValues, LookAt:=xlPart, _
        SearchOrder:=xlByColumns, SearchDirection:=xlPrevious, _
        MatchCase:=False, SearchFormat:=False).Row
        
    '5. Помещаем данные из Excel-листа в VBA-массив.
    myArray_1() = Range("A1:A" & myLastRow).Value
    
    '6. Удаляю данные из массива "myArray_1" из элементов, 
        'которые есть в объекте "myDictionary".
    For i = 1 To UBound(myArray_1, 1) Step 1
        'Смотрю, есть ли элемент из массива "myArray_1"
            'в объекте "myDictionary".
        If myDictionary.Exists(Key:=myArray_1(i, 1)) = True Then
            'Если есть, то удаляю данные из элемента массива "myArray_1".
            myArray_1(i, 1) = Empty
        End If
    Next i
    
    '7. Переношу данные из массива "myArray_1" в массив "myArray_2",
        'чтобы потом сразу вставить данные на Excel-лист. Так
        'должно быстрее сработать.
    ReDim myArray_2(1 To UBound(myArray_1, 1), 1 To 1)
    
    For i = 1 To UBound(myArray_1, 1) Step 1
        'Если в элементе массива не пусто, то помещаю данные
            'в массив "myArray_2".
        If myArray_1(i, 1) <> Empty Then
            'С помощью переменной "j" переходим по массиву "myArray_2".
            j = j + 1
            myArray_2(j, 1) = myArray_1(i, 1)
        End If
    Next i
    
    '8. Вставляем данные в столбец "A".
    Range("A1:A" & myLastRow).Value = myArray_2()
    
End Sub