Перезапуск процесса с разными параметрами

Set oWSH = CreateObject("WScript.Shell")
For Each N in Array(246,326,762)
  Set Exe = oWSH.Exec("Process.exe -s -a " & N & " -p 5630")
  WSH.Sleep 180000 : Exe.Terminate
Next

'Наблюдение на текущем компьютере за НЕ ИНТЕРАКТИВНЫМ процессом
'и перезапуск его, если он остановлен
Dim objWMI, objCollection, objInstance, objItem, objConfig
Dim intErr, intTemp, lngProcID, blnFound, i
Dim strPath, strProcess, strCmdLine, strHandle, strTemp1, strTemp2
 
strPath = "C:\New Folder\file.exe"
strProcess = "file.exe"
strCmdLine = "-s -a 246 -p 5630"
Set objWMI = GetObject("winmgmts:\\.\root\cimv2"): Set objInstance = GetObject("winmgmts:\\.\root\cimv2:Win32_Process")
Set objConfig = objWMI.Get("Win32_ProcessStartup").SpawnInstance_
objConfig.ShowWindow = 1
intErr = 0: blnFound = False
Set objCollection = objWMI.ExecQuery("SELECT Name,CommandLine,Handle FROM Win32_Process WHERE Name='" & strProcess & "'")
If objCollection.Count > 0 Then
    For Each objItem In objCollection
    strTemp1 = objItem.CommandLine
    strTemp2 = objItem.Handle
Next
    If InStr(1, strTemp1, strCmdLine, vbTextCompare) > 0 Then
        strHandle = CLng(strTemp2)
        blnFound = True
    End If
End If
If Not blnFound Then
    intErr = objInstance.Create(strPath & " " & strCmdLine, null, objConfig, lngProcID)
    If intErr = 0 Then
        strHandle = lngProcID
    Else
        WScript.Quit
    End If
End If
On Error Resume Next
Set objCollection = objWMI.ExecNotificationQuery("SELECT * FROM __InstanceDeletionEvent " & _
    "WITHIN 1 WHERE TargetInstance ISA 'Win32_Process' AND TargetInstance.Name='" & strProcess & "'")
If Err.Number = 0 Then
    Do
        Set objItem = objCollection.NextEvent
        If Err.Number = 0 Then
            lngProcID = CLng(objItem.TargetInstance.Handle)
            If strHandle = lngProcID Then
                intErr = objInstance.Create(strPath & " " & strCmdLine, null, objConfig, lngProcID)
                If intErr = 0 Then
                    strHandle = lngProcID
                    Do
                        WScript.Sleep 2000
                        intTemp = objWMI.ExecQuery("SELECT Name,Handle FROM Win32_Process WHERE Name='" & strProcess & "' AND Handle='" & CStr(strHandle) & "'").Count
                        If intTemp = 0 Then
                            intErr = objInstance.Create(strPath & " " & strCmdLine, null, objConfig, lngProcID)
                            If intErr = 0 Then
                                strHandle = lngProcID
                            Else
                                Err.Clear
                                WScript.Quit
                            End If
                        Else
                            Exit Do
                        End If
                    Loop
                    Else
                    Err.Clear
                    WScript.Quit
                End If
            End If
        Else
            WScript.Quit
        End If
    Loop
Else
    WScript.Quit
End If
Set objItem = Nothing: Set objCollection = Nothing: Set objConfig = Nothing: Set objInstance = Nothing: Set objWMI = Nothing
WScript.Quit 0

Set oWSH = CreateObject("WScript.Shell")
For Each N in Array(246,326,762)
  Set Exe = oWSH.Exec("DCServer.exe -s -a " & N & " -p 5630")
  WSH.Sleep 180000 : Exe.Terminate
Next

Option Explicit
Dim oService, N, PID
Set oService = GetObject("winmgmts:\\.\root\CIMV2")
Do
  For Each N In Split("246:3 326:5 762:3")
    oService.Get("Win32_Process").Create "DCServer.exe -s -a " & Split(N,":")(0) & " -p 5630",,, PID
    WSH.Sleep 60000*Split(N,":")(1) : oService.Get("win32_process.Handle=" & PID).Terminate
  Next
Loop