Ожидание завершения ранее запущеного процесса

Option Explicit
 
Private Const MAX_PATH As Long = 260&
 
Private Type PROCESSENTRY32
    dwSize As Long
    cntUsage As Long
    th32ProcessID As Long
    th32DefaultHeapID As Long
    th32ModuleID As Long
    cntThreads As Long
    th32ParentProcessID As Long
    pcPriClassBase As Long
    dwFlags As Long
    szExeFile As String * MAX_PATH
End Type
 
Private Declare Function CreateToolhelp32Snapshot Lib "kernel32.dll" (ByVal dwFlags As Long, ByVal th32ProcessID As Long) As Long
Private Declare Function Process32First Lib "kernel32.dll" (ByVal hSnapshot As Long, ByRef lppe As PROCESSENTRY32) As Long
Private Declare Function Process32Next Lib "kernel32.dll" (ByVal hSnapshot As Long, ByRef lppe As PROCESSENTRY32) As Long
Private Declare Function CloseHandle Lib "kernel32.dll" (ByVal hObject As Long) As Long
Private Declare Function lstrcmpi Lib "kernel32.dll" Alias "lstrcmpiW" (ByVal lpString1 As Long, ByVal lpString2 As Long) As Long
Private Declare Function OpenProcess Lib "kernel32.dll" (ByVal dwDesiredAccess As Long, ByVal bInheritHandle As Long, ByVal dwProcessId As Long) As Long
Private Declare Function WaitForSingleObject Lib "kernel32.dll" (ByVal hHandle As Long, ByVal dwMilliseconds As Long) As Long
 
Private Const TH32CS_SNAPPROCESS        As Long = 2
Private Const SYNCHRONIZE               As Long = &H100000
Private Const INFINITE                  As Long = -1
Private Const INVALID_HANDLE_VALUE      As Long = -1
 
Private Sub Form_Load()
    Dim sProcName As String
    Dim PID As Long
    Dim hProc As Long
    
    sProcName = "notepad.exe"
 
    If IsRunned(sProcName, PID) Then
        hProc = OpenProcess(SYNCHRONIZE, False, PID)
        If hProc > 0 Then
            Call WaitForSingleObject(hProc, INFINITE)
        End If
        MsgBox "Процесс " & sProcName & " завершился."
    Else
        MsgBox "Процесс " & sProcName & " не запущен!"
    End If
End Sub
 
 
Function IsRunned(Optional ByRef ProcessName As String, Optional ByRef ProcessID As Long) As Boolean
    ' Запущен ли процесс, указанный по имени или ProcessID
    ' (регистр символов не учитывается)
    ' Если процесс найден, в переменную ProcessID передается PID найденного процесса (если поиск велся по имени),
    ' либо в переменную ProcessName возвращается имя найденного процесса (если поиск велся по PID).
 
    Dim hSnap   As Long
    Dim pe      As PROCESSENTRY32
 
    If Len(ProcessName) = 0 And ProcessID = 0 Then Exit Function
 
    hSnap = CreateToolhelp32Snapshot(TH32CS_SNAPPROCESS, 0)
 
    If hSnap = INVALID_HANDLE_VALUE Then Exit Function
 
    pe.dwSize = Len(pe)
 
    If Process32First(hSnap, pe) Then
        Do
            If Len(ProcessName) = 0 Then
                If pe.th32ProcessID = ProcessID Then
                    IsRunned = True
                    ProcessName = Left$(pe.szExeFile, InStr(pe.szExeFile, vbNullChar) - 1)
                    Exit Do
                End If
            Else
                If lstrcmpi(StrPtr(pe.szExeFile), StrPtr(ProcessName)) = 0 Then
                    IsRunned = True
                    ProcessID = pe.th32ProcessID
                    Exit Do
                End If
            End If
        Loop While Process32Next(hSnap, pe)
    End If
    CloseHandle hSnap
End Function