Текстовые файлы в Excel 2010

Sub TXTFiles()
    Dim i As Long, r As Long, v As Variant
    Dim s As String, sFolder As String, sFiles As String
    With Application.FileDialog(msoFileDialogFolderPicker)
        .Title = "Выберите папку"
        If .Show = False Then Exit Sub
        sFolder = .SelectedItems(1) & "\" 'Важная тонкость - в конце строки пути
        'нужно поставить обратную косую черту, если речь идет о папке.
        'Команда Dir очень строга в отношении данного вопроса!
    End With
    sFiles = Dir(sFolder & "*.txt")
    Application.ScreenUpdating = False
    Do While sFiles <> ""
        'Если лист с определенным названием "xxx" уже существует,
        'то конструкция Worksheets.Add.Name = "xxx" создаст новый лист,
        'но не переименует его. Думаю, это неправильно. Вместо этого попробуем
        'активировать лист с названием "xxx".
        On Error GoTo ErrNoSuchSheet
        Sheets(Left(sFiles, Len(sFiles) - 4)).Activate
        On Error GoTo 0
        Cells.Clear
        r = 0
        Open sFiles For Input As #1
        Do While Not EOF(1)
            'Код жестко привязан к определнной размерности таблицы...
            'For i = 1 To 7
            'For j = 1 To 8
            'Cells(i, j) = Input(1, #1)
            'Next
            'Next
            '...а нужно обрабатывать таблицы разных размерностей, поэтому
            'поступим так...
            '1) Читаем из файла строку данных:
            Line Input #1, s
            r = r + 1
            '2) Разбиваем строку на элементы, используя Split:
            v = Split(s)
            '3) Выгружаем данные из массива в очередную строку листа:
            With Cells(r, 1).Resize(, UBound(v) + 1)
                .Value = v
                .Value = .Value
            End With
        Loop
        Close #1
        sFiles = Dir 'После обработки файла было бы неплохо перейти к следующему...
        '(или убедиться, что других текстовых файлов больше нет).
    Loop
    Application.ScreenUpdating = True
    Exit Sub
 
'Если же лист активировать не удалось, тогда его точно не существует,
'и можно смело создавать новый.
ErrNoSuchSheet:
    With Sheets
        .Add(After:=.Item(.Count)).Name = Left(sFiles, Len(sFiles) - 4)
    End With
    Resume Next
End Sub