Найти название товара, который по цене наиболее близкий к средней цене

Public Function minim _
    (Товары As Range, Цены As Range) As String
    
    Dim arrЦены As Variant, arrТовары As Variant
    Dim myCount As Integer
    Dim i As Integer
    '"Double" означает, что в переменной могут быть только числа
        '(ещё бывает, например, текст).
        'Причём числа могут быть как целые, так и дробные.
    Dim mySum As Double
    Dim myAverage As Double
    Dim myDifference As Double
    Dim myMinItem As Integer
    
    
    myCount = Цены.Rows.Count
    arrТовары = Товары.Value
    arrЦены = Цены.Value
    
    
    'Можно не писать "mySum = 0", т.к. VBA
        'сам помещает в переменные нули при запуске процедры,
        'если переменная не глобальная.
    mySum = 0
    For i = 1 To myCount Step 1
        mySum = mySum + arrЦены(i, 1)
    Next i
    
    'Находим среднюю цену.
    myAverage = mySum / myCount
    
    'Принимаем за нужную цену первую цену.
    'Т.к. ближайшая цена может быть меньше и больше средней, то
        'нужно не учитывать знак.
    'С помощью VBA-функции "Abs" убираем из числа знак.
    myDifference = Abs(arrЦены(1, 1) - myAverage)
    
    'В переменную "myMinItem" запоминаем порядковый
        'номер строки в массиве "arrЦены".
    myMinItem = 1
    
    For i = 2 To myCount Step 1
        If Abs(arrЦены(i, 1) - myAverage) < myDifference Then
            myDifference = Abs(arrЦены(i, 1) - myAverage)
            'Запоминаем порядковый номер строки в массиве "arrЦены".
            myMinItem = i
        End If
    Next i
    
    minim = arrТовары(myMinItem, 1)
    
End Function