Как передать параметр при использовании CommandBarButton.OnAction

Sub Procedure_1()
 
    Dim myBar As CommandBar
    Dim myButton As CommandBarButton
    
    '1. Создаём панель инструментов.
    'Temporary:=True - чтобы панель инструментов удалялась после
        'закрытия программы "Word".
    Set myBar = Application.CommandBars.Add(Name:="Панель", Temporary:=True)
    
    '2. Делаем панель инструментов видимой.
    myBar.Visible = True
    
    '3. Создаём на панели инструментов кнопку и даём
        'кнопке VBA-имя "myButton". Через это имя можно
        'в коде обращаться к кнопке.
    Set myButton = myBar.Controls.Add(Type:=msoControlButton)
    
    '4. Делаем параметры у кнопки.
    With myButton
        '4.1. Делаем, чтобы было видно кнопку.
        .Style = msoButtonCaption
        '4.2. Делаем надпись на кнопке.
        .Caption = "Кнопка"
        '4.3. Указываем, какую процедуру вызвать.
        .OnAction = "Procedure_2"
        '4.4. Указываем, какой параметр передать в процедуру.
        .Parameter = 1
    End With
 
End Sub
 
Sub Procedure_2()
    
    'Вызываем процедуру "Procedure_3" и передаём ей
        'параметр, который представляет собой параметр "Parameter"
        'элемента управления, который вызывал процедуру "Procedure_2".
    Call Procedure_3(Application.CommandBars.ActionControl.Parameter)
 
End Sub
 
Sub Procedure_3(myParameter As Long)
    
    'Выводим параметр кнопки в View - Immediate Window.
    Debug.Print myParameter
 
End Sub