Как получить доступ к "расшаренным" хардам компов, входящих в общую сеть

Open "//192.168.7.8/OGT_For_ALL/123.txt" For Input As 1
  Line Input #1, s
Close 1

Option Explicit
 
Private Sub Form_Load()
    Dim NetShare        As String
    Dim file            As String
    Dim sDriveLetter    As String
    
    NetShare = "\\192.168.12.6\общие документы"
    file = "test.txt"
 
    sDriveLetter = MountShare(NetShare)
    If sDriveLetter <> vbNullString Then
        MsgBox ReadFile(sDriveLetter & ":\" & file)
        UnMountShare sDriveLetter
    End If
End Sub
 
' Монтирует сетевое уст-во. Возвращает букву диска в случае успеха
Function MountShare(Share As String) As String
    Dim FSO, oNetwork, oDrive, sDrvMap, sDriveLetter
 
    sDrvMap = "DEFGHIJKLMNOPQRSTUVWX"   ' поиск свободной буквы диска
    Set FSO = CreateObject("Scripting.FileSystemObject")
    For Each oDrive In FSO.Drives
        sDrvMap = Replace(sDrvMap, oDrive.DriveLetter, "", 1, 1)
    Next
    sDriveLetter = Left(sDrvMap, 1)
 
    If sDriveLetter <> vbNullString Then
        Set oNetwork = CreateObject("Wscript.Network")
        On Error Resume Next
        oNetwork.MapNetworkDrive sDriveLetter & ":", Share
        If Err = 0 Then MountShare = sDriveLetter Else Debug.Print Err & " " & Err.Description
    End If
End Function
 
' Возвращает ноль в случае успеха
Function UnMountShare(sDriveLetter As String, Optional Force As Boolean) As Long
    Dim oNetwork
    
    Set oNetwork = CreateObject("Wscript.Network")
    On Error Resume Next
    oNetwork.RemoveNetworkDrive sDriveLetter & ":", Force
    UnMountShare = Err.Number
End Function
 
Function ReadFile(file As String) As String
    On Error Resume Next
    Dim ff          As Integer
    Dim FileSize    As Long
    
    ff = FreeFile()
    FileSize = FileLen(file)
    If FileSize Then
        Open file For Binary Access Read As #ff
            ReadFile = Space(FileSize)
            Get #ff, , ReadFile
        Close #ff
    End If
End Function