Как из программы управлять другой, уже запущенной программой

Option Explicit
 
Private Declare Function SetWinEventHook Lib "user32" (ByVal eventMin As Long, _
                                                 ByVal eventMax As Long, _
                                                 ByVal hmodWinEventProc As Long, _
                                                 ByVal pfnWinEventProc As Long, _
                                                 ByVal idProcess As Long, _
                                                 ByVal idThread As Long, _
                                                 ByVal dwFlags As Long) As Long
Private Declare Function UnhookWinEvent Lib "user32" (ByVal hWinEventHook As Long) As Long
Private Declare Function GetClassName Lib "user32" Alias "GetClassNameW" (ByVal hwnd As Long, _
                                                                          ByVal lpClassName As Long, _
                                                                          ByVal nMaxCount As Long) As Long
Private Declare Function FindWindowEx Lib "user32" Alias "FindWindowExW" (ByVal hWndParent As Long, _
                                                                          ByVal hWndChildAfter As Long, _
                                                                          ByVal lpClassName As Long, _
                                                                          ByVal lpWindowName As Long) As Long
Private Declare Function SendMessage Lib "user32" Alias "SendMessageW" (ByVal hwnd As Long, _
                                                                        ByVal wMsg As Long, _
                                                                        ByVal wParam As Long, _
                                                                        lParam As Any) As Long
 
Private Const WM_SETTEXT        As Long = &HC
Private Const EVENT_OBJECT_SHOW As Long = &H8002&
Private Const WM_LBUTTONDOWN    As Long = &H201
Private Const WM_LBUTTONUP      As Long = &H202
 
Dim hEvent As Long
 
' // Начать захват
Public Sub Hook()
    ' Устанавливаем хук на создание окон в системе
    hEvent = SetWinEventHook(EVENT_OBJECT_SHOW, EVENT_OBJECT_SHOW, 0, AddressOf WinEventProc, 0, 0, 0)
End Sub
 
' // Закончить захват
Public Sub Unhook()
    ' Снимаем хук
    UnhookWinEvent hEvent
End Sub
 
' // Функция вызывается при создании (показе) окна
Private Sub WinEventProc(ByVal hWinEventHook As Long, _
                         ByVal dwEvent As Long, _
                         ByVal hwnd As Long, _
                         ByVal idObject As Long, _
                         ByVal idChild As Long, _
                         ByVal dwEventThread As Long, _
                         ByVal dwmsEventTime As Long)
                   
    Dim cls As String
    Dim sLn As Long
    
    cls = Space(255)
    ' Получаем имя класса окна
    sLn = GetClassName(hwnd, StrPtr(cls), Len(cls))
    
    If sLn Then
        
        cls = Left(cls, sLn)
        ' Форма подтверждения пароля
        If cls = "TFormConfirm" Then
            Dim hEdit   As Long
            Dim hBtn    As Long
            Dim hPanel  As Long
            ' Ищем контейнер
            hPanel = FindWindowEx(hwnd, 0, StrPtr("TElPanel"), 0)
            ' Ищем поле ввода пароля
            hEdit = FindWindowEx(hPanel, 0, StrPtr("TElEdit"), 0)
            ' Ищем кнопку ОК
            hBtn = FindWindowEx(hPanel, 0, StrPtr("TElPopupButton"), StrPtr("OK"))
            
            If CBool(hEdit) And CBool(hBtn) Then
                ' Вводим текст в поле ввода
                SendMessage hEdit, WM_SETTEXT, 0, ByVal StrPtr("пароль")
                ' Жмем на кнопку
                SendMessage hBtn, WM_LBUTTONDOWN, 1, ByVal 0
                SendMessage hBtn, WM_LBUTTONUP, 0, ByVal 0
                
            End If
            
        End If
        
    End If
    
End Sub

' Ищем поле ввода пароля
hEdit = FindWindowEx(hPanel, 0, StrPtr("TElEdit"), 0)