Страны и столицы с отдельным txt

Option Explicit
 
Option Compare Text     ' Регистр не будем учитывать
Const n As Integer = 5  ' Количество вопросов
Dim Question(1 To n) As String ' Вопросы
Dim Country(1 To n) As String  ' Страны
Dim Capital(1 To n) As String  ' Столицы
Dim i As Integer
Dim nQ As Integer
 
'Следующий вопрос
Private Sub NextQuestion(ByVal i As Integer)
    'Если нужно сделать кнопки недоступными до тех пор пока
    'не будет дан правильный ответ (то есть невозможно будет перейти к следующему вопросу)
    'то нужно раскомментировать следующие две строчки кода
    'CommandButton2.Enabled = False 'Кнопки делаем недоступными
    'CommandButton1.Enabled = False '
    TextBox1.Text = Question(nQ)   ' В текстбокс выводим очередной вопрос
    TextBox2.Text = ""  'Текстбоксы стран и столиц очищаем
    TextBox3.Text = ""  'Текстбоксы стран и столиц очищаем
    Label1.Caption = ""
End Sub
 
'Конец игры
Private Sub GameOver()
    TextBox1.Text = "Вопросы закончились! Спасибо!"
    TextBox2.Text = "" 'Текстбоксы стран и столиц очищаем
    TextBox3.Text = "" 'Текстбоксы стран и столиц очищаем
    Label1.ForeColor = vbBlue: Label1.Caption = "Game over!"
    CommandButton1.Enabled = False 'Кнопки делаем недоступными
    CommandButton2.Enabled = False 'Кнопки делаем недоступными
End Sub
 
'Кнопка "Проверить"
Private Sub CommandButton1_Click()
    If Trim(TextBox2.Text) = "" And Trim(TextBox3.Text) = "" Then Exit Sub
   'Если текст в текстбоксах соответствует записям в массивах
   'то разрешаем кнопку "Следующий вопрос" и выводим в метку
   'соответствующую надпись
    If Trim(TextBox2.Text) = Country(nQ) And Trim(TextBox3.Text) = Capital(nQ) Then
            Label1.ForeColor = vbGreen: Label1.Caption = "Правильно!"
            CommandButton2.Enabled = True
    Else
            Label1.ForeColor = vbRed: Label1.Caption = "Неправильно!"
            'CommandButton2.Enabled = False ' можно запретить кнопку "Следующий вопрос", если ответ неправильный
    End If
End Sub
 
'Кнопка "Следующий вопрос"
Private Sub CommandButton2_Click()
    nQ = nQ + 1
    If nQ > n Then ' Еcли вопросы кончились , то вызываем процедуру окончания игры
         Call GameOver
         nQ = 1
    Else ' Иначе вызываем процедуру NextQuestion
         Call NextQuestion(nQ)
    End If
End Sub
 
'Кнопка "Выход"
Private Sub CommandButton3_Click()
    If MsgBox("Вы действительно хотите выйти?", vbYesNo, "Страны и столицы.") = vbYes Then
       Unload Me
    Else
       Call NewGame
    End If
End Sub
 
'При изменение содержимого тексбоксов очищаем метку и разрешаем кнопку "Проверить"
Private Sub TextBox2_Change()
    CommandButton1.Enabled = True
    Label1.Caption = ""
End Sub
'При изменение содержимого тексбоксов очищаем метку и разрешаем кнопку "Проверить"
Private Sub TextBox3_Change()
    CommandButton1.Enabled = True
    Label1.Caption = ""
End Sub
 
'Заполняем массивы вопросами и ответами
Private Sub LoadData()
    Dim St, S As String
    S = "На подоконнике стояли настурция и стакан карамели." & vbTab & "Турция" & vbTab & "Анкара" & vbCrLf & _
        "Несчастный, неужели Вы до сих пор не изучили, откуда коммерсант ягоду поставил " & vbTab & "Чили" & vbTab & "Сантьяго" & vbCrLf & _
        "А теперь у меня вопрос: сия леди послала письмо сквайру?" & vbTab & "Россия" & vbTab & "Москва" & vbCrLf & _
        "Пассажир в пятом купе ругается: ему не выдали матрац" & vbTab & "Перу" & vbTab & "Лима" & vbCrLf & _
        "Старатели Аляски, Таймырские геологи! Будете в Анапе - киньте в море монетку" & vbTab & "Китай" & vbTab & "Пекин" & vbCrLf
        St = Split(S, vbCrLf)
    For i = 1 To n
      Question(i) = Split(St(i - 1), vbTab)(0)
      Country(i) = Split(St(i - 1), vbTab)(1)
      Capital(i) = Split(St(i - 1), vbTab)(2)
    Next i
End Sub
' Процедура новой игры
Private Sub NewGame()
    CommandButton2.Enabled = True 'Кнопки делаем  доступными
    CommandButton1.Enabled = True
    Label1.Caption = ""
    TextBox2.Text = ""  'Текстбоксы стран и столиц очищаем
    TextBox3.Text = ""  'Текстбоксы стран и столиц очищаем
    nQ = 1              'Номер первого вопроса
    Call NextQuestion(nQ)
End Sub
 
Private Sub Form_Load()
    Call LoadData
    Call NewGame
End Sub