Как запустить приложение на ПК в сети

Sub Example()
Dim objWMI As Object, objCollection As Object, objItem As Object
Dim arrComputers, strProcess As String, strBias As String, strRunTime As String
Dim intResult As Integer, i As Integer
 
strProcess = "notepad.exe"
arrComputers = Array("user1", "user2")
On Error Resume Next
For i = 0 To UBound(arrComputers)
    Set objWMI = GetObject("winmgmts:{impersonationLevel=impersonate}!\\" & arrComputers(i) & "\root\cimv2")
    If Err.Number = 0 Then
        Set objCollection = objWMI.ExecQuery("SELECT Bias FROM Win32_TimeZone")
        For Each objItem In objCollection
            If objItem.Bias > 0 Then
                strBias = "+" & CStr(objItem.Bias)
            Else
                strBias = CStr(objItem.Bias)
            End If
        Next
        Set objCollection = objWMI.ExecQuery("SELECT Name FROM Win32_Process WHERE Name='" & strProcess & "'")
        If objCollection.Count = 0 Then
            Set objWMI = GetObject("winmgmts:{impersonationLevel=impersonate}!\\" & arrComputers(i) & "\root\cimv2:Win32_ScheduledJob")
            If Err.Number = 0 Then
                strRunTime = "********" & Replace(Left(DateAdd("n", 1, Time), 8), ":", "") & ".000000" & strBias
                intResult = objWMI.Create(strProcess, strRunTime, False, , , True)
                If Err.Number = 0 Then
                    If intResult = 0 Then
                        MsgBox arrComputers(i) & " - задание на запуск процесса назначено.", vbInformation
                    Else
                        MsgBox arrComputers(i) & " - ошибка назначения задания на запуск процесса. Код ошибки: " & intResult, vbCritical
                    End If
                Else
                    MsgBox arrComputers(i) & " - ошибка создания экземпляра задания. Код ошибки: " & Err.Number & vbNewLine & _
                            Err.Description, vbCritical
                    Err.Clear
                End If
            Else
                MsgBox arrComputers(i) & " - ошибка обращения к классу Win32_ScheduledJob. Код ошибки: " & Err.Number & vbNewLine & _
                        Err.Description, vbCritical
                Err.Clear
            End If
        Else
            MsgBox arrComputers(i) & " - процесс уже запущен.", vbExclamation
        End If
    Else
        MsgBox arrComputers(i) & " - ошибка подключени к пространству CIMV2. Код ошибки: " & Err.Number & vbNewLine & _
                Err.Description, vbCritical
        Err.Clear
    End If
Next
End Sub