Как узнать состояние CheckBox в чужом окне

Call DispCallFunc(ObjPtr(obj), 112, CC_STDCALL, vbLongLong, 2, types(0), param(0), VarRtn)

Option Explicit
 
Private Declare PtrSafe Function AccessibleObjectFromWindow Lib "oleacc" ( _
                                 ByVal hwnd As OLE_HANDLE, _
                                 ByVal dwId As Long, _
                                 ByRef riid As Any, _
                                 ByRef ppvObject As Object) As Long
Private Declare PtrSafe Function IIDFromString Lib "ole32" ( _
                                 ByRef lpsz As Any, _
                                 lpiid As Any) As Long
Private Declare PtrSafe Function DispCallFunc Lib "oleaut32" ( _
                                 ByVal PPV As IUnknown, _
                                 ByVal oVft As LongPtr, _
                                 ByVal cc As Long, _
                                 ByVal rtTYP As Long, _
                                 ByVal paCNT As Long, _
                                 paTypes As Any, _
                                 paValues As Any, _
                                 ByRef fuReturn As Variant) As Long
 
Private Const IID_IAccessible       As String = "{618736e0-3c3d-11cf-810c-00aa00389b71}"
Private Const OBJID_CLIENT          As Long = -4
Private Const CC_STDCALL            As Long = 4
Private Const STATE_SYSTEM_CHECKED  As Long = &H10
 
Private Function GetCheckState( _
                 ByVal hwnd As OLE_HANDLE) As Boolean
    Dim iid(15)     As Byte
    Dim IAccessible As IUnknown
    Dim hr          As Long
    
    hr = IIDFromString(ByVal StrPtr(IID_IAccessible), iid(0))
    If hr < 0 Then
        Err.Raise hr
    End If
    
    hr = AccessibleObjectFromWindow(hwnd, OBJID_CLIENT, iid(0), IAccessible)
    If hr < 0 Then
        Err.Raise hr
    End If
     
    GetCheckState = (IAccessibleGet_accState(IAccessible, 0&) And STATE_SYSTEM_CHECKED)
 
End Function
 
Private Function IAccessibleGet_accState( _
                 ByVal obj As IUnknown, _
                 ByVal VarID As Variant) As Variant
    Dim types() As Integer, param() As LongPtr
    Dim hr  As Long, vhr As Variant
    
    ReDim types(1): ReDim param(1)
    
    types(0) = vbVariant: types(1) = vbString
    param(0) = VarPtr(VarID): param(1) = VarPtr(IAccessibleGet_accState): IAccessibleGet_accState = param(1)
    
    hr = DispCallFunc(obj, 112, CC_STDCALL, vbLong, 2, types(0), param(0), vhr)
    
    If hr < 0 Then
        Err.Raise hr
    ElseIf vhr < 0 Then
        Err.Raise hr
    End If
    
End Function

Private Sub TestAccess()
Dim hwnd As LongPtr
    hwnd = &H1053C
    Debug.Print Hex(hwnd) & "h"
    Debug.Print GetCheckState(hwnd)
End Sub