Простой парсер xls или csv

Option Explicit
Dim cnn, rst, objWSH, strFName, strA, objA
 
strFName = "h:\_VBA\База данных\Jet.OLEDB\3\Example0.xls"
 
Set objWSH = CreateObject("WScript.Shell")
Set cnn = CreateObject("adodb.Connection")
Set rst = CreateObject("adodb.Recordset")
 
' Если установлена 64-разрядная версия Excel -> закомментировать этот блок
if GetOSBitness() = "x64" then
    if instr(1, Wscript.FullName, "SysWow64", 1) = 0 then
        Dim vbHost: vbHost = CreateObject("Scripting.FileSystemObject").GetBaseName(Wscript.FullName)
        objWSH.Run """" & objWSH.ExpandEnvironmentStrings("%SystemRoot%") & "\SysWow64\" & vbHost & ".exe""" & " //nologo " & """" & WScript.ScriptFullName & """", 1, false
        WScript.Quit
    end if
end if
 
'для Excel 97/2003
cnn.Open "Driver={Microsoft Excel Driver (*.xls)};DBQ=" & strFName
'для Excel 2007 и выше
'cnn.Open "Driver={Microsoft Excel Driver (*.xls, *.xlsx, *.xlsm, *.xlsb)};DBQ=" & strFName
rst.Open "SELECT * FROM [Лист1$A1:U]", cnn, 3, 1 '3 - adOpenStatic, 1 - adLockReadOnly
 
with rst
    Do until .EOF or .BOF
        if Len(GetValue("A")) = 0 then Exit Do
        
        strA = "myutil.exe " & vbCRLF
        strA = strA & " -param0 " & GetValue("A") & vbCRLF ' -param0 (номер строки начала обработки, по умолчанию = 1)
        strA = strA & " -param1 " & GetValue("S") & vbCRLF ' -param1 Filename
        strA = strA & " -param2 " & GetValue("E") & vbCRLF ' -param2 BrandName
        strA = strA & " -param3 " & GetValue("G") & vbCRLF ' -param3 Name2
        strA = strA & " -param4 " & GetValue("R") & vbCRLF ' -param4 Attrib2
 
        If GetValue("U") = "0" Then
                strA = strA & " -param5 " & GetValue("P") & vbCRLF ' -param5 (if Attrib4=0 then Sum1, otherwise Sum2)
                strA = strA & " -param6 AAA"                       ' -param6 (if Attrib4=0 then "AAA", otherwise "BBB")
        Else
                strA = strA & " -param5 " & GetValue("Q") & vbCRLF
                strA = strA & " -param6 BBB"
        End If
 
        MsgBox strA
 
        Set objA = objWSH.Exec(Replace(strA, vbCRLF, ""))
 
        If objA.ExitCode <> 0 Then
                MsgBox("Проблемы в строке #" & GetValue("A") & vbCRLF & strA & vbCRLF & "вылетаем")
                Exit Do
        End If
        
        .MoveNext
    Loop
end with
 
rst.Close: cnn.Close
 
Function GetValue(ColumnName): GetValue = Trim(rst.Fields(ASC(UCase(ColumnName))-65)): End Function
 
Function GetOSBitness()
    GetOSBitness = "x64": If objWSH.ExpandEnvironmentStrings("%PROCESSOR_ARCHITECTURE%") = "x86" and objWSH.ExpandEnvironmentStrings("%PROCESSOR_ARCHITEW6432%") = "%PROCESSOR_ARCHITEW6432%" then GetOSBitness = "x32"
End Function